gnuplot-info — For questions and discussion about gnuplot

Re: [Gnuplot-info] gnuplot load script twice problem

[Ethan A M. <eam...@gm...>]

On Friday, 18 January 2019 11:18:16 Junqing Liu wrote:
> Hi, everybody,
> I am an new people of gnuplot. I get a script, but I had a problem when I
> loaded the script twice, the first time work well, the second do not work.
> please see the error message:

Try issuing a "reset" command before the second load.
If that is not sufficient, try "reset session".

	Ethan

> 
> Terminal type is now 'wxt'
> gnuplot> load 'rstf.plt'
> gnuplot> load 'rstf.plt'
>          "rstf.plt" line 15: warning: could not confirm linked axis inverse
> mapping function
>         axis1: (set_min,min,testmin) = (0,0.001,nan); axis1:
> (set_max,max,testmax) = (120,10,120); axis2: (set_min,min) = (0,0.001);
> axis2: (
> set_max,max) = (120,10)
>          "rstf.plt" line 22: x range must be greater than 0 for log scale
> 
> multiplot>
> 
> 
> Junqing Liu

[Gnuplot-info] gnuplot load script twice problem

[Junqing L. <li...@gm...>]

Hi, everybody,
I am an new people of gnuplot. I get a script, but I had a problem when I
loaded the script twice, the first time work well, the second do not work.
please see the error message:


Terminal type is now 'wxt'
gnuplot> load 'rstf.plt'
gnuplot> load 'rstf.plt'
         "rstf.plt" line 15: warning: could not confirm linked axis inverse
mapping function
        axis1: (set_min,min,testmin) = (0,0.001,nan); axis1:
(set_max,max,testmax) = (120,10,120); axis2: (set_min,min) = (0,0.001);
axis2: (
set_max,max) = (120,10)
         "rstf.plt" line 22: x range must be greater than 0 for log scale

multiplot>


Junqing Liu

Re: [Gnuplot-info] plotting a knot on a torus

[Hans-Bernhard B. <HBB...@t-...>]

Am 04.01.2019 um 05:11 schrieb Brian Merchant:
> I plotted a torus, and a knot on it, using the following commands:

> However, if I plot a more complicated knot:
> 
> splot [-pi:pi][-pi:pi] (2 + cos(u))*cos(v), (2 + cos(u))*sin(v), sin(u),
> [-pi:pi][-pi:pi] (2 + cos(3*u))*cos(2*u), (2 + cos(3*u))*sin(2*u), sin(2*u),
> 
> then the knot's curve breaks :(  

I'm convinced that that's because that knot curve is not actually _on_
the torus.  It dives into it, and therefore hidden3d is doing exactly
what you asked it to.

Re: [Gnuplot-info] plotting a knot on a torus

[Ethan A M. <eam...@gm...>]

On Thursday, 03 January 2019 20:37:49 Ethan A Merritt wrote:

There are more options you can turn on if you don't use parametric mode.
For example here is a pm3d version (rather than hidden3d) that may be
a better starting point:

set style fill  transparent solid 0.40 border
set view 53, 100, 1, 1
set isosamples 50, 50
set style data lines
set pm3d depthorder border lc "black"  lw 0.25
unset colorbox
unset key

splot sample [-pi:pi][-pi:pi] '++' using (2 + cos($1))*cos($2)\
                                        :(2 + cos($1))*sin($2):(sin($1))\
                                        :(0xffeebb) with pm3d lc rgb variable, \
             [-pi:pi] '+'  using ((2 + cos(3*$1))*cos(2*$1))\
                               : ((2 + cos(3*$1))*sin(2*$1))\
                               : (sin(2*$1)) with lines lw 4
 

[Gnuplot-info] plotting a knot on a torus

[Brian M. <bhm...@gm...>]

I plotted a torus, and a knot on it, using the following commands:

unset key
set parametric
set isosamples 30,30
set hidden3d
splot [-pi:pi][-pi:pi] (2 + cos(u))*cos(v), (2 + cos(u))*sin(v), sin(u),
[-pi:pi] (2 + cos(u))*cos(u), (2 + cos(u))*sin(u), sin(u)

This works beautifully.

However, if I plot a more complicated knot:

splot [-pi:pi][-pi:pi] (2 + cos(u))*cos(v), (2 + cos(u))*sin(v), sin(u),
[-pi:pi][-pi:pi] (2 + cos(3*u))*cos(2*u), (2 + cos(3*u))*sin(2*u), sin(2*u),

