[JVCL-Checkins] CVS: dev/JVCL3/devtools/MakePNG MakePNG.dof,NONE,1.1 MakePNG.dpr,NONE,1.1 MakePNGUtils.pas,NONE,1.1

[Peter T. <pe...@us...>]

Update of /cvsroot/jvcl/dev/JVCL3/devtools/MakePNG
In directory sc8-pr-cvs1:/tmp/cvs-serv4702/JVCL3/devtools/MakePNG

Added Files:
	MakePNG.dof MakePNG.dpr MakePNGUtils.pas 
Log Message:
- Copied jvcl/devtools and jvcl/examples dev/JVCL3
- Copied JVCLConvert *.dat files to dev/JVCL3/converter

--- NEW FILE: MakePNG.dof ---
[Directories]
OutputDir=..\bin
UnitOutputDir=..\dcu

--- NEW FILE: MakePNG.dpr ---
program MakePNG;

{$APPTYPE CONSOLE}
uses
  MakePNGUtils in 'MakePNGUtils.pas',
  JTools in '..\Common\JTools.pas';

begin
  Run;  
end.

--- NEW FILE: MakePNGUtils.pas ---
unit MakePNGUtils;

interface

procedure Run;

implementation
uses
  Windows, SysUtils, Classes, Graphics, JTools,
  pngImage; // download from http://pngdelphi.sourceforge.net/ 

procedure ShowHelp;
begin
  writeln('');
  writeln('');
  writeln('MakePNG: BMP to PNG converter');
  writeln('Copyright (c) 2002 by Peter Thornqvist and JEDI');
  writeln('');
  writeln('Usage:');
  writeln(#9,ExtractFileName(ParamStr(0)),' <filemask> <outpath>');
  writeln('');
  writeln(#9'<filemask>'#9'sets the files to search for. Default is <curdir>\*.bmp');
  writeln(#9'<outpath>'#9'folder to save the PNG files to. Default is <curdir>');
end;

procedure MakePNGFiles(const FileMask, OutputFolder: string);
var
  fd: TWin32FindData;
  H: THandle;
  P: TPNGObject;
  B: TBitmap;
begin
  H := FindFirstFile(PChar(FileMask), fd);
  if H <> INVALID_HANDLE_VALUE then
  begin
    P := TPNGObject.Create;
    B := TBitmap.Create;
    try
      repeat
        try
          writeln('Processing ', string(fd.cFileName), '...');
          B.LoadFromFile(fd.cFileName);
          P.Assign(B);
          P.SaveToFile(OutputFolder + UpperCase(ChangeFileExt(fd.cFileName, '.PNG')));
        except
          writeln('Error processing ', string(fd.cFileName), '!');
          // probably not a valid BMP
        end;
      until not FindNextFile(H, fd);
    finally
      B.Free;
      P.Free;
    end;
    if H <> INVALID_HANDLE_VALUE then
      Windows.FindClose(H);
  end;
end;

procedure Run;
var
  FileMask, OutputFolder: string;
begin
  try
    if GetCmdSwitchValue('h', ['-', '/'], FileMask, true) or
      GetCmdSwitchValue('?', ['-', '/'], FileMask, true) then
    begin
      ShowHelp;
      Exit;
    end;
    case ParamCount of
      0:
        begin
          FileMask := ExtractFilePath(ParamStr(0)) + '*.bmp';
          OutputFolder := ExtractFilePath(ParamStr(0));
        end;
      1:
        begin
          FileMask := ParamStr(1);
          OutputFolder := ExtractFilePath(ParamStr(0));
        end;
    else
      begin
        FileMask := ParamStr(1);
        OutputFolder := ParamStr(2);
      end;
    end;
    ForceDirectories(OutputFolder);
    MakePNGFiles(FileMask, IncludeTrailingPathDelimiter(OutputFolder));
  except
    on E: Exception do
      writeln('ERROR: ', E.Message);
  end;
end;

end.