Re: [Ngspice-users] Incorrect simulation results

[Hugo v. d. M. <s13...@ba...>]

I am using ng-spice rework 14.

I have trimmed the netlist down to:

==========================================
* VBE multiplier, illustrates ng-spice bug

* Some HSpice options
**.options post=2 probe

*Power Supplies
Vccplus 1 0 15
Vccminus 6 0 -15

* Current source
Rcb1 1 2 11.3k
Rcb2 2 0 86.705k
Rce 1 11 1k
Q1 3 2 11 Q2N3906

* VBE multiplier
Rm2 3 4 9.25k
Rm1 4 5 3.25k
Q2 3 4 5 Q2N3904
Rleak 5 6 13.75k

*  Fairchild Semiconductor 2N3906
.MODEL Q2N3906 PNP (Is=1.41f Xti=3 Eg=1.11 Vaf=18.7 Bf=180.7 Ne=1.5 Ise=0
+ Ikf=80m Xtb=1.5 Br=4.977 Nc=2 Isc=0 Ikr=0 Rc=2.5 Cjc=9.728p Mjc=.5776
+ Vjc=.75 Fc=.5 Cje=8.063p Mje=.3677 Vje=.75 Tr=33.42n Tf=179.3p Itf=.4 Vtf=4
+ Xtf=6 Rb=10)

*  Fairchild Semiconductor 2N3904
.MODEL Q2N3904 NPN (Is=6.734f Xti=3 Eg=1.11 Vaf=74.03 Bf=416.4 Ne=1.259
+ Ise=6.734 Ikf=66.78m Xtb=1.5 Br=.7371 Nc=2 Isc=0 Ikr=0 Rc=1 Cjc=3.638p Mjc=.3085
+ Vjc=.75 Fc=.5 Cje=4.493p Mje=.2593 Vje=.75 Tr=239.5n Tf=301.2p Itf=.4 Vtf=4 Xtf=2 Rb=10)

* .tran tstep tstop <tstart <tmax>>
.tran 1u 6000u 4000u 1u

* HSpice output options:
**.probe vout=v(10) vbb=v(3) vb0=v(5) vbe=v(4,5) v1k=v(1,11)
.end
==========================================


Approx HSpice output, iirc:
v(5)=-1.21; v(4,5)=0.654; v(1,11)=1.01; v(3)=1.57

ng-spice output, from results below:
v(5)=-1.47; v(4,5)=9.82e-3; v(1,11)=0.99; v(3)=7.65

Initial Transient Solution
--------------------------

Node                                   Voltage
----                                   -------
1                                           15
6                                          -15
2                                      13.3127
11                                     14.0115
3                                      7.64842
4                                     -1.45624
5                                     -1.46605
vccminus#branch                    0.000984287
vccplus#branch                     -0.00113783


It seems like the Vbe multiplier is the problem, the "current source" is
relatively accurate.

Thanks,
Hugo van der Merwe