then the knot's curve breaks :(  It seems this has something to do with
`set hidden3d`, as if I unset that, then nothing is hidden, but the curve
is rendered normally.

What can I do to fix this problem?

I am on Windows 10, using the latest version of gnuplot, with the Qt
terminal.

Kind regards,
Brian

[Gnuplot-info] How to realize vertically/horizontally hatched fill patterns?

[theozh <th...@gm...>]

Hi,
I was trying to plot some filled curves with hatched patterns.
If I type "test" I see 7 different fill patterns.
However, I couldn't find vertically or horizontally hatched patterns.
How can I realize this with gnuplot?
Thank you for hints.
Theo.

Re: [Gnuplot-info] read file to datablock

[theozh <th...@gm...>]

Thanks again, Ethan!
just for completeness, such that the world can read your valuable comments (see below).
Theo.
> 
>     just for curiosity...
>     Do you know if there is also a way under Linux without creating and loading two helper files?
> 
> 
> I'm sure there are several, but I thought the shell syntax would not be applicable on MSWin. 
> Here is one way
> 
> load '< echo "\$DATA << EOD" & cat file.dat'
>  
> 
>     Do you actually need the "EOD" at the end under Linux?
> 
> 
> You do if it is being read from a file or input stream that may contain other 
> commands after the data block.  The EOD signals the end of the data block and the
> start of regular commands. But in your specific case there is nothing after the data
> and the true end-of-file serves the same purpose.  So the answer is "no" you do not
> need the EOD if the load operation is only filling a datablock.
> 
>               Ethan
>

Re: [Gnuplot-info] read file to datablock

[theozh <th...@gm...>]

just for curiosity...
Do you know if there is also a way under Linux without creating and loading two helper files?
Do you actually need the "EOD" at the end under Linux?

Re: [Gnuplot-info] read file to datablock

[theozh <th...@gm...>]

> Do you understand why the < characters need to be escaped?
> It seems worth documenting this technique somewhere and it would
> be nice to explain when this is or isn't necessary.
> Would it would to put in another set of quotes instead?
>    load "< echo '$Data <<EOD' & type ".FILE
> 

For some reason this does not work:
load "< echo '$Data <<EOD' & type ".FILE
I don't know why.

The '<' characters need to be escaped because otherwise they would be interpreted as redirection.
I found this information here:
https://ss64.com/nt/syntax-redirection.html

I haven't yet succeeded to put "EOD" at the end if the very last character of the datafile is not "\n". But apparently there is no need to put EOD at the end because it seems to work without.

Yes, it would be nice if this will be documented somewhere "officially" :-)
And maybe a more advanced Win-user can comment on this.

Re: [Gnuplot-info] read file to datablock

[Ethan A M. <eam...@gm...>]

On Tuesday, 13 November 2018 22:02:42 theozh wrote:
> ok, I think here we go :-)
> You concatenate the text '$Data <<EOD' and the content of the file using the commands 'echo' and 'type' at which the character '<' has to be escaped by '^'.
> So easy if you know how.
> 
> The advantages over the earlier mentioned other methods:
> - empty lines are preserved
> - no additional space character at the beginnig of the line
> - no loading of any extra assistant files
> 
> 
> ### Read file "as is" to datablock under Windows
> reset session
> FILE = "Test.dat"
> 
> load "< echo $Data ^<^<EOD & type ".FILE
> print "$Data"
> print $Data
> ### end of code

Do you understand why the < characters need to be escaped?
It seems worth documenting this technique somewhere and it would
be nice to explain when this is or isn't necessary.
Would it would to put in another set of quotes instead?
   load "< echo '$Data <<EOD' & type ".FILE

Glad you got it working.

	Ethan

Re: [Gnuplot-info] read file to datablock

[theozh <th...@gm...>]

ok, I think here we go :-)
You concatenate the text '$Data <<EOD' and the content of the file using the commands 'echo' and 'type' at which the character '<' has to be escaped by '^'.
So easy if you know how.

The advantages over the earlier mentioned other methods:
- empty lines are preserved
- no additional space character at the beginnig of the line
- no loading of any extra assistant files


### Read file "as is" to datablock under Windows
reset session
FILE = "Test.dat"

