#559 Insert (scalable) images as axis labels (e.g. to add LaTeX in GUI terminals)

[armando sano]

I use qt and wxt terminals increasingly to quickly create plots, and export them directly to pdf or svg, as a convenient way to generate quality figures, rather than using cairolatex and post-compilation by latex. The problem with this approach is that I can't easily typeset math labels properly, à la LaTeX. In fact, I use qt/wxt terminals for streaming data, so cairolatex + pdflatex is too slow to work for dynamic display.

I have been playing with inserting latex labels using set pixmap 'xlabel.png' at graph 0.5,-0.1 center, where xlabel.png is a figure generated by pdflatexing a file like

\documentclass[12pt]{standalone}
\usepackage{amsmath,amsthm,amssymb,amsfonts}
\begin{document}
$\boldsymbol{\hat\alpha}_i$
\end{document}

and converting it to png using convert -density 200 -quality 85 (imagemagick) This works relatively well, but is hacky, and requires manual placement and adjustment of margins, rotation for y label etc. Some of it can be automated as we can call some of these 3rd-party utilities using < in the filename argument of pixmap.

But one of the main issue is that the size of the label image depends on pixel density and rescaling the label image in pixmap with the height or width options scrambles it. The export from qt as a pdf is of poor quality.

The old ticket https://sourceforge.net/p/gnuplot/feature-requests/413/ would solve that issue, but I'd propose to go even further: it would be great if gnuplot could handle all (or most) of the intermediate steps: calling latex on the label text $\boldsymbol{\hat\alpha}_i$, rotating, scaling, placing the label, adjusting margins so that we can have latex labels inserted in lots of terminals.

Being able to add latex labels elsewhere in the plot would also be useful (keys, anywhere really, just like pixmap). These label images could be temporary images in /tmp that only need to be recompiled if the labels have changed. It would add so much to be able to add LaTeX snippets to other terminals in a more convenient way than epslatex/cairolatex, on the fly! :)

[Ethan Merritt]

First thoughts:

I do not fully understand your workflow or your speed requirements, but let me suggest a possible alternative to your described use of qt or wxt followed by export to svg or pdf. Suppose you want to create a standalone pdf file with latex labels. I will use a plot of the complex Airy function from the gnuplot demo set as an example. The file airy.gp is here after some fiddling to change the label text to latex:

set terminal tikz standalone size 5in,3in
set output 'airy.tex'
#
set border -1 front lt black linewidth 1.000 dashtype solid
set view 45, 51, 0.9, 1
set samples 51, 51
set isosamples 51, 51
set xyplane relative 0
unset cbtics
set title '{$\Re( Ai(x+iy) )$}'
set xrange [ -4.00000 : 4.00000 ]
set xlabel '$x$'
set yrange [ -4.00000 : 4.00000 ]
set ylabel '$iy$'
set zrange [ -4.00000 : 2.00000 ]
set cbrange [-pi:pi]
set cblabel '${\left\vert Ai(x + iy) \right\vert}$'
set pm3d border lt black linewidth 0.5
set pm3d lighting primary 0.5 specular 0.5 spec2 0
set palette defined ( 0 0.5451 0 0, 1 1 0.8431 0 )
#
splot '++' using 1:2:(real(Ai(x + y*I))):(arg(Ai(x + y*I))) notitle with pm3d

# Run pdflatex to update the display
unset output
!pdflatex airy

• Running gnuplot on this file, e.g. gnuplot airy.gp will produce an output file airy.pdf.
• Display this file and leave the viewer open, e.g. okular airy.pdf&.
• To do further work, tweak the labels, change the plot, whatever, reopen the file airy.gp in the editor. Make your changes and - still from inside the editor - rerun gnuplot on the edited file.
• gnuplot will reexecute the commnds, invoke pdflatex, and the displayed pdf will update in the viewer.

On my klunky old desktop machine at home it takes approximately 6 seconds from the time I invoke gnuplot the editor to the time that the display updates with the revised file. That's not instantaneous, but then again using the export widget to produce a separate file is not instantaneous either.