erc-help — Archive of problems, bugs, features, news

[Erc-help] url buttons

[Sven G. <sv...@xe...>]

Hello,
i just build erc from the cvs tree in xemacs, but url buttons were not
working. After i patched with Adrian Archners patch (this mailing list
nov 2003 erc-widget-press-button) it worked. 

Could you include that xemacs fix in the cvs tree? Thank you

Best regards

Sven Grundmann

[Erc-help] Re: erc-nicklist.el --- mIRC style nicklists.

[<boj...@dd...>]

Lawrence Mitchell <we...@gm...> writes:

Oh, and there's some parenthesis error here:

>        buffer
>        window))))
>     (message "%s" (get-text-property point 'erc-nicklist-nick))))

-- 
Johan Bockgård

[Erc-help] Re: erc-nicklist.el --- mIRC style nicklists.

[<boj...@dd...>]

Lawrence Mitchell <we...@gm...> writes:

[...]
> (defun erc-nicklist-make-window ()
>   "Create an ERC nicklist window.
>
> See also `erc-nicklist-window-size'."
>   (let ((width (floor (* (window-width) (/ erc-nicklist-window-size 100.0))))
>         (buffer (erc-nicklist-buffer-name))
>         window)
>     (split-window-horizontally (- width))
>     (setq window (next-window))

split-window* returns the newly created window, so this could be
simplified.

>     (set-window-buffer window (get-buffer buffer))

Should that be `get-buffer-create'?

>     (with-current-buffer buffer
>       (set-window-dedicated-p window t))))

-- 
Johan Bockgård

Re: [Erc-help] erc-nicklist.el --- mIRC style nicklists.

[Jeremy Maitin-S. <jb...@at...>]

Lawrence Mitchell <we...@gm...> writes:

> Here's a proof-of-concept implementation of nicklists for ERC.
> That is, a separate buffer which just displays nicks.  This is a
> bit like erc-speedbar, but not quite as invasive, and doesn't
> require use of a new frame.

> [snip: implementation]

It appears this is a basically a non-invasive, toned down version of the
channel info buffers.  I know replacing channel info buffers has been on
the todo list for quite a while, and if it were expanded to include more
of the functionality of channel info buffers, it would certainly justify
ripping out all of the channel info buffer code from erc.el.

A few comments:

 - `loop' is really nasty; it makes me cringe just to look at it; are
   you sure you want to use it? ;)

 - I believe erc.el already includes a function for obtaining a sorted
   list of nicks.

I also spotted what appear to be several (minor) bugs; I will send some
fixes later.

-- 
Jeremy Maitin-Shepard

[Erc-help] erc-nicklist.el --- mIRC style nicklists.

[Lawrence M. <we...@gm...>]

Here's a proof-of-concept implementation of nicklists for ERC.
That is, a separate buffer which just displays nicks.  This is a
bit like erc-speedbar, but not quite as invasive, and doesn't
require use of a new frame.

Comments welcome, it's mildly tested here, but that's no
guarantee that it'll actually work.

;;; erc-nicklist.el --- Display channel nicknames in a side buffer.

;; Copyright (C) 2004 Lawrence Mitchell <we...@gm...>
;; Filename: erc-nicklist.el
;; Version: 1
;; Author: Lawrence Mitchell <we...@gm...>
;; Created: 2004-04-30
;; Keywords: IRC chat client Internet

;; COPYRIGHT NOTICE

;; This program is free software; you can redistribute it and/or
;; modify it under the terms of the GNU General Public License as
;; published by the Free Software Foundation; either version 2 of the
;; License, or (at your option) any later version.
;;
;; This program is distributed in the hope that it will be useful, but
;; WITHOUT ANY WARRANTY; without even the implied warranty of
;; MERCHANTABILITY or FITNESS FOR A PARTICULAR PURPOSE. See the GNU
;; General Public License for more
;; details. http://www.gnu.org/copyleft/gpl.html
;;
;; You should have received a copy of the GNU General Public License
;; along with GNU Emacs. If you did not, write to the Free Software
;; Foundation, Inc., 675 Mass Ave., Cambridge, MA 02139, USA.

;;; Commentary
;; This provides a minimal mIRC style nicklist buffer for ERC.  To
;; activate, do M-x erc-nicklist RET in the channel buffer you want
;; the nicklist to appear for.  To close and quit the nicklist
;; buffer, do M-x erc-nicklist-quit RET.
;;
;; TODO: lots of things :)

;;; Code

(require 'erc)

(defvar erc-nicklist-window-size 20.0
  "*The size of the nicklist window.

This specifies a percentage of the channel window width.")

(defun erc-nicklist-buffer-name (&optional buffer)
  "Return the buffer name for a nicklist associated with BUFFER.

If BUFFER is nil, use the value of `current-buffer'."
  (format " *%s-nicklist*" (buffer-name (or buffer (current-buffer)))))

