Re: [Gnuplot-info] xyzerrorlars

[theozh <th...@gm...>]

a (strange) workaround might be the following...

Assuming your original data has the following structure:
x   y   z  dx  dy  dz 
you can create a dataset which contains the x,y,z errorbars as data each separated by at least 2 empty lines.
When you plot this dataset, lines will not be connected and will look like x,y,z errorbars.
Maybe this is somehow helpful.
Theo.


####### 3D plot with "x,y,z errorbars"

$Data <<EOD
# x   y   z  dx  dy  dz 
0.0 0.0 0.0 0.1 0.1 0.1
1.0 0.5 1.0 0.2 0.2 0.2
2.0 2.0 1.5 0.5 0.5 0.5
4.0 3.0 1.0 1.0 0.6 0.4
EOD

stats $Data
set print $ErrXYZ
do for [i=0:STATS_records-1] {
   set table $Dummy
   plot $Data u ($1-$4):2:3 every ::i::i with table
   plot $Data u ($1+$4):2:3 every ::i::i with table
   print $Dummy
   print "\n"
   set table $Dummy
   plot $Data u 1:($2-$5):3 every ::i::i with table
   plot $Data u 1:($2+$5):3 every ::i::i with table
   print $Dummy
   print "\n"  
   set table $Dummy
   plot $Data u 1:2:($3-$6) every ::i::i with table
   plot $Data u 1:2:($3+$6) every ::i::i with table
   print $Dummy
   print "\n"   
}
unset table 
set print
# print $ErrXYZ  #uncomment this line if you want to print the dataset

splot $Data u 1:2:3 w lp, $ErrXYZ w lp ls 7 ps 0.5 lc rgb "red"

# end of code