Alain,
there is no avalanche breakdown modeled in the standard gummel poon model.
Please look for modern bipolar model documentations like vbic, mextram and hicum.
It is a script under /contrib/vbic which you can use to transform the existing GP model to vbic model as a starting point and the afterwards to play around with vbic model parameters avc1 and avc2 to fit the hopeful available avalanche characteristic data.
Nothing ready for a quick lunch - in other simulators too.
Sorry - Dietmar
If you would like to refer to this comment somewhere else in this project, copy and paste the following link:
Thank everybody for pointing me the VBIC model, link is now bookmarked (and some others too).
I succeed to create some others bjt models.
Thank Holger for the circuit file, I learnt a lot with it during this week.
But I failed to find suitable values for avc1 and avc2, circuit simulation isn't as expected.
Is there a way to evaluate them with some characterics form datasheet?
I made a try with a similar circuit using a 2n2369, result is worst…
Circuit is on the Linear Application Notes, page 93: http://cds.linear.com/docs/Application Note/an47fa.pdf
Hi,
I'm a new ngspice user (and a new spice user) and I should want to know if the
avalanche breakdown effect of a bjt is simulated.
I'm trying to simulate a small part of the following circuit:
http://www.holmea.demon.co.uk/Avalanche/Avalanche.htm
(only +130V, R2, Q1, R7, R4, R8, R5)
Here is the description circuit:
* Pulse generator
.include 2N3904.ckt
VCC 1 0 DC 130
R1 1 2 100k
R2 3 0 3.3k
R3 4 5 22
R4 5 0 10
R5 5 6 47
C1 2 0 50p
Q1 2 3 4 2N3904
.tran 100n 1000U
.plot v(5)
2N3904.ckt
* Model generated on Aug 07, 01
* MODEL FORMAT: SPICE3
.MODEL 2n3904 npn
+IS=1.26532e-10 BF=206.302 NF=1.5 VAF=1000
+IKF=0.0272221 ISE=2.30771e-09 NE=3.31052 BR=20.6302
+NR=2.89609 VAR=9.39809 IKR=0.272221 ISC=2.30771e-09
+NC=1.9876 RB=5.8376 IRB=50.3624 RBM=0.634251
+RE=0.0001 RC=2.65711 XTB=0.1 XTI=1
+EG=1.05 CJE=4.64214e-12 VJE=0.4 MJE=0.256227
+TF=4.19578e-10 XTF=0.906167 VTF=8.75418 ITF=0.0105823
+CJC=3.76961e-12 VJC=0.4 MJC=0.238109 XCJC=0.8
+FC=0.512134 CJS=0 VJS=0.75 MJS=0.5
+TR=6.82023e-08 PTF=0 KF=0 AF=1
In the circuit, C1 replace the open-ended 50 ohms coaxial line.
Regards,
Alain
Alain,
there is no avalanche breakdown modeled in the standard gummel poon model.
Please look for modern bipolar model documentations like vbic, mextram and hicum.
It is a script under /contrib/vbic which you can use to transform the existing GP model to vbic model as a starting point and the afterwards to play around with vbic model parameters avc1 and avc2 to fit the hopeful available avalanche characteristic data.
Nothing ready for a quick lunch - in other simulators too.
Sorry - Dietmar
Alan,
attached my simple test on the transistor, prepared according to Dietmars suggestions:
* Pulse generator
*VCC 1 0 DC 130
*R1 1 2 100k
*R2 3 0 3.3k
*R3 4 5 22
*R4 5 0 10
*R5 5 6 47
*C1 2 0 50p
*output characteristics to see if avalanche effect is modelled
IBE 0 3 1u
VEE 4 0 0
VCE 2 0 1
* QXXXXXXX nc nb ne <ns>
Q1 2 3 4 0 2N3904L4
* Model generated on Aug 07, 01
* MODEL FORMAT: SPICE3
* no avalanche effect included in model!!
.MODEL 2n3904L2 npn
+level=2
+IS=1.26532e-10 BF=206.302 NF=1.5 VAF=1000
+IKF=0.0272221 ISE=2.30771e-09 NE=3.31052 BR=20.6302
+NR=2.89609 VAR=9.39809 IKR=0.272221 ISC=2.30771e-09
+NC=1.9876 RB=5.8376 IRB=50.3624 RBM=0.634251
+RE=0.0001 RC=2.65711 XTB=0.1 XTI=1
+EG=1.05 CJE=4.64214e-12 VJE=0.4 MJE=0.256227
+TF=4.19578e-10 XTF=0.906167 VTF=8.75418 ITF=0.0105823
+CJC=3.76961e-12 VJC=0.4 MJC=0.238109 XCJC=0.8
+FC=0.512134 CJS=0 VJS=0.75 MJS=0.5
+TR=6.82023e-08 PTF=0 KF=0 AF=1
.model 2n3904L4 npn
* VBIC model parameters generated from above data by perl script sgp2vbic
* see http://www.designers-guide.org/VBIC/downloads.html
+ level=4
+ rcx = 2.65711
+ rci = 0.0
+ rbx = 0.634251
+ rbi = 5.203349
+ re = 0.0001
+ is = 1.26532e-10
+ nf = 1.5
+ nr = 2.89609
+ fc = 0.512134
+ cje = 4.64214e-12
+ pe = 0.4
+ me = 0.256227
+ cjc = 3.015688e-12
+ cjep = 7.53922e-13
+ pc = 0.4
+ mc = 0.238109
+ cjcp = 0
+ ps = 0.75
+ ms = 0.5
+ ibei = 6.13333850374693e-13
+ nei = 1.5
+ iben = 2.30771e-09
+ nen = 3.31052
+ ibci = 6.13333850374693e-12
+ nci = 2.89609
+ ibcn = 2.30771e-09
+ ncn = 1.9876
+ vef = 566.483710419377
+ ver = 8.69028854282359
+ ikf = 0.0272221
+ ikr = 0.272221
+ tf = 4.19578e-10
+ xtf = 0.906167
+ vtf = 8.75418
+ itf = 0.0105823
+ tr = 6.82023e-08
+ td = 0
+ ea = 1.05
+ eaie = 1.05
+ eaic = 1.05
+ eane = 1.05
+ eanc = 1.05
+ xis = 1
+ xii = 0.9
+ xin = 0.668948
+ kfn = 0
+ afn = 1
* avalanche parameters added according to
* http://www.designers-guide.org/VBIC/documents/VbicText.pdf, page 13
* You have to play with both parameters to obtain suitable description of real transistor behaviour!
* This is just a guess!!
+ avc1 = 0.02
+ avc2 = 110
* initial condition for transient: V(2) set to 0
*.ic V(2) = 0
.control
*tran 100n 1000U
*plot v(2) v(5)
dc vce 0 150 0.1 ibe 100u 1m 100u
plot vee#branch
.endc
.end
Regards
Holger
Hi,
Thank everybody for pointing me the VBIC model, link is now bookmarked (and some others too).
I succeed to create some others bjt models.
Thank Holger for the circuit file, I learnt a lot with it during this week.
But I failed to find suitable values for avc1 and avc2, circuit simulation isn't as expected.
Is there a way to evaluate them with some characterics form datasheet?
I made a try with a similar circuit using a 2n2369, result is worst…
Circuit is on the Linear Application Notes, page 93:
http://cds.linear.com/docs/Application Note/an47fa.pdf
* Pulse generator
.include 2n2369l4.model
VCC 1 0 DC 100
R1 1 coll 1Meg
R2 base 0 10k
R3 emit 0 50
C1 coll 0 20p
* QXXXXXXX nc nb ne <ns>
Q1 coll base emit 0 Q2N2369L4
* initial condition for transient: V(2) set to 0
.ic V(coll) = 0
.control
tran 1n 1U
plot v(coll) v(emit) v(base)
plot v(emit)
.endc
.end
.model q2n2369l4 npn
+ level=4
+ rcx = .6
+ rci = 0.0
+ rbx = 10
+ rbi = 0
+ re = 0
+ is = 1e-16
+ nf = 1
+ nr = 1
+ fc = .5
+ cje = 4.5p
+ pe = .75
+ me = .2418
+ cjc = 2.83
+ cjep = 0
+ pc = .75
+ mc = 86.19m
+ cjcp = 0
+ ps = 0.75
+ ms = 0
+ ibei = 1.27681307456588e-18
+ nei = 1
+ iben = 9.195e-15
+ nen = 1.389
+ ibci = 7.88022064617809e-18
+ nci = 1
+ ibcn = 0
+ ncn = 2
+ vef = -1.60440280094598e+16
+ ver = -0.689700348076935
+ ikf = .3498
+ ikr = 0
+ tf = 227.6p
+ xtf = 4
+ vtf = 4
+ itf = .3
+ tr = 1.073u
+ td = 0
+ ea = 1.11
+ eaie = 1.11
+ eaic = 1.11
+ eane = 1.11
+ eanc = 1.11
+ xis = 3
+ xii = 1.5
+ xin = 0.9165
+ kfn = 0
+ afn = 1
+ avc1 = .02
+ avc2 = 100
Regards,
Alain
http://cds.linear.com/docs/Application Note/an47fa.pdf
Sorry, hoping this will work…
http://cds.linear.com/docs/Application%20Note/an47fa.pdf