#2426 No result for definite integral (II)

[christoph reineke]

Enter in Maxima:

integrate(sin(x)/x*log(x),x,0,inf)

and Maxima returns:

integrate((log(x)*sin(x))/x,x,0,inf)

The correct result is: -(%pi*gamma)/2, gamma=Euler's constant.

build_info("5.27.0","2012-04-24 08:52:03","i686-pc-mingw32","GNU Common Lisp (GCL)","GCL 2.6.8")

Regards

Chris

[Aleksas]

Problem: integrate(sin(x)*log(x)/x,x,0,inf)

We use laplace integral transformations metrhod.

(%i1) declare(integrate,linear)$
(%i2) assume(s>0)$

(%i3) S:'integrate(sin(x)*log(x*a)/x,x,0,inf)$
(%i4) f:first(S);
(%o4) (sin(x)*log(a*x))/x
(%i5) laplace(%,a,s);
(%o5) ((log(x)-log(s)-%gamma)*sin(x))/(s*x)
(%i6) integrate(%,x,0,inf),expand;
(%o6) integrate((log(x)*sin(x))/x,x,0,inf)/s-(log(s)*integrate(sin(x)/x,x,0,inf))/s-(%gamma*integrate(sin(x)/x,x,0,inf))/s
(%i7) ev(%, nouns);
(%o7) integrate((log(x)*sin(x))/x,x,0,inf)/s-(%pi*log(s))/(2*s)-(%gamma*%pi)/(2*s)
(%i8) eq1:-S=ilt(-%,s,a);
(%o8) -integrate((sin(x)*log(a*x))/x,x,0,inf)=-integrate((log(x)*sin(x))/x,x,0,inf)+ilt((%pi*log(s))/(2*s),s,a)+(%gamma*%pi)/2

(%i9) S1:'integrate(sin(a*x)*log(x)/x,x,0,inf)$
(%i10) f:first(S1);
(%o10) (log(x)*sin(a*x))/x
(%i11) laplace(%,a,s);
(%o11) log(x)/(x^2+s^2)
(%i12) integrate(%,x,0,inf);
(%o12) (%pi*log(s))/(2*s)
(%i13) eq2:S1=ilt(%,s,a);
(%o13) integrate((log(x)*sin(a*x))/x,x,0,inf)=ilt((%pi*log(s))/(2*s),s,a)

(%i14) subst(a=1,[eq1,eq2]);
(%o14) [-integrate((log(x)*sin(x))/x,x,0,inf)=-integrate((log(x)*sin(x))/x,x,0,inf)+ilt((%pi*log(s))/(2*s),s,1)+(%gamma*%pi)/2,integrate((log(x)*sin(x))/x,x,0,inf)=ilt((%pi*log(s))/(2*s),s,1)]
(%i15) solve(%,[integrate((log(x)*sin(x))/x,x,0,inf),ilt((%pi*log(s))/(2*s),s,1)]);
(%o15) [[integrate((log(x)*sin(x))/x,x,0,inf)=-(%gamma*%pi)/2,ilt((%pi*log(s))/(2*s),s,1)=-(%gamma*%pi)/2]]

(%i16) solution:%[1][1];
(%o16) integrate((log(x)*sin(x))/x,x,0,inf)=-(%gamma*%pi)/2

Best
Aleksas D

[christoph reineke]

Aleksas,

thank you very much. Brlliant. The master of integrals... ;-))

All the best,

Chris