Re: [Gnuplot-info] Polar Plot with logarithmic magnitude

[Thomas S. <t.s...@fz...>]

apply the log10() function to your data and shift the resulting r range
to positive values (starting from zero).
an example:

# rrange goes from 10^-4 = 0.0001 to 10^0 = 1.
# so log10(rrange) goes from -4 to 0 and must be
# shifted to 0 to 4
reset
set angles radians
set grid polar pi/6.
unset label
set label 1 "0.0001" at 0, -0.2
set label 2 "0.001" at 1, -0.2
set label 3 "0.01" at 2, -0.2
set label 4 "0.1" at 3, -0.2
set label 5 "1.0" at 4, -0.2
unset arrow
set arrow 1 from 0,0 to 4,0 nohead
set polar
set samples 1000, 1000
set size square
set rrange [0:4]
set xrange [-4:4]
set yrange [-4:4]
# some function producing values in the range
# 0.0001 to (nearly) 1.0
f(t)=0.99*(sin(t+0.5*pi)**2+10**(-4))
# plot the function (multiplied by 4. to have the same range)
plot f(t)*4.
# plot log10() of the function (shifted by 4.)
replot log10(f(t))+4.
pause -1
# and now without border
unset border
set format x ""
set format y ""
set xtics scale 0
set ytics scale 0
replot


Christian Winkel-2 wrote:
> 
> Hi
> 
> I have to plot a lot of polar plots with a logarithmic r scale.
> 
> It should look like this:
> 
> http://img39.imageshack.us/img39/5214/polarmie.png
> 
> This plot is made by gnumeric, but it is too time-consuming and didn't
> look good in a latex document.
> 
> Is it possibe to plot someting like this with gnuoplot? How?
> 
> 
> 
> 
> Thank you
> 
> 
> Chris
> 
> 
> ------------------------------------------------------------------------------
> This SF.Net email is sponsored by the Verizon Developer Community
> Take advantage of Verizon's best-in-class app development support
> A streamlined, 14 day to market process makes app distribution fast and
> easy
> Join now and get one step closer to millions of Verizon customers
> http://p.sf.net/sfu/verizon-dev2dev 
> _______________________________________________
> gnuplot-info mailing list
> gnu...@li...
> https://lists.sourceforge.net/lists/listinfo/gnuplot-info
> 
> 

-- 
View this message in context: http://old.nabble.com/Polar-Plot-with-logarithmic-magnitude-tp26965592p26966685.html
Sent from the Gnuplot - User mailing list archive at Nabble.com.