load "< echo $Data ^<^<EOD & type ".FILE
print "$Data"
print $Data
### end of code

Re: [Gnuplot-info] read file to datablock

[theozh <th...@gm...>]

Hi Ethan,
I agree, that this was not a good solution.

Ok, here is another attempt, however, still not so nice with creating the temporary second file 'head' on disk.
It seems like to work even without the end-of-data-marker (i.e. your 'tail' file containing 'EOD')

Would it a big thing to implement such a 'file-to-datablock-import' in gnuplot directly? Or not worth it?

Theo.

### Read file "as is" to datablock under Windows
reset session
FILE = "Test.dat"

# Method3
set print "head"
print "$Data3 <<EOD"
set print

load "<type head & type ".FILE
print $Data3
### end of code

Re: [Gnuplot-info] read file to datablock

[Ethan A M. <eam...@gm...>]

On Monday, 12 November 2018 20:41:56 theozh wrote:
> Hi Ethan,
> based on your suggestion... the following seems to work under Windows.
> In case anybody on Windows might be interested.
> Although pretty ugly and cumbersome...
> 1. writing 2 files to disk
> 2. reading and concatenating 3 files from disk
> 3. writing another file to disk
> 4. and reading this file from disk
> 
> I am wondering whether this will work properly with extremely large files on extremely slow network drives?

Copying the original data into new file first and then reading it in a
separate step is strictly worse than directing it through a pipe.

So no, I would not recommend the file-based Method3 you show below.

Hopefully someone more familiar than I am with MSWin can help with
the commands needed to direct the catenation operation through a pipe.

	Ethan



> 
> Thanks,
> Theo.
> 
> ### Read file "as is" to datablock under Windows
> reset session
> FILE = "Test.dat"
> 
> # Method3
> set print "head"
> print "$Data3 << EOD"
> set print "tail"
> print "EOD"
> set print
> 
> system "type head ".FILE." tail > Temp.dat"
> load "Temp.dat"
> print $Data3
> ### end of code
> 
> 
> 
> _______________________________________________
> gnuplot-info mailing list
> gnu...@li...
> Membership management via: https://lists.sourceforge.net/lists/listinfo/gnuplot-info

Re: [Gnuplot-info] read file to datablock

[theozh <th...@gm...>]

Hi Ethan,
based on your suggestion... the following seems to work under Windows.
In case anybody on Windows might be interested.
Although pretty ugly and cumbersome...
1. writing 2 files to disk
2. reading and concatenating 3 files from disk
3. writing another file to disk
4. and reading this file from disk

I am wondering whether this will work properly with extremely large files on extremely slow network drives?

Thanks,
Theo.

### Read file "as is" to datablock under Windows
reset session
FILE = "Test.dat"

# Method3
set print "head"
print "$Data3 << EOD"
set print "tail"
print "EOD"
set print

system "type head ".FILE." tail > Temp.dat"
load "Temp.dat"
print $Data3
### end of code

Re: [Gnuplot-info] read file to datablock

[Ethan A M. <eam...@gm...>]

On Saturday, 10 November 2018 20:14:53 theozh wrote:
> Thank you again!
> I am not familiar with Win Powershell... would take a while to figure out.
> 
> But do you have an idea why Method2 gets this space at the beginning of the line?

"with table" places a " " character at the front of every field.
This insures that the fields can be distinguish even if you mess
up in specifying a field separator.

	Ethan


> 
> ### Read file to datablock
> reset session
> FILE = "Test.dat"
> set datafile separator "\n"
> set datafile commentschar ""
> 
> # Method2
> set table $Data2
>     plot FILE u (stringcolumn(1)) with table
> unset table
> print $Data2
> 
> 
> Am 10.11.2018 um 19:30 schrieb Ethan A Merritt:
> > On Saturday, 10 November 2018 19:02:12 theozh wrote:
> >> Thanks, in priciple a nice idea.
> >> But probably works only under Linux?!
> >> I guess 'cat' doesn't exists in a simple Win7 system.
> >> I tried with 'type' instead, but no success.
> > 
> > I can't help with Windows.
> > A quick bit of googling suggests that the equivalent of
> > "cat" in the Windows PowerShell is "get-content".  But I
> > do not know whether that works from inside gnuplot.
> > 
> > 	Ethan
> > 
> 
> 
> 
> _______________________________________________
> gnuplot-info mailing list
> gnu...@li...
> Membership management via: https://lists.sourceforge.net/lists/listinfo/gnuplot-info

