[Ngspice-users] GZ34 ngspice model

[Dominique M. <dom...@ho...>]

ngspice model for a vacuum diode GZ34

I have put 2 diodes in the model because i'm using it with Geda and i want 
to have the concordance with my gschem symbol. And like it is 2 devices in 
the enveloppe...
It is a resistance to "simulate" the filament. I have put it to obtain the 
correspondance of all the pines with my Geda's symbol, and to eventualy have 
an approximation of the heating's courant if i'm doing a simulation of a 
whole amplifier with the alimentation.

* Double diode GZ34 Uinv max 1500V Imax 750mA
.SUBCKT GZ34 A1 A2 C F
* #########################################################
* Not modeled:
* Influence of the filament, noise,
* reverse caracteristic after 1500V
* Capacitances are pure estimations
*
* To do: noise model
* not urgent because it is much more easier to cancel out
*  as the noise from a silicon diode

* For reference about this model
* and for parameters for other vaccum diodes
* http://digilander.libero.it/paeng/vacuum_diode_models.htm
*##########################################################
* chauffage 5V 1.9A
RF C F 2,631578947

* parametres du tube
Vka ka 0 DC 0.0065731838
Vkb kb 0 DC 0.000345434
Veps eps 0 DC 0.1
Rka ka 0 1G
Rkb kb 0 1G
Reps eps 0 1G

* diode 1
B1 1 0 V=(V(ka)+(V(kb)*V(A1,C)))
R1 1 0 1G
B2 2 0 V=(V(A1,C)+V(eps))
R2 2 0 1G
* pwr(v(2),at)
B3 3 0 V=((abs(V(2)))^1.0847522)
R3 3 0 1G
* pwrs(v(2),at)
B4 4 0 V=((u(V(2))-1)*V(3)+u(V(2))*V(3))
R4 4 0 1G
* Ia1
B5 A1 C I=((V(1)/2)*(V(3)+V(4)))
* resistance de fuite
* I have a mathematical reference to calculate that resistance
* for a given tube, but it is not necessary to use it for a power
* tube at the main frequency, add more complexity for nothing more
RA1C A1 C 10meg
CA1C A1 C 11p
* CA1C .5n in case of serious convergence problems

* diode 2
B11 11 0 V=(V(ka)+(V(kb)*V(A2,C)))
R11 11 0 1G
B12 12 0 V=(V(A2,C)+V(eps))
R12 12 0 1G
B13 13 0 V=((abs(V(12)))^1.0847522)
R13 13 0 1G
B14 14 0 V=((u(V(12))-1)*V(13)+u(V(12))*V(13))
R14 14 1 1G
B15 A2 C I=(V(11)/2*(V(13)+V(14)))
RA2C A2 C 10meg
CA2C A2 C 11p

CAA A1 A2 .8p

.ENDS

The following simulation will get it at work:

* GZ34 double alternance redressement with LC filter
X1 4 5 2 1 GZ34
L1 7 0 40H
V2 3 7 sin 0 777.82 50
V3 7 6 sin 0 777.82 50
R3 6 5 175
R2 4 3 175
R1 2 0 4093
C1 2 0 60uF
V1 1 2 DC 5V
* put the model here:

*
.TRAN 10u 10000m
* if you get an out of memory, don't panic when your system is going slow
* and after a while try something like:
*.TRAN 100u 1000m
*.TRAN 1m 1000m
.END

V2, V3, R3 and R2 are the transformator as in the philips data sheet.
L1, C1 are the LC filter as in the data sheet.
plot v(1) will give you the tension on the last (R1).
The straith part of the curve show us an ondulation of 0.7 Vpp AC for 470 
VDC
The first part of the curve show us at it is a second time constant at very 
low frequency,
T=~248 ms. That is typiquely the quind of stuff that can cause a lot of 
trouble in a poor
designed amplifier.
I think at ngspice, that don't have a limited number of components a 
simulation can do,
can be usefull to simulate and analyse such kind of problems.

Best Regards
Dominique Michel

_________________________________________________________________
MSN Hotmail : antivirus et antispam intégrés 
http://www.msn.fr/newhotmail/Default.asp?Ath=f