Martin Genet <mgenet <at> lbl.gov> writes:
>
> Dear GNUPlot:
>
> I have three questions:
>
> 1) Suppose I plot on the same graph a first curve using one color and axes
xy1, and a second curve using another
> color and axes xy2. Is there a way to have y1 axis, tics & label of the same
color as the first curve, and y2
> axis, tics & label of the same color as the second curve? (Actually, by hand I
know how to do the label and
> tics…but the axis?)
either by defining some arrows covering the axes:
set arrow 1 from graph 0,0 to graph 0,1 lt 1 lw 2
set arrow 2 from graph 1,0 to graph 1,1 lt 2 lw 2
or by using 'multiplot' with fixed margins:
reset
set bmargin 2
set lmargin 7
set rmargin 7
set tmargin 2
set multiplot
unset xtics
set ytics nomirror
unset y2tics
set border 2 linetype 1 linewidth 2
plot sin(x) axes x1y1 linetype 1 notitle
unset xtics
unset ytics
set y2tics nomirror
set border 8 linetype 2 linewidth 2
plot 2.*cos(x) axes x1y2 linetype 2 notitle
set xtics nomirror
unset ytics
unset y2tics
set border 1 linetype -1 linewidth 1
plot sin(x) notitle
unset multiplot
> 2) Suppose I plot points in a 3D graph. Is there a point type representing a
small cube, similar to the small
> square existing for 2D graphs? (I know a small square is possible in 3D, but I
don't really like it.)
as far as i know, no
this 'point' should be a 3-dim object, you could simulate this
by placing little 'plots' where you want to have cubes:
datafile.dat:
-1 -1 -1
-1 1 -1
-1 1 1
-1 -1 1
-1 -1 -1
1 -1 -1
1 1 -1
1 1 1
1 -1 1
1 -1 -1
plot script:
set xrange [-10:10]
set yrange [-10:10]
set zrange [-10:10]
splot 'datafile.dat' using 1:2:3 with lines linetype 1, \
'' using (0.1*$1+1.):(0.1*$2-2.):(0.1*$3+2.) w l lt 1, \
'' using (0.5*$1-3.):(0.5*$2+2.):(0.5*$3-2.) w l lt 1
> 3) Suppose I plot points using crosses. Is there a way to change the thickness
of the lines of the cross?
plot ... with points linewidth 3
> Many thanks in advance for your precious help.
>
> Martin
|