Re: [Gnuplot-info] read file to datablock

[theozh <th...@gm...>]

Thank you again!
I am not familiar with Win Powershell... would take a while to figure out.

But do you have an idea why Method2 gets this space at the beginning of the line?

### Read file to datablock
reset session
FILE = "Test.dat"
set datafile separator "\n"
set datafile commentschar ""

# Method2
set table $Data2
    plot FILE u (stringcolumn(1)) with table
unset table
print $Data2


Am 10.11.2018 um 19:30 schrieb Ethan A Merritt:
> On Saturday, 10 November 2018 19:02:12 theozh wrote:
>> Thanks, in priciple a nice idea.
>> But probably works only under Linux?!
>> I guess 'cat' doesn't exists in a simple Win7 system.
>> I tried with 'type' instead, but no success.
> 
> I can't help with Windows.
> A quick bit of googling suggests that the equivalent of
> "cat" in the Windows PowerShell is "get-content".  But I
> do not know whether that works from inside gnuplot.
> 
> 	Ethan
> 

Re: [Gnuplot-info] read file to datablock

[Ethan A M. <eam...@gm...>]

On Saturday, 10 November 2018 19:02:12 theozh wrote:
> Thanks, in priciple a nice idea.
> But probably works only under Linux?!
> I guess 'cat' doesn't exists in a simple Win7 system.
> I tried with 'type' instead, but no success.

I can't help with Windows.
A quick bit of googling suggests that the equivalent of
"cat" in the Windows PowerShell is "get-content".  But I
do not know whether that works from inside gnuplot.

	Ethan


> 
> On Saturday, 10 November 2018 07:05:46 theozh wrote:
> > Hi, I would like to read a file (as is) into a datablock.
> > I basically found two ways to do this. See code below.
> 
> I would do something very different.
> 
> set print "head"
> print "$Data1 << EOD"
> set print "tail"
> print "EOD"
> unset print
> 
> load "< cat head Test.dat tail"
> print $Data1
> 
> 		Ethan

Re: [Gnuplot-info] read file to datablock

[theozh <th...@gm...>]

Thanks, in priciple a nice idea.
But probably works only under Linux?!
I guess 'cat' doesn't exists in a simple Win7 system.
I tried with 'type' instead, but no success.


On Saturday, 10 November 2018 07:05:46 theozh wrote:
> Hi, I would like to read a file (as is) into a datablock.
> I basically found two ways to do this. See code below.

I would do something very different.

set print "head"
print "$Data1 << EOD"
set print "tail"
print "EOD"
unset print

load "< cat head Test.dat tail"
print $Data1

		Ethan

[Gnuplot-info] read file to datablock

[theozh <th...@gm...>]

Hi, I would like to read a file (as is) into a datablock.
I basically found two ways to do this. See code below.

First question:
My concern is that in Method1 the file has to be read/accessed (row)-times from disk whereas Method2 only once. If I have a file with several thousands or million rows on a very slow network connection this probably would take rather long, correct? I currently cannot test.
Can anybody comment on this?

Second question:
When reading the file via Method2 the datablock contains a space at every beginning of the line.
Can anybody explain why and how to avoid? Bug or feature?

Assuming the file "Test.dat" looks for example like the following:

# Test.dat
# Some test data
# more comments
1 2 3
4 5 6
7 8 9

Here is the code:

### Read file to datablock
reset session
FILE = "Test.dat"
set datafile separator "\n"
set datafile commentschar ""

# Method1
stats FILE u 0 nooutput
set print $Data1
set table $Dummy
do for [row=0:STATS_records-1] {
    plot FILE u (a=stringcolumn(1),a) every ::row::row with table
    print a
}
unset table
set print
print $Data1

# Method2
set table $Data2
    plot FILE u (stringcolumn(1)) with table
unset table
print $Data2

### end of code

Re: [Gnuplot-info] transpose data with gnuplot

[Ethan M. <eam...@gm...>]

On Thu, Nov 8, 2018 at 12:17 PM theozh <th...@gm...> wrote:

> Thank you, Ethan
> very interesting construct!
> For certain types of data it works.
>
> However, what I couldn't yet get to work is how to plot row data of the
> following type:
>
> $Data <<EOD
> # spectral data as function of time in rows
> Wav 400 500 600 700 800
> t01 1.1 1.2 1.3 1.4 1.5
> t02 2.1 2.2 2.3 2.4 2.5
> t03 3.1 3.2 3.3 3.4 3.5
> EOD
>

