Mandelbrot set when 512x512 isn't big enough, plus two compiler bugs

[Yet Another Troll]

I think I found two compiler bugs, one involving DRAW, both involving DEFFN functions. This gives incorrect results. wh% is the window height set by GET_GEOMETRY:

hh% = Min(225, wh% / 3)
DefFn HY(H) = wh% - 1 - Int(hh% * Log1P(H * 999999.0) / Log(1000000.0))

This compiles but fails with "Function HY not defined" when run:

Draw i% - 1, wh% - 1 To i% - 1, @HY(1.0 * Hist%(maxx% - i%) / HTot%)

Workarounds were easy enough in Procedure Histogram:

#!/lbin/ybasic

! Shamelessly ripped off, umm, I meant, adapted, yeah yeah that's the ticket, from,
! https://hackaday.com/2020/06/23/boot-to-basic-box-packs-a-killer-graphics-engine/

! Plus 'tweaks' to see what the original cuts off from the left, top, and bottom

Program Manglebrot

 OpenW 1
 Pause 0.05
 ClearW
 ShowPage

 Get_Screensize sx%, sy%, sw%, sh%
 Get_Geometry 1, wx%, wy%, ww%, wh%

 Print "Screen", sx%, sy%, sw%, sh%
 Print "Window", wx%, wy%, ww%, wh%

 maxx% = 500 ! 77
 w = ww% ! 240
 h = wh% ! 216
 hh = Int(h / 2)
 maxCol = 255

 ! Map iteration counts to purrty color palette

 Dim map%(maxx%)

 For i% = 0 To 99
  ! Black to Red (Make first few shades super easy to distinguish)
  map%(0 + i%) = Color_RGB(Log1P((i% / 99.0) * 49.0) / Log(50.0), 0, 0)
  ! Red to Violet
  map%(100 + i%) = Color_RGB(1, 0, i% / 99.0)
  ! Violet to Blue
  map%(200 + i%) = Color_RGB(1 - i% / 99.0, 0, 1)
  ! Blue to Aqua
  map%(300 + i%) = Color_RGB(0, i% / 99.0, 1)
  ! Aqua to White
  map%(400 + i%) = Color_RGB(i% / 99.0, 1, 1)
 Next i%

 map%(0) = Color_RGB(0, 0, 0)
 ! map%(1) = Color_RGB(1, 0, 0)
 ! map%(2) = Color_RGB(0, 1, 0)
 ! map%(3) = Color_RGB(0, 0, 1)
 map%(maxx% - 1) = Color_RGB(1, 1, 1)

 ! Are there differences in the visible area between platforms?
 Color Color_RGB(0, 1, 0)
 PBox -1, -1, ww% + 2, wh% + 2

 ! Flash the palette
 For x% = 0 To ww% - 1
  i% = (1.0 * x% / ww%) * (maxx% - 1)
  Color map%(i%)
  Draw x%, 0 To x%, wh% - 1
  ShowPage
 Next x%
 Pause 1

 ! Are there differences in the visible area between platforms?
 Color Color_RGB(0, 1, 0)
 PBox -1, -1, ww% + 2, wh% + 2

 ! Set up histogram
 Dim Hist%(maxx%)
 Clr Hist%()
 Clr HTot%

 ! Refresh timer
 Clr PrevTime, CurrTime
 ! PrevTime = STimer

 Start = CTimer

 ! Let's goooo

 For py = 0 To hh

  py1 = max(py, h - 1 - py)

  ! Keep magic numbers as is to match the original program
  ! scaleY = (py / h) * 2.0 - 1.0
  ! and simply kludge the result to show more of the "hair"
  scaleY = Abs((py / hh) * 1.15 - 1.15)

  CurrTime = STimer
  If (CurrTime <> PrevTime) Or ((hh - 5) < py)
   @Histogram
   ShowPage
   U$ = "########"
   Print Chr$(13); py Using U$; py1 Using U$; ! h - py Using U$; 
   Print scaleY Using "###.#########"; " "; HTot%;
   ShowPage
   PrevTime = STimer
  EndIf

  For px = 0 to w - 1 ! I can haz DO CONCURRENT plz can I?

   ! It's just a jump to the left...
   ! Keep magic numbers as is to match the original program
   ! scaleX = (px / w) * 3.0 - 2.0
   ! Forget that noise lol
   scaleX = (px / w) * 2.5 - 2.005

   Clr i%, x, y ! , vy, vx

   Clr x2, y2

   Do
    ! Pseudocode from,
    ! https://en.wikipedia.org/wiki/Plotting_algorithms_for_the_Mandelbrot_set
    ! shows "while (x2 + y2 ≤ 4 and..." Is the difference significant?
    ! Exit If 4.0 <= (x2 + y2)
    Exit If 4.0 < (x2 + y2)
    xx = x2 - y2 + scaleX
    y = 2.0 * x * y + scaleY
    x = xx
    Inc i%
    Exit If i% = maxx%
    x2 = x * x
    y2 = y * y
   Loop

   ! col = MaxCol * i% / maxx%
   Color map%(i% - 1)
   Draw px, py To px, py1

   ! Synch update histogram
   Inc Hist%(i% - 1)
   Inc HTot%

  Next px

 Next py

 ShowPage

 ! Histogram

 @Histogram
 ShowPage

 Print
 Print wx%, wy%, ww%, wh%, hh, py, px
 C = CTimer - Start
 Print HTot%; " points in "; Round(C, 2); " CPU seconds"
 Print Round(HTot% / C, 2); " points / CPU second"

 If Android?
  Pause 20
 EndIf

 Print 
 Print "OK"