(defun erc-nicklist-make-window ()
  "Create an ERC nicklist window.

See also `erc-nicklist-window-size'."
  (let ((width (floor (* (window-width) (/ erc-nicklist-window-size 100.0))))
        (buffer (erc-nicklist-buffer-name))
        window)
    (split-window-horizontally (- width))
    (setq window (next-window))
    (set-window-buffer window (get-buffer buffer))
    (with-current-buffer buffer
      (set-window-dedicated-p window t))))

(defun erc-nicklist ()
  "Create an ERC nicklist buffer."
  (interactive)
  (let ((channel (current-buffer)))
    (erc-nicklist-make-window)
    (with-current-buffer (get-buffer (erc-nicklist-buffer-name channel))
      (setq buffer-read-only nil)
      (erase-buffer)
      (mapc (lambda (n)
              (insert (propertize n 'erc-nicklist-nick n 'mouse-face 'region
                                  'erc-nicklist-channel channel
                                  'help-echo "Mouse-3 for menu") "\n"))
            (erc-nicklist-channel-nicks channel))
      (erc-nicklist-mode)))
  (add-hook 'erc-channel-members-changed-hook #'erc-nicklist-update))

(defun erc-nicklist-update ()
  "Update the ERC nicklist buffer."
  (let ((b (get-buffer (erc-nicklist-buffer-name)))
        (channel (current-buffer)))
    (when b
      (with-current-buffer b
        (setq buffer-read-only nil)
        (erase-buffer)
        (mapc (lambda (n)
                (insert (propertize n 'erc-nicklist-nick n 'mouse-face 'region
                                    'erc-nicklist-channel channel
                                    'help-echo "Mouse-3 for menu") "\n"))
              (erc-nicklist-channel-nicks channel))
        (erc-nicklist-mode)))))

(defvar erc-nicklist-mode-map
  (let ((map (make-sparse-keymap)))
    (define-key map (kbd "<mouse-3>") 'erc-nicklist-menu)
    (define-key map "q" 'erc-nicklist-quit)
    map)
  "Keymap for `erc-nicklist-mode'.")

(define-derived-mode erc-nicklist-mode fundamental-mode
  "Nicklist"
  "Major mode for the ERC nicklist buffer."
  (setq buffer-read-only t))

(defun erc-nicklist-call-erc-command (command point buffer window)
  "Call an ERC COMMAND.

Depending on what COMMAND is, it's called with one of POINT, BUFFER,
or WINDOW as arguments."
  (let* ((p (text-properties-at point))
         (b (plist-get p 'erc-nicklist-channel)))
    (if (memq command '(erc-nicklist-quit ignore))
        (funcall command window)
      ;; EEEK!  Horrble, but it's the only way we can ensure the
      ;; response goes to the correct buffer.
      (setq erc-active-buffer b)
      (with-current-buffer b
        (funcall command (plist-get p 'erc-nicklist-nick))))))

(defvar erc-nicklist-menu
  (let ((map (make-sparse-keymap "Action")))
    (define-key map [erc-cmd-WHOIS]
      '("Whois" . erc-cmd-WHOIS))
    (define-key map [erc-cmd-DEOP]
      '("Deop" . erc-cmd-DEOP))
    (define-key map [erc-cmd-MSG]
      '("Message" . erc-cmd-MSG))
    (define-key map [erc-cmd-QUERY]
      '("Query" . erc-cmd-QUERY))
    (define-key map [ignore]
      '("Cancel" . ignore))
    (define-key map [erc-nicklist-quit]
      '("Close nicklist" . erc-nicklist-quit))
    map)
  "Menu keymap for the ERC nicklist.")

(defun erc-nicklist-quit (&optional window)
  "Delete the ERC nicklist.

Deletes WINDOW and stops updating the nicklist buffer."
  (interactive)
  (let ((b (window-buffer window)))
    (with-current-buffer b
      (set-buffer-modified-p nil)
      (kill-this-buffer)
      (remove-hook 'erc-channel-members-changed-hook 'erc-nicklist-update))
    (delete-window window)))

(defun erc-nicklist-menu (&optional arg)
  "Show the ERC nicklist menu."
  (interactive "e")
  (let* ((point (nth 1 (cadr arg)))
         (window (caadr arg))
         (buffer (window-buffer window)))
    (with-current-buffer buffer
      (erc-nicklist-call-erc-command
       (car (x-popup-menu arg
                          erc-nicklist-menu))
       point
       buffer
       window))))
    (message "%s" (get-text-property point 'erc-nicklist-nick))))

(defun erc-nicklist-channel-nicks (channel)
  "Return a sorted list of all nicks on CHANNEL."
  (let ((nicks (with-current-buffer channel
                 (loop for m being the hash-keys of erc-channel-users
                       collect m))))
    (sort nicks #'string<)))

(provide 'erc-nicklist)

;;; erc-nicklist.el ends here.

-- 
Lawrence Mitchell <we...@gm...>

[Erc-help] Re: Is erc cvs access down?

[Adrian A. <ad...@xe...>]

Adrian Aichner <ad...@xe...> writes:

> Hi All!
>
> For the last half hour at least I get
>
> ssh: connect to host cvs.sourceforge.net port 22: Connection reset by peer

Works again for me now.

>
> when I try to M-x cvs-update from repository
> :ext:MY_...@cv...:/cvsroot/erc
>
> Anybody else seeing the problem?

-- 
Adrian Aichner
 mailto:ad...@xe...
 http://www.xemacs.org/

[Erc-help] Is erc cvs access down?

[Adrian A. <ad...@xe...>]

Hi All!

For the last half hour at least I get

ssh: connect to host cvs.sourceforge.net port 22: Connection reset by peer

when I try to M-x cvs-update from repository
:ext:MY_...@cv...:/cvsroot/erc

Anybody else seeing the problem?

-- 
Adrian Aichner
 mailto:ad...@xe...
 http://www.xemacs.org/

[Erc-help] Notice of private mail loss

[Adrian A. <ad...@xe...>]

Hello All,

due to sillyness on my part I have lost email messages received by my
ad...@xe... and adr...@t-... addresses between
2004-04-21T09:00:00+0200 and 2004-04-21T15:00:00+0200 yesterday.

For improtant messages you sent to me privately and not to publically
available mail archives or news groups, please resend.

Thanks,

Adrian

-- 
Adrian Aichner
 mailto:ad...@xe...
 http://www.xemacs.org/

Re: [Erc-help] Re: Percent signs duplicated in topics

[Mark T. <ms...@di...>]

Lawrence Mitchell <we...@gm...> writes:

> Mark Triggs wrote:
>
>> I guess the solution would either to be have these functions unescape
>> the 'channel-topic' string before using it, or have any functions that
>> use 'channel-topic' as a format string do the escaping themselves. Does
>> anyone have a preference for either method? I have a patch for the
>> former that I'll be happy to send.
>
> Does this patch fix things?  It seems simpler than your suggestion.

Yep, sure does. Thanks.

Mark

-- 
Mark Triggs
<ms...@di...>

[Erc-help] Re: Percent signs duplicated in topics

[Lawrence M. <we...@gm...>]

Mark Triggs wrote:

[...]

> The percent sign has been duplicated.

> This seems to be because 'erc-update-channel-topic' avoids possible
> issues with 'format' by replacing "%" with "%%", but functions like
> 'erc-cmd-APPENDTOPIC' and 'erc-set-topic' don't unescape 'channel-topic'
> before using it.

> I guess the solution would either to be have these functions unescape
> the 'channel-topic' string before using it, or have any functions that
> use 'channel-topic' as a format string do the escaping themselves. Does
> anyone have a preference for either method? I have a patch for the
> former that I'll be happy to send.

Does this patch fix things?  It seems simpler than your suggestion.

Index: erc.el
===================================================================
RCS file: /cvsroot/erc/erc/erc.el,v
retrieving revision 1.648
diff -u -r1.648 erc.el
--- erc.el	6 Apr 2004 01:53:59 -0000	1.648
+++ erc.el	19 Apr 2004 13:28:10 -0000
@@ -6313,17 +6313,14 @@
 
 If optional MODIFY is 'append or 'prepend, then append or prepend the
 TOPIC string to the current topic."
-  (erc-with-buffer
-   (channel)
-	(when (boundp 'channel-topic)
-	  (cond ((eq modify 'append)
-		 (setq channel-topic (concat channel-topic topic)))
-		((eq modify 'prepend)
-		 (setq channel-topic (concat topic channel-topic)))
-		(t (setq channel-topic topic))))
-   ;; Make sure the topic does not contain any format controls.
-   (setq channel-topic (erc-replace-regexp-in-string "%" "%%" channel-topic))
-   (erc-update-mode-line-buffer (current-buffer))))
+  (erc-with-buffer (channel)
+    (when (boundp 'channel-topic)
+      (cond ((eq modify 'append)
+	     (setq channel-topic (concat channel-topic topic)))
+	    ((eq modify 'prepend)
+	     (setq channel-topic (concat topic channel-topic)))
+	    (t (setq channel-topic topic))))
+    (erc-update-mode-line-buffer (current-buffer))))
 
 (defun erc-set-modes (tgt mode-string)
   "Set the modes for the TGT provided as MODE-STRING."
@@ -7737,7 +7734,10 @@
 				   (fill-region (point-min) (point-max))
 				   (buffer-string))))
 		  (setq header-line-format
-			(propertize header 'help-echo help-echo)))
+			(erc-replace-regexp-in-string
+			 "%"
+			 "%%"
+			 (propertize header 'help-echo help-echo))))
 	      (setq header-line-format header)))
 	(setq header-line-format nil)))))
 

[...]


-- 
Lawrence Mitchell <we...@gm...>

[Erc-help] Percent signs duplicated in topics

[Mark T. <ms...@di...>]

Hi all,

I've noticed a slight glitch when a '%' appears in a channel topic. To
give an example:

ERC> /topic blah% 
*** mst (0...@th...) has set the topic for #test: "blah%"
ERC> /at | something else 
*** mst (0...@th...) has set the topic for #test: "blah%%
    | something else"

The percent sign has been duplicated.

This seems to be because 'erc-update-channel-topic' avoids possible
issues with 'format' by replacing "%" with "%%", but functions like
'erc-cmd-APPENDTOPIC' and 'erc-set-topic' don't unescape 'channel-topic'
before using it.

I guess the solution would either to be have these functions unescape
the 'channel-topic' string before using it, or have any functions that
use 'channel-topic' as a format string do the escaping themselves. Does
anyone have a preference for either method? I have a patch for the
former that I'll be happy to send.

I'm using today's CVS (ERC 4.0 revision 1.648) with GNU Emacs 21.3.50.1.

Best wishes,

Mark

-- 
Mark Triggs
<ms...@di...>

[Erc-help] Re: [PATCH] Improvements to erc-list

[Lawrence M. <we...@gm...>]

Is anyone actually looking at committing this?

Alex Schroeder wrote:

[...]

> Things I changed:

> Instead of replacing member-ignore-case with a call to member* with
> appropriate :test, I opted to define it, if it doesn't exist yet.
> Maybe that should be moved to erc-compat.el?

We already have erc-member-ignore-case, I think we should use
that instead.

> I also removed all the variables foo-face that just hold the symbol
> foo-face.  I think this is old school and nobody uses this anymore.
> We should only have faces, not variables and faces, where variables
> point to the faces.  Brian just kept what was there; but I think it
> should go.  What do you think?

I agree, we don't need variables too, it's a /very/ old
font-lock hangover, and is bad practice these days.

[...]

I'll commit this if it hasn't already been, and no-one has any
objections, I'm going to guess they don't since no-one's
responded prior to now :).

-- 
Lawrence Mitchell <we...@gm...>

[Erc-help] Re: [PATCH] Make using erc-add-scroll-to-bottom less slow

[Lawrence M. <we...@gm...>]

Brian Downing wrote:

> I'm running ERC on a old computer (200 MHz), with potentially tall
> windows.  I am using erc-add-scroll-to-bottom.  After the window had
> scrolled, text input was painfully slow.  It turns out that
> erc-scroll-to-bottom, and hence (recenter -1), was getting called
> several times for each character entered.  On a 60+ line window, this
> was really bad.

This sounds like an Emacs bug, rather than an ERC function.
Emacs shouldn't be calling window-scroll-functions if the
display doesn't scroll, can you narrow down when this problem
occurs at all?  I'd like to hold back on applying this, or
something similar, until we can be sure this is an ERC bug.

[...]

-- 
Lawrence Mitchell <we...@gm...>

[Erc-help] Re: [PATCH] Make using erc-add-scroll-to-bottom less slow

[Brian D. <bdo...@la...>]

Sorry for the quick self-followup, but I believe this patch may be more
correct.  It should handle backwards motion (just in case), and sets
erc-point-at-last-scroll-to-bottom after every erc-scroll-to-bottom, not
just after every recenter.

-bcd
-- 
*** Brian Downing <bdowning at lavos dot net> 

[Erc-help] [PATCH] Make using erc-add-scroll-to-bottom less slow

[Brian D. <bdo...@la...>]

Hi,

I'm running ERC on a old computer (200 MHz), with potentially tall
windows.  I am using erc-add-scroll-to-bottom.  After the window had
scrolled, text input was painfully slow.  It turns out that
erc-scroll-to-bottom, and hence (recenter -1), was getting called
several times for each character entered.  On a 60+ line window, this
was really bad.

The attached patch improves this greatly, not recentering for small
numbers of characters added.  (4 is a number I pulled from the ether,
but since the default ERC prompt plus a newline is longer than that it
seemed safe.)

It's probably wicked kludgey.  What I really wanted to do was ask emacs
if the current point location in the current window was on the last
line, and if not then recenter to the last line, but looking through the
emacs-lisp reference and M-x apropos'ing point, cursor, and window
didn't reveal anything to me.  Since the point-based method worked and
was cheap, I went with it.  I know very little emacs lisp, so there's
probably a better way to do this.

This patch applies to ERC 4.0.

Anyway, I hope this is generally useful.

-bcd
-- 
*** Brian Downing <bdowning at lavos dot net> 

[Erc-help] Wrong type error when I try to connect to freenode

[Brian P. <bp...@re...>]

I've been getting some errors recently, and just got motivated enough
to make sure that it's not one of my customizations that's screwing it
up. This is something that interferes with my autojoin, but after the
error is raised,I can manually join channels. It's not obvious to me
what exactly is going on here.

Namely, I start with clean fresh copy of erc from cvs. I start up
  XEmacs 21.5  (beta16) "celeriac" (+CVS-20040111) [Lucid] (sparc-sun-solaris2.9)
with debug-on-error set to true. I then do
   M-x erc-select RET irc.freenode.net RET 6667 RET bpalmer2 RET RET

Signaling: (wrong-type-argument stringp #<network connection "erc-irc.freenode.net-6667" (6667 . "irc.freenode.net") state:run>)
  string-match("^/g?away.*$" #<network connection "erc-irc.freenode.net-6667" (6667 . "irc.freenode.net") state:run>)
  (not (string-match "^/g?away.*$" line))
  (and erc-auto-discard-away (not (string-match "^/g?away.*$" line)))
  (if (and erc-auto-discard-away (not ...)) (erc-autoaway-set-back line))
  (when (and erc-auto-discard-away (not ...)) (erc-autoaway-set-back line))
  erc-autoaway-reset-idletime(#<network connection "erc-irc.freenode.net-6667" (6667 . "irc.freenode.net") state:run> ["001" "kornbluth.freenode.net" "bpalmer2" "Welcome to the freenode IRC Network bpalmer2" nil nil nil nil nil nil nil nil nil nil nil nil nil nil nil nil nil nil nil nil nil nil nil nil nil nil nil nil])
  run-hook-with-args-until-success(erc-autoaway-reset-idletime #<network connection "erc-irc.freenode.net-6667" (6667 . "irc.freenode.net") state:run> ["001" "kornbluth.freenode.net" "bpalmer2" "Welcome to the freenode IRC Network bpalmer2" nil nil nil nil nil nil nil nil nil nil nil nil nil nil nil nil nil nil nil nil nil nil nil nil nil nil nil nil])
  (progn (run-hook-with-args-until-success hook proc msg) nil)
  (if (and hook (symbol-value hook)) (progn (run-hook-with-args-until-success hook proc msg) nil) (run-hook-with-args-until-success (quote erc-default-server-hook) proc msg) nil)
  (let ((hook ...)) (if (and hook ...) (progn ... nil) (run-hook-with-args-until-success ... proc msg) nil) (with-current-buffer (erc-server-buffer) (run-hook-with-args ... ...)))
  erc-call-hooks(#<network connection "erc-irc.freenode.net-6667" (6667 . "irc.freenode.net") state:run> ["001" "kornbluth.freenode.net" "bpalmer2" "Welcome to the freenode IRC Network bpalmer2" nil nil nil nil nil nil nil nil nil nil nil nil nil nil nil nil nil nil nil nil nil nil nil nil nil nil nil nil])
  (if (member (aref msg 0) erc-prevent-duplicates) (progn (if ... ...) (puthash ... ... erc-duplicates)) (erc-call-hooks proc msg))
  (let ((posn ...) (msg ...) (n 2)) (aset msg 1 (if ... erc-session-server ...)) (aset msg 0 (let* ... ... ...)) (while (and posn ...) (aset msg n ...) (setq n ...)) (if posn (aset msg n ...)) (if (member ... erc-prevent-duplicates) (progn ... ...) (erc-call-hooks proc msg)))
  (progn (let (... ... ...) (aset msg 1 ...) (aset msg 0 ...) (while ... ... ...) (if posn ...) (if ... ... ...)))
  (unwind-protect (progn (let ... ... ... ... ... ...)) (store-match-data match-data))
  (let ((match-data ...)) (unwind-protect (progn ...) (store-match-data match-data)))
  (save-match-data (let (... ... ...) (aset msg 1 ...) (aset msg 0 ...) (while ... ... ...) (if posn ...) (if ... ... ...)))
  (if (string= string "") nil (save-match-data (let ... ... ... ... ... ...)))
  (unless (string= string "") (save-match-data (let ... ... ... ... ... ...)))
  erc-parse-line-from-server(#<network connection "erc-irc.freenode.net-6667" (6667 . "irc.freenode.net") state:run> ":kornbluth.freenode.net 001 bpalmer2 :Welcome to the freenode IRC Network bpalmer2")
  (lambda (line) (erc-parse-line-from-server proc line))(":kornbluth.freenode.net 001 bpalmer2 :Welcome to the freenode IRC Network bpalmer2")
  mapc-internal((lambda (line) (erc-parse-line-from-server proc line)) (":kornbluth.freenode.net 001 bpalmer2 :Welcome to the freenode IRC Network bpalmer2" ":kornbluth.freenode.net 002 bpalmer2 :Your host is kornbluth.freenode.net[kornbluth.freenode.net/6667], running version dancer-ircd-1.0.35" "NOTICE bpalmer2 :*** Your host is kornbluth.freenode.net[kornbluth.freenode.net/6667], running version dancer-ircd-1.0.35" ":kornbluth.freenode.net 003 bpalmer2 :This server was cobbled together Sun Feb 15 03:16:50 UTC 2004" ":kornbluth.freenode.net 004 bpalmer2 kornbluth.freenode.net dancer-ircd-1.0.35 aAbBcCdDeEfFGhHiIjkKlLmMnNopPQrRsStUvVwWxXyYzZ0123459*@ bcdefFhiIklmnoPqstv" ":kornbluth.freenode.net 005 bpalmer2 MODES=4 CHANLIMIT=#:20 NICKLEN=16 USERLEN=10 HOSTLEN=63 TOPICLEN=450 KICKLEN=450 CHANNELLEN=30 KEYLEN=23 CHANTYPES=# PREFIX=(ov)@+ CASEMAPPING=ascii CAPAB IRCD=dancer :are available on this server" ":kornbluth.freenode.net 251 bpalmer2 :There are 8044 victims and 8269 h!
 iding on 32 servers" ":kornbluth.freenode.net 252 bpalmer2 41 :flagged staff members"))
  mapc((lambda (line) (erc-parse-line-from-server proc line)) (":kornbluth.freenode.net 001 bpalmer2 :Welcome to the freenode IRC Network bpalmer2" ":kornbluth.freenode.net 002 bpalmer2 :Your host is kornbluth.freenode.net[kornbluth.freenode.net/6667], running version dancer-ircd-1.0.35" "NOTICE bpalmer2 :*** Your host is kornbluth.freenode.net[kornbluth.freenode.net/6667], running version dancer-ircd-1.0.35" ":kornbluth.freenode.net 003 bpalmer2 :This server was cobbled together Sun Feb 15 03:16:50 UTC 2004" ":kornbluth.freenode.net 004 bpalmer2 kornbluth.freenode.net dancer-ircd-1.0.35 aAbBcCdDeEfFGhHiIjkKlLmMnNopPQrRsStUvVwWxXyYzZ0123459*@ bcdefFhiIklmnoPqstv" ":kornbluth.freenode.net 005 bpalmer2 MODES=4 CHANLIMIT=#:20 NICKLEN=16 USERLEN=10 HOSTLEN=63 TOPICLEN=450 KICKLEN=450 CHANNELLEN=30 KEYLEN=23 CHANTYPES=# PREFIX=(ov)@+ CASEMAPPING=ascii CAPAB IRCD=dancer :are available on this server" ":kornbluth.freenode.net 251 bpalmer2 :There are 8044 victims and 8269 hiding on !
 32 servers" ":kornbluth.freenode.net 252 bpalmer2 41 :flagged staff members"))
  (save-current-buffer (set-buffer (process-buffer proc)) (mapc (lambda ... ...) (erc-split-multiline string)))
  (with-current-buffer (process-buffer proc) (mapc (lambda ... ...) (erc-split-multiline string)))
  erc-process-filter(#<network connection "erc-irc.freenode.net-6667" (6667 . "irc.freenode.net") state:run> ":kornbluth.freenode.net 001 bpalmer2 :Welcome to the freenode IRC Network bpalmer2\n:kornbluth.freenode.net 002 bpalmer2 :Your host is kornbluth.freenode.net[kornbluth.freenode.net/6667], running version dancer-ircd-1.0.35\nNOTICE bpalmer2 :*** Your host is kornbluth.freenode.net[kornbluth.freenode.net/6667], running version dancer-ircd-1.0.35\n:kornbluth.freenode.net 003 bpalmer2 :This server was cobbled together Sun Feb 15 03:16:50 UTC 2004\n:kornbluth.freenode.net 004 bpalmer2 kornbluth.freenode.net dancer-ircd-1.0.35 aAbBcCdDeEfFGhHiIjkKlLmMnNopPQrRsStUvVwWxXyYzZ0123459*@ bcdefFhiIklmnoPqstv\n:kornbluth.freenode.net 005 bpalmer2 MODES=4 CHANLIMIT=#:20 NICKLEN=16 USERLEN=10 HOSTLEN=63 TOPICLEN=450 KICKLEN=450 CHANNELLEN=30 KEYLEN=23 CHANTYPES=# PREFIX=(ov)@+ CASEMAPPING=ascii CAPAB IRCD=dancer :are available on this server\n:kornbluth.freenode.net 251 bpalmer2 :Th!
 ere are 8044 victims and 8269 hiding on 32 servers\n:kornbluth.freenode.net 252 bpalmer2 41 :flagged staff members\n:kornbluth.freenode.net 254 bpalmer2 ")
  ("execute_internal_event()" "[internal]")
  (dispatch-event "[internal]")



The erc variables I customize are
 '(erc-auto-query 'window-noselect)
 '(erc-autoaway-idle-seconds 3600)
 '(erc-autoaway-message "I'm gone (autoaway)")
 '(erc-autojoin-channels-alist '(("freenode.net" "#perl" "#java" "#emacs")
 '(erc-insert-post-hook '(erc-truncate-buffer erc-make-read-only)
 '(erc-modules '(autoaway autojoin button completion fill netsplit pcomplete ring services)
 '(erc-send-post-hook '(erc-make-read-only)
 '(erc-server-NOTICE-hook '(erc-auto-query erc-nickserv-identify-autodetect erc-server-PRIVMSG-or-NOTICE)
 '(erc-track-exclude-types '("JOIN" "KICK" "NICK" "PART" "QUIT")

in my init.el, I do

(require 'erc)
(require 'erc-truncate)
(require 'erc-autojoin)
(require 'erc-track)

-- 
I'm awfully glad I'm a Beta, because I don't work so hard.

Re: [Erc-help] [PATCH] Improvements to erc-list

[Brian P. <bp...@re...>]

Alex Schroeder <al...@em...> writes:

> Hi Brian, hi List,
> 
> I can't check in any new files...  :(

ah :-)
 
> Anyway, I looked through the patch (new one appended), and wrote a
> ChangeLog entry.

I thought erc didn't use ChangeLogs ? Oh, for CVS comments. (and drat,
I can't use the mkChangelog stuff I can't use because I don't have zsh
lying around). 
 
> Things I changed:
> 
> Instead of replacing member-ignore-case with a call to member* with
> appropriate :test, I opted to define it, if it doesn't exist yet.
> Maybe that should be moved to erc-compat.el?

Aha! That's something I forgot to change after my first patch. It came
out in discussion on #emacs that erc.el has a

  (defun erc-member-ignore-case (string list)

which people should use, instead of member-ignore-case.

> I also removed all the variables foo-face that just hold the symbol
> foo-face.  I think this is old school and nobody uses this anymore.
> We should only have faces, not variables and faces, where variables
> point to the faces.  Brian just kept what was there; but I think it
> should go.  What do you think?

It *had* struck me as awfully general purpose to use both the vars and
the faces. So I'd be fine with removing them, for what it's worth. 
-- 
I'm awfully glad I'm a Beta, because I don't work so hard.

Re: [Erc-help] [PATCH] Improvements to erc-list

[Alex S. <al...@em...>]

Hi Brian, hi List,

I can't check in any new files...  :(

ssh_exchange_identification: Connection closed by remote host
cvs [commit aborted]: end of file from server (consult above messages if any)


Anyway, I looked through the patch (new one appended), and wrote a
ChangeLog entry.

Things I changed:

Instead of replacing member-ignore-case with a call to member* with
appropriate :test, I opted to define it, if it doesn't exist yet.
Maybe that should be moved to erc-compat.el?

I also removed all the variables foo-face that just hold the symbol
foo-face.  I think this is old school and nobody uses this anymore.
We should only have faces, not variables and faces, where variables
point to the faces.  Brian just kept what was there; but I think it
should go.  What do you think?

Alex.


2004-04-06  Brian Palmer  <bp...@re...>, Alex Schroeder  <al...@gn...>

	* erc-list.el: Require overlay if make-overlay is not bound for
	XEmacs compatibility.
	(member-ignore-case): Added simple defun for XEmacs compatibility.
	(erc-chanlist-frame-parameters): Use defcustom.
	(erc-chanlist-header-face, erc-chanlist-odd-line-face)
	(erc-chanlist-even-line-face): Use defface, removed corresponding
	defvar.
	(erc-chanlist-mode-hook): Use defcustom.
	(erc-chanlist-post-command-hook): Simplify, use
	erc-chanlist-highlight-line and erc-chanlist-dehighlight-line.
	(erc-chanlist-highlight-overlay): New.
	(erc-chanlist-highlight-line): Use overlays.
	(erc-chanlist-dehighlight-line): New.

*** erc-list.el.~1.25.~	2004-04-06 14:52:01.000000000 +0200
--- erc-list.el	2004-04-06 15:08:41.000000000 +0200
***************
*** 30,35 ****
--- 30,45 ----
  
  (require 'erc)
  (require 'erc-nets)
+ (unless (fboundp 'make-overlay)
+   (require 'overlay))
+ 
+ (unless (fboundp 'member-ignore-case)
+   (require 'cl)
+   (defun member-ignore-case (elt list)
+     "Like `member', but ignores differences in case and text representation.
+ Compatibility function defined by ERC."
+     (member* elt list
+ 	     :test (lambda (a b) (equal (upcase a) (upcase b))))))
  
  ;;;;;;;;;;;;;;;;;;;;;;;;;;;;;;;;;;;;;;;;;;;;;;;;;;;;;;;;;;;;;;;;;;;;;;;;;;;;;;;;
  ;; User customizable variables.
***************
*** 45,81 ****
    :group 'erc
    :type '(repeat string))
  
! (defvar erc-chanlist-frame-parameters nil
    "If nil, the channel list is displayed in a new window, otherwise this
  variable holds the frame parameters used to make a frame to display the channel
! list.")
  
  (defcustom erc-chanlist-hide-modeline nil
    "*If nil, the channel list buffer has a modeline, otherwise the modeline is hidden."
    :group 'erc
    :type 'boolean)
  
! ;;;;;;;;;;;;;;;;;;;;;;;;;;;;;;;;;;;;;;;;;;;;;;;;;;;;;;;;;;;;;;;;;;;;;;;;;;;;;;;;
! ;; Faces.  There's really no good default value that we can set for the
! ;; foreground color of these faces, since we don't know the user's color scheme.
! ;; The user should modify these faces as desired.
! ;;;;;;;;;;;;;;;;;;;;;;;;;;;;;;;;;;;;;;;;;;;;;;;;;;;;;;;;;;;;;;;;;;;;;;;;;;;;;;;;
! 
! (make-face 'erc-chanlist-header-face)
! (defvar erc-chanlist-header-face 'erc-chanlist-header-face)
! (set-face-foreground 'erc-chanlist-header-face nil)
! (set-face-background 'erc-chanlist-header-face nil)
! 
! (make-face 'erc-chanlist-odd-line-face)
! (defvar erc-chanlist-odd-line-face 'erc-chanlist-odd-line-face)
! (set-face-foreground 'erc-chanlist-odd-line-face nil)
! (set-face-background 'erc-chanlist-odd-line-face nil)
! 
! (make-face 'erc-chanlist-even-line-face)
! (defvar erc-chanlist-even-line-face 'erc-chanlist-even-line-face)
! (set-face-foreground 'erc-chanlist-even-line-face nil)
! (set-face-background 'erc-chanlist-even-line-face nil)
! 
  
  ;;;;;;;;;;;;;;;;;;;;;;;;;;;;;;;;;;;;;;;;;;;;;;;;;;;;;;;;;;;;;;;;;;;;;;;;;;;;;;;;
  ;; All variables below this line are for internal use only.
--- 55,83 ----
    :group 'erc
    :type '(repeat string))
  
! (defcustom erc-chanlist-frame-parameters nil
    "If nil, the channel list is displayed in a new window, otherwise this
  variable holds the frame parameters used to make a frame to display the channel
! list."
!   :group 'erc
!   :type 'sexp)
  
  (defcustom erc-chanlist-hide-modeline nil
    "*If nil, the channel list buffer has a modeline, otherwise the modeline is hidden."
    :group 'erc
    :type 'boolean)
  
! (defface erc-chanlist-header-face '((t (:bold t)))
!   "Face used for the headers in erc's channel list"
!   :group 'erc-faces)
! 
! (defface erc-chanlist-odd-line-face '((t (:inverse-video t)))
!   "Face used for the odd lines in erc's channel list"
!   :group 'erc-faces)
! 
! (defface erc-chanlist-even-line-face '((t (:inverse-video nil)))
!   "Face used for the event lines in erc's channel list"
!   :group 'erc-faces)
  
  ;;;;;;;;;;;;;;;;;;;;;;;;;;;;;;;;;;;;;;;;;;;;;;;;;;;;;;;;;;;;;;;;;;;;;;;;;;;;;;;;
  ;; All variables below this line are for internal use only.
***************
*** 101,108 ****
  ;; Define erc-chanlist-mode.
  ;;;;;;;;;;;;;;;;;;;;;;;;;;;;;;;;;;;;;;;;;;;;;;;;;;;;;;;;;;;;;;;;;;;;;;;;;;;;;;;;
  
! (defvar erc-chanlist-mode-hook nil
!   "A hook run by erc-chanlist-mode.")
  
  (define-derived-mode erc-chanlist-mode fundamental-mode "ERC Channel List"
    "Mode for viewing a channel list of a particular server.
--- 103,112 ----
  ;; Define erc-chanlist-mode.
  ;;;;;;;;;;;;;;;;;;;;;;;;;;;;;;;;;;;;;;;;;;;;;;;;;;;;;;;;;;;;;;;;;;;;;;;;;;;;;;;;
  
! (defcustom erc-chanlist-mode-hook nil
!   "A hook run by erc-chanlist-mode."
!   :group 'erc
!   :type 'hook)
  
  (define-derived-mode erc-chanlist-mode fundamental-mode "ERC Channel List"
    "Mode for viewing a channel list of a particular server.
***************
*** 152,158 ****
       321
       '(progn
  	(add-hook 'erc-server-322-hook 'erc-chanlist-322 nil t)
- 
  	(erc-once-with-server-event
  	 323
  	 '(progn
--- 156,161 ----
***************
*** 160,172 ****
  	    (let ((buf erc-chanlist-buffer))
  	      (if (not (buffer-live-p buf))
  		  (error "`erc-chanlist-buffer' does not refer to a live buffer"))
- 
  	      (set-buffer buf)
  	      (let (buffer-read-only
  		    (sort-fold-case t))
  		(sort-lines nil (point-min) (point-max))
  		(setq erc-chanlist-sort-state 'channel)
- 
  		(let ((sum (count-lines (point-min) (point-max))))
  		  (goto-char (point-min))
  		  (insert (substitute-command-keys
--- 163,173 ----
***************
*** 178,189 ****
  				  sum (if (eq erc-chanlist-sort-state 'channel)
  					  "channel name"
  					"number of users"))))
- 
  		(insert (format "%-25s%5s %s\n------------------------ ----- ----------------------------\n"
  				"Channel"
  				"Users"
  				"Topic"))
- 
  		;; Display the channel list buffer.
  		(if erc-chanlist-frame-parameters
  		    (progn
--- 179,188 ----
***************
*** 204,210 ****
  	    (erc-chanlist-highlight-line)
  	    (message "")
  	    t))
- 
  	(setq erc-chanlist-buffer (get-buffer-create (format "*Channels on %s*" (aref parsed 1))))
  	(with-current-buffer erc-chanlist-buffer
  	  (setq buffer-read-only nil)
--- 203,208 ----
***************
*** 215,221 ****
  	      (setq mode-line-format nil))
  	  (setq buffer-read-only t))
  	t))
- 
      ;; Now that we've setup our callbacks, pull the trigger.
      (if (interactive-p)
  	(message "Collecting channel list for server %s" erc-session-server))
--- 213,218 ----
***************
*** 236,242 ****
  	(let (buffer-read-only)
  	  (insert (format "%-26s%4s %s\n" (erc-interpret-controls chnl) nv
  			  (erc-interpret-controls topic))))
- 
  	;; Maybe display a progress indicator in the minibuffer.
  	(when (and erc-chanlist-progress-message
  		   (> (erc-time-diff
--- 233,238 ----
***************
*** 245,274 ****
  	  (setq erc-chanlist-last-time (erc-current-time))
  	  (message "Accumulating channel list ... %c"
  		   (aref [?/ ?| ?\\ ?- ?! ?O ?o] (random 7))))
- 
  	;; Return success to prevent other hook functions from being run.
  	t))))
  
  (defun erc-chanlist-post-command-hook ()
    "Keeps the current line highlighted."
    (ignore-errors
-     ;; First, restore all channel lines to their normal faces.
-     (erc-prettify-channel-list)
- 
-     ;; Then, highlight the current line.
-     ;;(sleep-for 2)
      (save-excursion
        (beginning-of-line)
!       (when (looking-at erc-chanlist-channel-line-regexp)
! 	(erc-chanlist-highlight-line)))))
  
  (defun erc-chanlist-highlight-line ()
    "Highlights the current line."
    (save-excursion
!     (let ((bol (point))
! 	  (inhibit-read-only t))
        (end-of-line)
!       (add-text-properties bol (point) `(face highlight)))))
  
  (defun erc-prettify-channel-list ()
    "Makes the channel list buffer look pretty.  When this function runs, the
--- 241,283 ----
  	  (setq erc-chanlist-last-time (erc-current-time))
  	  (message "Accumulating channel list ... %c"
  		   (aref [?/ ?| ?\\ ?- ?! ?O ?o] (random 7))))
  	;; Return success to prevent other hook functions from being run.
  	t))))
  
  (defun erc-chanlist-post-command-hook ()
    "Keeps the current line highlighted."
    (ignore-errors
      (save-excursion
        (beginning-of-line)
!       (if (looking-at erc-chanlist-channel-line-regexp)
! 	  (erc-chanlist-highlight-line)
! 	(erc-chanlist-dehighlight-line)))))
! 
! (defvar erc-chanlist-highlight-overlay nil
!   "The overlay used for erc chanlist highlighting")
! (make-variable-buffer-local 'erc-chanlist-highlight-overlay)
  
  (defun erc-chanlist-highlight-line ()
    "Highlights the current line."
+   (unless erc-chanlist-highlight-overlay
+     (setq erc-chanlist-highlight-overlay 
+ 	  (make-overlay (point-min) (point-min)))
+     ; Detach it from the buffer. 
+     (delete-overlay erc-chanlist-highlight-overlay)
+     (overlay-put erc-chanlist-highlight-overlay 'face 'highlight)
+     ;; Expressly put it at a higher priority than the text
+     ;; properties used for faces later on. Gnu emacs promises that
+     ;; right now overlays are higher priority than text properties,
+     ;; but why take chances?
+     (overlay-put erc-chanlist-highlight-overlay 'priority 1))
    (save-excursion
!     (let ((bol (point)))
        (end-of-line)
!       (move-overlay erc-chanlist-highlight-overlay bol (point)))))
! 
! (defun erc-chanlist-dehighlight-line ()
!   "Removes the line highlighting."
!   (delete-overlay erc-chanlist-highlight-overlay))
  
  (defun erc-prettify-channel-list ()
    "Makes the channel list buffer look pretty.  When this function runs, the
***************
*** 281,287 ****
  	    (end-of-line)
  	    (add-text-properties (point-min) (point) '(face erc-chanlist-header-face))
  	    (forward-line 1))
- 
  	  (while (not (eobp))
  	    (let ((sol (point)))
  	      (end-of-line)
--- 290,295 ----
***************
*** 311,329 ****
  	      (setq erc-chanlist-sort-state 'users))
  	  (sort-lines nil (point) (point-max))
  	  (setq erc-chanlist-sort-state 'channel))
- 
  	(goto-char (point-min))
  	(if (search-forward-regexp "^[0-9]+ channels (sorted by \\(.*\\)).$" nil t)
  	    (replace-match (if (eq erc-chanlist-sort-state 'channel)
  			       "channel name"
  			     "number of users")
  			   nil nil nil 1))
- 
  	(goto-char (point-min))
  	(search-forward-regexp "^-----" nil t)
  	(forward-line 1)
  	(recenter -1)
- 
        	(erc-prettify-channel-list)))))
  
  (defun erc-chanlist-quit ()
--- 319,334 ----

[Erc-help] [PATCH] Improvements to erc-list

[Brian P. <bp...@re...>]

I had sent a message on this before
(http://sourceforge.net/mailarchive/message.php?msg_id=7608111)
outlining the motivation and general approach I took, but didn't hear
anything back, nor does it seem to have been applied.  This seems like
it'd be useful; if there are no objections, could somebody please
apply it?

Index: erc-list.el
===================================================================
RCS file: /cvsroot/erc/erc/erc-list.el,v
retrieving revision 1.24
diff -r1.24 erc-list.el
32a33,35
> (require 'cl)
> (unless (fboundp 'make-overlay)
>   (require 'overlay))
48c51
< (defvar erc-chanlist-frame-parameters nil
---
> (defcustom erc-chanlist-frame-parameters nil
51c54,56
< list.")
---
> list."
>   :group 'erc
>   :type 'sexp)
58,77c63,88
< ;;;;;;;;;;;;;;;;;;;;;;;;;;;;;;;;;;;;;;;;;;;;;;;;;;;;;;;;;;;;;;;;;;;;;;;;;;;;;;;;
< ;; Faces.  There's really no good default value that we can set for the
< ;; foreground color of these faces, since we don't know the user's color scheme.
< ;; The user should modify these faces as desired.
< ;;;;;;;;;;;;;;;;;;;;;;;;;;;;;;;;;;;;;;;;;;;;;;;;;;;;;;;;;;;;;;;;;;;;;;;;;;;;;;;;
< 
< (make-face 'erc-chanlist-header-face)
< (defvar erc-chanlist-header-face 'erc-chanlist-header-face)
< (set-face-foreground 'erc-chanlist-header-face nil)
< (set-face-background 'erc-chanlist-header-face nil)
< 
< (make-face 'erc-chanlist-odd-line-face)
< (defvar erc-chanlist-odd-line-face 'erc-chanlist-odd-line-face)
< (set-face-foreground 'erc-chanlist-odd-line-face nil)
< (set-face-background 'erc-chanlist-odd-line-face nil)
< 
< (make-face 'erc-chanlist-even-line-face)
< (defvar erc-chanlist-even-line-face 'erc-chanlist-even-line-face)
< (set-face-foreground 'erc-chanlist-even-line-face nil)
< (set-face-background 'erc-chanlist-even-line-face nil)
---
> (defface erc-chanlist-header-face '((t (:bold t)))
>   "Face used for the headers in erc's channel list"
>   :group 'erc-faces)
> 
> (defcustom erc-chanlist-header-face 'erc-chanlist-header-face
>   "*Face used for the headers in erc's channel list"
>   :group 'erc
>   :type 'face)
> 
> (defface erc-chanlist-odd-line-face '((t (:inverse-video t)))
>   "Face used for the odd lines in erc's channel list"
>   :group 'erc-faces)
> 
> (defcustom erc-chanlist-odd-line-face 'erc-chanlist-odd-line-face
>   "*Face used for the odd lines in erc's channel list"
>   :group 'erc
>   :type 'face)
> 
> (defface erc-chanlist-even-line-face '((t (:inverse-video nil)))
>   "Face used for the event lines in erc's channel list"
>   :group 'erc-faces)
> 
> (defcustom erc-chanlist-even-line-face 'erc-chanlist-even-line-face
>   "*Face used for the event lines in erc's channel list"
>   :group 'erc
>   :type 'face)
104,105c115,118
< (defvar erc-chanlist-mode-hook nil
<   "A hook run by erc-chanlist-mode.")
---
> (defcustom erc-chanlist-mode-hook nil
>   "A hook run by erc-chanlist-mode."
>   :group 'erc
>   :type 'hook)
134c147,148
< 	   (member-ignore-case (erc-network-name) erc-no-list-networks))
---
> 	   (member* (erc-network-name) erc-no-list-networks 
> 		    :test (lambda (a b) (equal (upcase a) (upcase b)))))
255,259d268
<     ;; First, restore all channel lines to their normal faces.
<     (erc-prettify-channel-list)
< 
<     ;; Then, highlight the current line.
<     ;;(sleep-for 2)
262,263c271,277
<       (when (looking-at erc-chanlist-channel-line-regexp)
< 	(erc-chanlist-highlight-line)))))
---
>       (if (looking-at erc-chanlist-channel-line-regexp)
> 	  (erc-chanlist-highlight-line)
> 	(erc-chanlist-dehighlight-line)))))
> 
> (defvar erc-chanlist-highlight-overlay nil
>   "The overlay used for erc chanlist highlighting")
> (make-variable-buffer-local 'erc-chanlist-highlight-overlay)
266a281,292
>   (unless erc-chanlist-highlight-overlay
>     (setq erc-chanlist-highlight-overlay 
> 	  (make-overlay (point-min) (point-min)))
>     ; Detach it from the buffer. 
>     (delete-overlay erc-chanlist-highlight-overlay)
>     (overlay-put erc-chanlist-highlight-overlay 'face 'highlight)
>     ;; Expressly put it at a higher priority than the text
>     ;; properties used for faces later on. Gnu emacs promises that
>     ;; right now overlays are higher priority than text properties,
>     ;; but why take chances?
>     (overlay-put erc-chanlist-highlight-overlay 'priority 1))
>   
268,269c294
<     (let ((bol (point))
< 	  (inhibit-read-only t))
---
>     (let ((bol (point)))
271c296,300
<       (add-text-properties bol (point) `(face highlight)))))
---
>       (move-overlay erc-chanlist-highlight-overlay bol (point)))))
> 
> (defun erc-chanlist-dehighlight-line ()
>   "Removes the line highlighting."
>   (delete-overlay erc-chanlist-highlight-overlay))

-- 
I'm awfully glad I'm a Beta, because I don't work so hard.

[Erc-help] Re: [patch] erc-scroll-to-bottom fails if erc-insert-marker is nil

[Lawrence M. <we...@gm...>]

Jari Aalto wrote:

> I'm sending thri patch here, as nobody seemed to have read the
> Sourceforge patch page. The scroll to bottom function dies, if
> erc-insert-marker is nil.

>    (if (and window (window-live-p window))
>+      ;;  If there is no value, nothing we can do
>+      erc-insert-marker

I think you mean:

(if (and window (window-live-p window) erc-insert-marker) ...)

yes?


I think `erc-insert-marker' being nil when
`erc-scroll-to-bottom' is called is probably indicative of a
more fundamental bug.  I can't think of any point at which
`erc-scroll-to-bottom' should be called without
`erc-insert-marker' being initialised.

Can you provide a repeatable test case for the problem?

[...]

-- 
Lawrence Mitchell <we...@gm...>

[Erc-help] [patch] erc-scroll-to-bottom fails if erc-insert-marker is nil

[<jar...@po...>]

I'm sending thri patch here, as nobody seemed to have read the Sourceforge
patch page. The scroll to bottom function dies, if erc-insert-marker
is nil.

Jari


   (if (and window (window-live-p window))
+      ;;  If there is no value, nothing we can do
+      erc-insert-marker
       ;; Temporarily bind resize-mini-windows to nil so that users who have it
       ;; set to a non-nil value will not suffer from premature minibuffer
       ;; shrinkage due to the below recenter call.  I have no idea why this

[Erc-help] [C] Re: [PATCH] erc: Use truncate-string-to-width instead of truncate-string alias

[Adrian A. <ad...@xe...>]

COMMIT

Adding a Ditto. to the commit message, as suggested by bojohan on #emacs.

I got following Backtrace during commit:

http://www.emacswiki.org/cgi-bin/wiki.pl/BacktraceDuringErcCommit

-- 
Adrian Aichner
 mailto:ad...@xe...
 http://www.xemacs.org/

[Erc-help] [PATCH] erc: Use truncate-string-to-width instead of truncate-string alias

[Adrian A. <ad...@xe...>]

As discussed on #emacs today ...

I'll commit after review.

Best regards,

Adrian

Commit message:

2004-03-28  Adrian Aichner  <ad...@xe...>

	* erc.el (erc-cmd-BANLIST): Use `truncate-string-to-width' instead
        of `truncate-string' alias.
	* erc.el (erc-nickname-in-use):

erc source patch:
Diff command:   cvs -f -z3 -q diff -u -N
Files affected: erc.el

Index: erc.el
===================================================================
RCS file: /cvsroot/erc/erc/erc.el,v
retrieving revision 1.644
diff -u -r1.644 erc.el
--- erc.el	22 Mar 2004 08:24:48 -0000	1.644
+++ erc.el	27 Mar 2004 22:50:22 -0000
@@ -3822,9 +3822,9 @@
        (lambda (x)
          (erc-display-line
 	    (format fmt
-		    (truncate-string (cdr x) (/ erc-fill-column 2))
+		    (truncate-string-to-width (cdr x) (/ erc-fill-column 2))
 		    (if (car x)
-			(truncate-string (car x) (/ erc-fill-column 2))
+			(truncate-string-to-width (car x) (/ erc-fill-column 2))
 		      ""))
           'active))
        channel-banlist)
@@ -4561,7 +4561,7 @@
       (if erc-default-nicks
 	  (setq erc-default-nicks (cdr erc-default-nicks)))
       (if (not newnick)
-	  (setq newnick (concat (truncate-string
+	  (setq newnick (concat (truncate-string-to-width
 				 nick
 				 (if (and erc-connected nicklen)
 				     (- (string-to-int nicklen) 1)

-- 
Adrian Aichner
 mailto:ad...@xe...
 http://www.xemacs.org/

[Erc-help] Improving erc-list compatibility, performance, customizations

[Brian P. <bp...@re...>]

-- 
I'm awfully glad I'm a Beta, because I don't work so hard.

[Erc-help] [C] Re: [S] [PATCH] packages: Fix mis-compiled erc macros

[Adrian A. <ad...@xe...>]

COMMIT

only commited to XEmacs CVS after a day of usage.

-- 
Adrian Aichner
 mailto:ad...@xe...
 http://www.xemacs.org/