I have scripts that I use to plot *.csv files similar to this that are
generated
by a piece of equipment in the lab.
I agree that it would be nice to have an automatic "transpose" button or
command since opening up each *.csv file to do it in Excel is an annoying
detour.   My gnuplot scripts, although ugly, can handle the raw files.

Your case is a little worse because the first column is non-numeric.
Nevertheless here is a modified version of one of my scripts that plots
your data by rows.  Unfortunately the non-numeric 1st column causes it to
print warning messages.
Ugly? You bet.  But it works, except for extracting labels from the row
headers.

%%%%%%%%%%%%%%%%%%%%%%%%%%%%%%%%%%%%%%%%%%%%%%%%%%%%%%%
 $Data <<EOD
 # spectral data as function of time in rows
 Wav 400 500 600 700 800
 t01 1.1 1.2 1.3 1.4 1.5
 t02 2.1 2.2 2.3 2.4 2.5
 t03 3.1 3.2 3.3 3.4 3.5
 EOD

 array xval[10]
 stats $Data matrix using 1:(xval[$1+1]=$0,$0) every :::0::0  nooutput
 cols = STATS_records
 rows = |$Data| - 2
 print cols, " X values: ", xval
 set xrange [xval[2] : xval[cols]]
 show xrange
 set style data linespoints
 plot for [row=1:rows] $Data matrix using (xval[$1+1]):($3) every
:::row::row title sprintf("Row %d",row)
%%%%%%%%%%%%%%%%%%%%%%%%%%%%%%%%%%%%%%%%%%%%%%%%%%%%%%%

Re: [Gnuplot-info] transpose data with gnuplot

[theozh <th...@gm...>]

Thank you, Ethan
very interesting construct!
For certain types of data it works.

However, what I couldn't yet get to work is how to plot row data of the following type:

$Data <<EOD
# spectral data as function of time in rows
Wav 400 500 600 700 800 
t01 1.1 1.2 1.3 1.4 1.5
t02 2.1 2.2 2.3 2.4 2.5
t03 3.1 3.2 3.3 3.4 3.5
EOD

If the data was transposed, it would be very easy to plot.

$Data <<EOD
# spectra in columns
Wav t01 t02 t03 
400 1.1 2.1 3.1
500 1.2 2.2 3.2
600 1.3 2.3 3.3
700 1.4 2.4 3.4
800 1.5 2.5 3.5
EOD

plot for [i=2:4] $Data u 1:i w lp


So, a handy transpose function would be very helpful.
Theo.

Re: [Gnuplot-info] transpose data with gnuplot

[Ethan A M. <eam...@gm...>]

On Wednesday, 07 November 2018 08:13:40 theozh wrote:
> sometimes, data curves are available in rows and since gnuplot requires data in columns you would have to transpose your data, correct?
> 
> Of course, you can transpose your data with external tools (Python, awk, ...), however, in some cases it might be easier to do this in gnuplot.
> I am not aware of a function in gnuplot which plots rows or a function which transposes data.

Obscure commands
================

plot nth row of data in a file
        plot 'rowdata' matrix using 1:0 every :::n::n
     
store row n to an array, then plot it
        array row_n[10]
        stats 'rowdata' matrix using 1:(row_n[$1+1]=$0,$0) every :::n::n
        plot row_n

These commands arose unintentionally out of the way "every" interacts with
"matrix". So far as I know they are undocumented, but the behavior is not
likely to change.

    cheers,

		Ethan