End

Procedure Histogram
 Local hh%, i%, HY
 hh% = Min(225, wh% / 3)

 ! BUG: Works in interpreter, incorrect result when compiled
 ! DefFn HY(H) = wh% - 1 - Int(hh% * Log1P(H * 999999.0) / Log(1000000.0))
 DefFn HY(H) = Int(wh% - 1 - Int(hh% * Log1P(H * 999999.0) / Log(1000000.0)))

 Color Color_RGB(0.2, 0.2, 0.2, 0.5)
 PBox 0, wh% - 1, maxx% - 1, @HY(1)

 Color Color_RGB(0.5, 0.5, 0.5, 0.5), Color_RGB(0, 0, 0, 0)
 DefText 1, 0.05, 0.06, 0

 For i% = 0 To 10
  HY = @HY(i% / 100000.0)
  Draw 0, HY To maxx% - 1, HY
  HY = @HY(i% / 10000.0)
  Draw 0, HY To maxx% - 1, HY
  HY = @HY(i% / 1000.0)
  Draw 0, HY To maxx% - 1, HY
  HY = @HY(i% / 100.0)
  Draw 0, HY To maxx% - 1, HY
  HY = @HY(i% / 10.0)
  Draw 0, HY To maxx% - 1, HY
 Next i%

 LText maxx% + 3, -4 + @HY(1.0),   "100 %"
 LText maxx% + 3, -4 + @HY(0.1),   "10.0%"
 LText maxx% + 3, -4 + @HY(0.01),  "1.00%"
 LText maxx% + 3, -4 + @HY(0.001), "0.10%"
 LText maxx% + 3, -4 + @HY(0.0001), "0.01%"
 LText maxx% + 3, -5 + @HY(0.00001), "0.001%"

 HY = @HY(0.0000025)
 Draw 0, HY To maxx% - 1, HY
 LText maxx% + 3, HY - 5, "0.00025%"

 HY = @HY(0.0000001)
 Draw 0, HY To maxx% - 1, HY
 LText maxx% + 3, wh% - 7, "0.00001%"

 If HTot% > 0
  For i% = 1 To maxx%
   If 0 < Hist%(maxx% - i%)
    Color map%(maxx% - i%)
    ! BUG: Works in interpreter, "Function HY not defined" when compiled
    ! Draw i% - 1, wh% - 1 To i% - 1, @HY(1.0 * Hist%(maxx% - i%) / HTot%)
    HY = @HY(1.0 * Hist%(maxx% - i%) / HTot%)
    Draw i% - 1, wh% - 1 To i% - 1, HY
   EndIf
  Next i%
 EndIf

Return