Re: [Gnuplot-info] No border around the plot, but axes with arrows

[Thomas S. <t.s...@fz...>]

extent xrange and yrange a little bit:
set xrange [-10:10.5]
set yrange [-10:10.5]

if you want to restrict plotting up to x=10 modify your plot command:
plot x<=10?sin(x) * cos(x):1/0

here is a complete script:
set xzeroaxis lt -1 lw .5
set yzeroaxis lt -1 lw .5
set xrange [-10:10.5]
set yrange [-10:10.5]
set xtics axis
set ytics axis
unset border
set arrow 1 from graph 0,first 0 to graph 1,first 0  lt -1 lw .5
set arrow 2 from first 0,graph 0 to first 0,graph 1  lt -1 lw .5
set samples 1000
plot x<=10?sin(x) * cos(x):1/0 title "sin(x)*cos(x)"

you may also modify the labels:
set xtics -10,2,9
(for more information see 'help set xtics')


fips wrote:
> 
> 
> fips wrote:
>> 
>> I need arrows at the end of the visible part of the axes to show, that
>> the axes does not end there.
>> I know how paint arrows, but is there a way to change the axes, that they
>> paint arrows themselfs?
>> 
> 
> Thanks to "Thomas Sefzick" I have solved nearly the whole problem.
> 
> Now: The arrows should go some mm over the numbering.
> This could be done by 
> 
> a) removing the topmost (rightmost) label in the graph.
> b) enlarging the arrow by 3mm each.
> 
> any idea?
> 
> Now i use the following script:
> 
> 
> set xzeroaxis lt -1 lw .5
> set yzeroaxis lt -1 
> set xrange [-10:10]
> set yrange [-10:10]
> set xtics axis
> set ytics axis
> unset border
> set arrow 1 from graph 0,first 0 to graph 1,((first 0) + 1) lt -1
> set arrow 2 from first 0,graph 0 to first 0,graph 1
> set nolabel 1
> plot sin(x) * cos(x)4
> 
> 

-- 
View this message in context: http://www.nabble.com/No-border-around-the-plot%2C-but-axes-with-arrows-tf4566710.html#a13112487
Sent from the Gnuplot - User mailing list archive at Nabble.com.