> So, I created the script below.
> I think it is neither very elegant nor efficient, but is seems to work.
> However, if you have to load the data from a file and transpose it this file needs to be loaded "Rows x Cols" times for every datapoint. Is it like that or will the file be kept in memory? This will be problematic if you have to load the data from a slow network drive.
> If anybody has a better solution please let me know.
> 
> The script below will 1) create some dummy data 2) print the data 3) transpose it 4) print the transposed data
> 
> ### transpose data
> reset session
> 
> # create some dummy data
> Rows = 5
> Cols = 7
> set print $Data 
> LINE = sprintf("%gx%g\t",Rows,Cols)
> # create header columns
> do for [j=1:Cols] {
>     LINE = LINE.sprintf("x[%g]",j)
>     if (j<Cols) {LINE = LINE."\t"}
> }
> print LINE
> do for [i=1:Rows] {
>     LINE = ""
>     do for [j=1:Cols] {
>         LINE = LINE.sprintf("%g", (i-1)*Cols + j)
>         if (j<Cols) {LINE = LINE."\t"}
>     }
>     LINE = sprintf("t[%g]\t",i).LINE
>     print LINE
> }
> set print
> print $Data 
> # end dummy data
> 
> # transpose data
> set autoscale    # autoscale before stats
> stats $Data u 0 nooutput
> set table $Dummy
> set print $Transposed
> do for [i=1:STATS_columns] {
>     LINE = ""
>     do for [j=0:STATS_records-1] {
>        plot $Data u (a=stringcolumn(i),i) every ::j::j with table
>        LINE = LINE.sprintf("%s", a)
>        if (j < STATS_records-1) {LINE = LINE."\t"}
>     }
>     print LINE
> }
> set print
> unset table
> print $Transposed
> # end transpose data

[Gnuplot-info] transpose data with gnuplot

[theozh <th...@gm...>]

sometimes, data curves are available in rows and since gnuplot requires data in columns you would have to transpose your data, correct?

Of course, you can transpose your data with external tools (Python, awk, ...), however, in some cases it might be easier to do this in gnuplot.
I am not aware of a function in gnuplot which plots rows or a function which transposes data.
So, I created the script below.
I think it is neither very elegant nor efficient, but is seems to work.
However, if you have to load the data from a file and transpose it this file needs to be loaded "Rows x Cols" times for every datapoint. Is it like that or will the file be kept in memory? This will be problematic if you have to load the data from a slow network drive.
If anybody has a better solution please let me know.

The script below will 1) create some dummy data 2) print the data 3) transpose it 4) print the transposed data

### transpose data
reset session

# create some dummy data
Rows = 5
Cols = 7
set print $Data 
LINE = sprintf("%gx%g\t",Rows,Cols)
# create header columns
do for [j=1:Cols] {
    LINE = LINE.sprintf("x[%g]",j)
    if (j<Cols) {LINE = LINE."\t"}
}
print LINE
do for [i=1:Rows] {
    LINE = ""
    do for [j=1:Cols] {
        LINE = LINE.sprintf("%g", (i-1)*Cols + j)
        if (j<Cols) {LINE = LINE."\t"}
    }
    LINE = sprintf("t[%g]\t",i).LINE
    print LINE
}
set print
print $Data 
# end dummy data

# transpose data
set autoscale    # autoscale before stats
stats $Data u 0 nooutput
set table $Dummy
set print $Transposed
do for [i=1:STATS_columns] {
    LINE = ""
    do for [j=0:STATS_records-1] {
       plot $Data u (a=stringcolumn(i),i) every ::j::j with table
       LINE = LINE.sprintf("%s", a)
       if (j < STATS_records-1) {LINE = LINE."\t"}
    }
    print LINE
}
set print
unset table
print $Transposed
# end transpose data

Re: [Gnuplot-info] testing gnuplot build for fedora

[Ethan M. <eam...@gm...>]

n Mon, Nov 5, 2018 at 1:01 PM Ronaldo Mercado <r_m...@sk...> wrote:

> Hello,
>
> I would like to test gnuplot as built for fedora.
> https://bugzilla.redhat.com/show_bug.cgi?id=1476616
>
> How would I verify whether the libcerf functions are working as expected?
>

Run the scripts  complex_trig.dem and cerf.dem provided in the demo
directory.
Compare the output to the on-line demo collection
    http://gnuplot.sourceforge.net/demo_5.3/complex_trig.html
    http://gnuplot.sourceforge.net/demo_5.3/cerf.html


Thank you.
>
> Ronaldo
>
> _______________________________________________
> gnuplot-info mailing list
> gnu...@li...
> Membership management via:
> https://lists.sourceforge.net/lists/listinfo/gnuplot-info
>

[Gnuplot-info] testing gnuplot build for fedora

[Ronaldo M. <r_m...@sk...>]

Hello,

I would like to test gnuplot as built for fedora.
https://bugzilla.redhat.com/show_bug.cgi?id=1476616

How would I verify whether the libcerf functions are working as expected?

Thank you.

Ronaldo