#793 linetype dot/dash pattern dont work
It test the example from website:
#
# Demonstrate explicit choice of both dot/dash pattern (linetype) and color (linecolor).
#
reset
set xrange [-0.5:3.5]
set yrange [-1:1.4]
set bmargin 7
unset ytics
unset xtics
#
set title "Independent colors and dot/dash styles"
unset colorbox
#
# define line styles using explicit rgbcolor names
#
set style line 1 lt 2 lc rgb "red" lw 3
set style line 2 lt 2 lc rgb "orange" lw 2
set style line 3 lt 2 lc rgb "yellow" lw 3
set style line 4 lt 2 lc rgb "green" lw 2
#
set label 1 'set style line 1 lt 2 lc rgb "red" lw 3' at -0.4, -0.25 tc rgb "red"
set label 2 'set style line 2 lt 2 lc rgb "orange" lw 2' at -0.4, -0.35 tc rgb "orange"
set label 3 'set style line 3 lt 2 lc rgb "yellow" lw 3' at -0.4, -0.45 tc rgb "yellow"
set label 4 'set style line 4 lt 2 lc rgb "green" lw 2' at -0.4, -0.55 tc rgb "green"
set label 5 'plot ... lt 1 lc 3 lw 3' at -0.4, -0.65 tc lt 3
set label 6 'plot ... lt 3 lc 3 lw 2' at -0.4, -0.75 tc lt 3
set label 7 'plot ... lt 5 lc 3 lw 3' at -0.4, -0.85 tc lt 3
#
set xlabel "You will only see dashed lines if your current terminal setting permits it"
#
show style line
#
# draw some plots
#
plot cos(x) ls 1 title 'ls 1', \
cos(x-.2) ls 2 title 'ls 2',\
cos(x-.4) ls 3 title 'ls 3',\
cos(x-.6) ls 4 title 'ls 4', \
cos(x-.8) lt 1 lc 3 title 'lt 1 lc 3', \
cos(x-1.) lt 3 lc 3 title 'lt 3 lc 3', \
cos(x-1.2) lt 5 lc 3 title 'lt 5 lc 3'
#
But Gnuplot dont show different linetypes only the color and line width change from line to line.
I'm running a gentoo linux
sci-visualization/gnuplot-4.2.5-r1
I'm not sure if this are enough infos for you, if not please contact me dm <at> tu-clausthal.de
Best,
David
Please have a look at the xlabel, and type:
set termoption dashed
replot
after the scribt given above.
Juergen
Hi Juergen,
first of all thanks for that answer but if i try
------
gnuplot> set termoption dashed
^
This option cannot be changed using 'set termoption'
------
I'm really new with gnuplot so i have no clue whats going wrong.
Best David
OK, sorry, I did not check your version.
Please have a short look at help pages like "term" and "output". Then type "show terminal" to get to know which terminal you use. I suppose it is either "x11" or "wxt". The wxt terminal is the newer and better one, but in 4.2.x, only x11 can do dashed lines. So type
set term x11 dashed
to get them. But please note that dashed lines in interactive terminals are not utterly useful. And for file output, you likely want to use terminals like postscript, pdf or png, which all support dashed lines.
Juergen
Hi Juergen,
i have that prob even if i use terminals like SVG, which i want to use! So at the end it is not a terminal setting problem ... i will verify that tomorrow!
Best,
David
Have you tried "set term svg dashed"?
Oh my mistake :( ... now it works but if i add "set term svg dashed" the svg file have an other size :-/ thats very strange or?
Here my code:
-----
set terminal svg size 1024 768
set output './atzrr_avg.svg'
set size 1, 1
set origin 0, 0
set ylabel 'time / millisec'
set xlabel 'penetration volume / %'
set term svg dashed
set data style lines
set xrange [ 0 : 0.14 ]
set multiplot
set key right top spacing 2.0
# dlr line
set style line 1 lt rgb "red" lw 2 pt 3
# ist lines
set style line 2 lt 3 lc rgb "#00FF00" lw 3 pt 4 # lime
set style line 3 lt 1 lc rgb "#008000" lw 3 pt 5 # green
set style line 4 lt 1 lc rgb "#0000FF" lw 3 pt 6 # blue
set style line 5 lt 1 lc rgb "#00FFFF" lw 3 pt 7 # aqua
set title 'atzrr / avg timing - VPS vs. IST' 0,-1
plot 0 notitle, \
'atzrr_afnt_dlr' using 1:2 title 'dlr-avg' ls 1 with lp, \
'atzrr_afnt_0.009_v1031550_i576432.v115' using 1:2 title 'ist-avg (576432)' ls 2 with lp, \
'atzrr_afnt_0.0114_v513422_i286881.v91' using 1:2 title 'ist-avg (286881)' ls 3 with lp, \
'atzrr_afnt_0.0137_v300352_i169908.v76' using 1:2 title 'ist-avg (169908)' ls 4 with lp, \
'atzrr_afnt_0.02_v103933_i55620.v53' using 1:2 title 'ist-avg (55620)' ls 5 with lp, \
0 notitle
-----
and here is the result
http://www2.in.tu-clausthal.de/~dmainzer/tmp/printDashed.svg
and the same gnuplot only without the "set term svg dashed"
http://www2.in.tu-clausthal.de/~dmainzer/tmp/printNoDashed.svg
it looks very different in size :-( ... is there a command to fix it?
And a lot of thanks to Juergen!!
Best,
David
You can experiment a little with the exact commands... I guess that you will be fine if you simply merge the "set term" lines:
set term svg size 1024 768 dashed
Juergen
thank you very much :) now everything works fine for me :)
Best,
David
Fine. Would you please close this issue, then. Because I can't...
Thanks,
Juergen
Sorry, but i can't close this issue too :-/
Best,
David