#285 Color Column Not Grided

[Douglas]

I have some data that isn't gridded. The gridding functions in gnuplot are spectacular! But one thing confuses me: when I put in the commands at the end of this request, I receive the error: "Gridding of the color column is not implemented"

I would understand why gnuplot can't interpolate between an rgb triplet, but this is a paletted color scheme. Am I failing to make an appropriate setting somewhere?

set palette model HSV functions gray,1,1
set cbrange[-pi:pi]
set hidden3d
set pm3d implicit at bs
a = 2.4600e-10
i = {0.0,1.0}
scale = .02
limit = 6 #in normal point size, so one or five are good numbers
unset xtics
unset ytics
unset ztics
unset border
set dgrid3d 100,100,100 splines
set cbtics ( "-{/Symbol p}" -pi, "-{/Symbol p}/2" -pi/2.0, "0" 0, "{/Symbol p}/2" pi/2.0, "{/Symbol p}" pi)

set title "Resonant State Wavefunction"

radius(z) = abs(z)*scale
splot '-' u 1:2:(radius($3+$4*i)):(arg($3+$4*i)) w pm3d notitle

[Douglas]

Similarly the problem arises for the command:

splot '-' u 1:2:(radius($3+$4*i)):(arg($3+$4*i)) w p pt 7 ps 1 lc palette notitle

[Douglas]

Any interest in this problem? I figure a palette color is a linear function just like height and should be easy to implement.

[Douglas]

Here's a solution to the problem. I still think this could be accounted for by gridding the color column, and I may move this to a feature request:

set palette model HSV functions gray,1,1
set cbrange[-pi:pi]
set hidden3d
set pm3d at bs
set dgrid3d 200,200 splines
a = 2.4600e-10
i = {0.0,1.0}
scale = .02
limit = 6 #in normal point size, so one or five are good numbers
unset xtics
unset ytics
unset ztics
unset border
set cbtics ( "-{/Symbol p}" -pi, "-{/Symbol p}/2" -pi/2.0, "0" 0, "{/Symbol p}/2" pi/2.0, "{/Symbol p}" pi)

set title "Resonant State Wavefunction"

radius(z) = abs(z)*scale
#:(arg($3+$4*i))

set table 'tmp.dat'
splot '-' u 1:2:(radius($3+$4*i)) w linesp pt 7 ps 1 lc palette notitle
data
unset table

set table 'tmp2.dat'
splot '-' u 1:2:(arg($3+$4*i)) w linesp pt 7 ps 1 lc palette notitle
data
unset table

unset dgrid3d
splot '< paste tmp.dat tmp2.dat' u 1:2:3:7 w pm3d notitle

[Hans-Bernhard Broeker]

This is asking for a feature that gnuplot currently simply doesn't have. It would call for gnuplot to run the gridding algorithm twice: once for the z column, and again for the 'colour' column.

Thus the error message you got, and the reason to move this to Feature Requests.

[Anonymous]

Hello,

My current problem seems to be similar.
I also have a data set of amplitude and phase values on a two-dimensional grid
and would like to display them using a gnuplot script.
Thereby the phase is aimed to be represented by a hue parameter, whereas the amplitude
determines the color intensity.
Is the solution which was suggested here appropriate for this issue?
I tried to use the given code, but there seem to be difficulties with the interpolation.
Can you tell me how to proceed?

Best regards,

Joachim

[Ethan Merritt]

5.3 can now carry through color information to the gridded expansion, subject to the limitations:
1: palette color only; no rgb variable color
2: gridding via thin splines is not supported