use either histograms or boxes, not both at the same time.
histograms:
set style fill solid 1 border -1
set style data histograms
set style histogram rowstacked
set xtics rotate
plot '/data/personal/prac_data.dat' using 2:xtic(1) title "Personal", ''
using 3 title "On Ensemble", '' using 4 title "Group", '' using 5 title
"Live"
boxes:
set style fill solid 1 border -1
set xdata time
set timefmt "%y%m%d"
set xtics rotate
plot '/data/personal/prac_data.dat' using 1:($2+$3+$4+$5) title "Live" with
boxes, '' using 1:($2+$3+$4) title "Group" with boxes, '' using
1:($2+$3)title "On Ensemble" with boxes, '' using 1:2 title "Personal" with
boxes
xuxa wrote:
>
> I am a musician trying to create a graph that tracks my daily practice in
> four categories. I just read about other people's issues with stacked
> histograms but have not been able to translate the responses to my
> particular situation.
>
> gnuplot doesn't seem to be including all the values in the histogram bars.
> For example, with the following data:
>
> # Per On Grp Live
> 090621 1 2 3 4
> 090622 0 1 2 3 # June 22
> 090623 0 0 1 2
> 090624 0 0 0 1
> 090625 2 3 4 5
> ... (plus lots of other, more random data)...
>
> And the following script...
>
> set style fill solid 1 border -1
> set style data histograms
> set style histogram rowstacked
> set xdata time
> set timefmt "%y%m%d"
> set xtics rotate
> plot '/data/personal/prac_data.dat' using 1:2 title "Personal" with boxes,
> '' using 1:3 title "On Ensemble" with boxes, '' using 1:4 title "Group"
> with boxes, '' using 1:5 title "Live" with boxes
> pause -1 "Hit any key to continue"
>
> I get this:
> http://onensemble.org/krisShare/gnuplot_hist_prob.jpg
>
> Notice how only the last value in each row is actually being used in many
> of the bars.
>
> Any ideas what I'm doing incorrectly?
>
> Kris
>
>
--
View this message in context: http://www.nabble.com/Stacked-histogram-bars-not-properly-added-tp25987063p25987778.html
Sent from the Gnuplot - User mailing list archive at Nabble.com.
|
