gnuplot-info

[Gnuplot-info] Use of multiplot with "set object"

[dbateman <dba...@fr...>]

I'm trying to use multiplot and "set object" together to set a background
colour and then a colour for each of the plot. I tried something like

reset
set object 1 rectangle from screen 0,0 to screen 1,1 behind fc rgb "#FF0000"
set multiplot layout 2, 1 title "Plot 1"
set object 2 rectangle from graph 0,0 to graph 1,1 behind fc rgb "#00FF00"
plot sin(x)/x
set object 3 rectangle from graph 0,0 to graph 1,1 behind fc rgb "#0000FF"
plot sin(x)/x
unset mulitplot

but only the last of the plots appeared. It seems that the background colour
appears only behind the last plot rather than all of the plots. I tried this
with the WXT and X11 terminals with the same results. Is there a way to put
the background colour behind all of the plots?

Regards
David

-- 
View this message in context: http://old.nabble.com/Use-of-multiplot-with-%22set-object%22-tp27173363p27173363.html
Sent from the Gnuplot - User mailing list archive at Nabble.com.

Re: [Gnuplot-info] Use of multiplot with "set object"

[Thomas S. <t.s...@fz...>]

reset
set object 1 rectangle from screen 0,0 to screen 1,1 behind fc rgb "#FF0000"
set object 2 rectangle from graph 0,0 to graph 1,1 behind fc rgb "#00FF00"
set multiplot layout 2, 1 title "Plot 1"
plot sin(x)/x
unset object 1
set object 2 fc rgb "#0000FF"
plot sin(x)/x
unset multiplot


dbateman wrote:
> 
> I'm trying to use multiplot and "set object" together to set a background
> colour and then a colour for each of the plot. I tried something like
> 
> reset
> set object 1 rectangle from screen 0,0 to screen 1,1 behind fc rgb
> "#FF0000"
> set multiplot layout 2, 1 title "Plot 1"
> set object 2 rectangle from graph 0,0 to graph 1,1 behind fc rgb "#00FF00"
> plot sin(x)/x
> set object 3 rectangle from graph 0,0 to graph 1,1 behind fc rgb "#0000FF"
> plot sin(x)/x
> unset mulitplot
> 
> but only the last of the plots appeared. It seems that the background
> colour appears only behind the last plot rather than all of the plots. I
> tried this with the WXT and X11 terminals with the same results. Is there
> a way to put the background colour behind all of the plots?
> 
> Regards
> David
> 
> 

-- 
View this message in context: http://old.nabble.com/Use-of-multiplot-with-%22set-object%22-tp27173363p27174830.html
Sent from the Gnuplot - User mailing list archive at Nabble.com.

Re: [Gnuplot-info] Use of multiplot with "set object"

[dbateman <dba...@fr...>]

Thomas Sefzick wrote:
> 
> reset
> set object 1 rectangle from screen 0,0 to screen 1,1 behind fc rgb
> "#FF0000"
> set object 2 rectangle from graph 0,0 to graph 1,1 behind fc rgb "#00FF00"
> set multiplot layout 2, 1 title "Plot 1"
> plot sin(x)/x
> unset object 1
> set object 2 fc rgb "#0000FF"
> plot sin(x)/x
> unset multiplot
> 
> 

That works though it seems a bit strange to me to unset an object before
plotting the final plot.. 

Best Wishes
David

-- 
View this message in context: http://old.nabble.com/Use-of-multiplot-with-%22set-object%22-tp27173363p27176275.html
Sent from the Gnuplot - User mailing list archive at Nabble.com.

Re: [Gnuplot-info] Use of multiplot with "set object"

[Thomas S. <t.s...@fz...>]

there is no 'final' plot. 'multiplot' allows a series of
individual plots on the same canvas. and all defined
objects, arrows, labels, ... are drawn for each of
these plots.
the manual says (in the 'multiplot' section):

> Just about everything else that can be set is applied
> to each plot, too. If you want something to appear
> only once on the page, for instance a single time stamp,
> you'll need to put a set time/unset time pair around
> one of the plot, splot or replot commands within the
> set multiplot/unset multiplot block.

the red background box should be drawn only once
and at the beginning of the multiplot series,
otherwise it will cover everything plotted so far.


dbateman wrote:
> 
> 
> 
> Thomas Sefzick wrote:
>> 
>> reset
>> set object 1 rectangle from screen 0,0 to screen 1,1 behind fc rgb
>> "#FF0000"
>> set object 2 rectangle from graph 0,0 to graph 1,1 behind fc rgb
>> "#00FF00"
>> set multiplot layout 2, 1 title "Plot 1"
>> plot sin(x)/x
>> unset object 1
>> set object 2 fc rgb "#0000FF"
>> plot sin(x)/x
>> unset multiplot
>> 
>> 
> 
> That works though it seems a bit strange to me to unset an object before
> plotting the final plot.. 
> 
> Best Wishes
> David
> 
> 

-- 
View this message in context: http://old.nabble.com/Use-of-multiplot-with-%22set-object%22-tp27173363p27179525.html
Sent from the Gnuplot - User mailing list archive at Nabble.com.