Menu
▾
▴
Re: [Gnuplot-info] 3D plot of measurement data
|
From: Thomas S. <t.s...@fz...> - 2010-07-11 10:33:25
|
a complete script with automatic definition of x- and ytics (needs
3 dummy plots) would look like this:
reset
set macro
set term push
set term dumb
datafilename = 'your_datafilename'
datafilenamepipe = '< tail +2 '.datafilename.' | cut -d " " -f 2-'
# determine the numbers of rows and columns
splot datafilenamepipe matrix
nxtics = GPVAL_X_MAX-GPVAL_X_MIN
nytics = GPVAL_Y_MAX-GPVAL_Y_MIN
# define xtics (use 1st line only)
# to make gnuplot happy plot a linear function (using (i):(i))
xtics = "("
plot for [i=0:nxtics] \
datafilename \
using (i):(i>0?xtics=xtics.',':0 , \
xtics=xtics.' "'.stringcolumn(i+1).'" '.i , \
i) \
every ::0::0
xtics = xtics.' )'
set xtics @xtics
set xtics rotate by 90
sh xtics
# define ytics (start with 2nd line)
# to make gnuplot happy plot a linear function (using 2:($2))
ytics = "("
plot datafilename \
using 2:($0>0?ytics=ytics.',':0 , \
ytics=ytics.' "'.stringcolumn(1).'" '.sprintf("%d",$0) , \
$2) \
every ::1
ytics = ytics.' )'
set ytics @ytics
set ytics rotate by 90
sh ytics
set term pop
splot datafilenamepipe matrix with linespoints
Thomas Sefzick wrote:
>
> if you omit the x- and y-tics strings then your data are in a
> simple ascii matrix format and may be plotted with
>
> splot 'datafilename' matrix
>
> delete the 1st line, i.e. the line with the x-tics lables, otherwise
> 'splot' will fail. on a unix-like system and on a windows system
> with cygwin library you may use
>
> splot '< tail +1 datafilename' matrix
>
> x- and y-values in the plot are the column and row numbers, resp.
> starting from '0'.
>
> (you may 'set table' to convert your matrix (using the above 'splot'
> command) into the data format like in the demos.)
>
>
> Christian Baun wrote:
>>
>> Hi,
>>
>> I'm looking for a way to plot measurement data of iozone with gnuplot.
>>
>> The data has this style.
>>
>> "4" "8" "16" "32" "64"
>> "64" 1419266 2068710 2198495 2291049 2360570 ...
>> "128" 1852885 2137077 1907552 2414195 1779689
>> "256" 1218963 1766143 1391933 2304816 2509077
>> "512" 1450125 2217077 1580337 1610085 2081676
>> "1024" 1416237 2106757 1875193 2011379 2437817
>> "2048" 1603861 1459826 1759561 1841672 1728337
>> "4096" 1454529 1505890 1501415 1710995 1810833
>> "8192" 1330492 319961 1582402 1542753 1697480
>> "16384" 1317258 1512262 1578257 1378195 1579478
>> ...
>>
>> The first row is the caption of the X-axis.
>> The first line is the caption of the Y-axis.
>> A perfect output would be like the first image at the iozone-website [1].
>>
>> Now, I'm searching for a demo script that does more or less the same. The
>> page [2] with the demo scripts for gnuplot version 4.4 has some scripts
>> for surfaces and 3D plotting but these scripts always plot a function or
>> the data is from this style:
>>
>> 0.092386 0.000000 -0.291706
>> 0.084399 0.037577 -0.291706
>> 0.061819 0.068656 -0.291706
>> 0.028549 0.087865 -0.291706
>> 0.009657 0.091880 -0.291706
>> ...
>>
>> But this approach is totally different.
>>
>> I'm not sure, if plotting iozone measurement data can be done with
>> "splot". I also don't know how to import the captions of the X and Y-axis
>> (first row and first line). It's not possible here to work with "set
>> xrange" and "set yrange".
>>
>> Thanks in advance for any help.
>>
>> Best Regards,
>> Christian
>>
>> [1] http://www.iozone.org
>> [2] ttp://gnuplot.sourceforge.net/demo_4.4/
>>
>> ------------------------------------------------------------------------------
>> This SF.net email is sponsored by Sprint
>> What will you do first with EVO, the first 4G phone?
>> Visit sprint.com/first -- http://p.sf.net/sfu/sprint-com-first
>> _______________________________________________
>> gnuplot-info mailing list
>> gnu...@li...
>> https://lists.sourceforge.net/lists/listinfo/gnuplot-info
>>
>>
>
>
--
View this message in context: http://old.nabble.com/3D-plot-of-measurement-data-tp29125066p29130726.html
Sent from the Gnuplot - User mailing list archive at Nabble.com.
|
