Help understanding generator results

[Vishal Verma]

Hello everyone,

I'm trying to run OpenDSS in dynamics mode.
I'm using four bus system in beginning. I have connected a generator object, model=3, at node n4.
However, when I'm increasing kW output of generator more than load in the system, I'm observing no waveform in the monitor, and solution shows that mode is Snap instead of Dynamic.
I was expecting that in such case generator will supply power back to infinite bus, and I will still have some voltage waveform output.
Please find my code here.

clear
Set DefaultBaseFrequency=60
! Based on script developed by Alan Dunn and Steve Sparling

new circuit.4bus basekV=12.47 phases=3 mvasc3=600 600

! **** DEFINE WIRE DATA
new wiredata.conductor Runits=mi Rac=0.306 GMRunits=ft GMRac=0.0244 Radunits=in Diam=0.721
new wiredata.neutral Runits=mi Rac=0.592 GMRunits=ft GMRac=0.00814 Radunits=in Diam=0.563

! **** DEFINE LINE GEOMETRY; REDUCE OUT THE NEUTRAL
new linegeometry.4wire nconds=4 nphases=3 reduce=yes
~ cond=1 wire=conductor units=ft x=-4 h=28
~ cond=2 wire=conductor units=ft x=-1.5 h=28
~ cond=3 wire=conductor units=ft x=3 h=28
~ cond=4 wire=neutral units=ft x=0 h=24

! **** 12.47 KV LINE
new line.line1 geometry=4wire length=2000 units=ft bus1=sourcebus bus2=n2

! **** 3-PHASE STEP-DOWN TRANSFORMER 12.47/4.16 KV Delta-Ygrd
new transformer.t1 xhl=6
~ wdg=1 bus=n2 conn=delta kV=12.47 kVA=6000 %r=0.5
~ wdg=2 bus=n3 conn=wye kV=4.16 kVA=6000 %r=0.5

! **** 4.16 KV LINE
new line.line2 bus1=n3 bus2=n4 geometry=4wire length=2500 units=ft

! **** WYE-CONNECTED 4.16 KV LOAD
new load.load1 phases=3 bus1=n4 conn=wye kV=4.16 kW=2400 pf=0.9 model=1
//new load.load2 phases=3 bus1=n3 conn=wye kV=4.16 kW=5400 pf=0.9 model=1

~ vminpu=0.75 ! model will remain const p,q down to 0.75 pu voltage

// -------------------------------------SG---------------------------------------
New Generator.Gen1 Bus1=n4 model =3 kW =3000 kV=4.16

// ----------------------------------------Monitors-----------------------------
New Monitor.voltage_1 element=line.line2 terminal= 1 mode=0

set voltagebases=[12.47, 4.16]
calcvoltagebases ! **** let DSS compute voltage bases
solve

Set mode=dynamics number=1 h=0.000166667
solve

Solve number = 4000
//Disable Line.line1
Solve number= 5000

get time
get number

Plot monitor object= voltage_1 channels=(1, 3, 5)

Thanks in advance.

[Davis Montenegro]

Hi,

Check again, it works on my PC. It seems that it needs more control iterations on the first solution so add the following line before the first "solve" command:

set maxiterations=35 maxcontroliter=35

That should work

Best regards

Davis

[Vishal Verma]

Thanks Davis, it worked after using the command.

[Vishal Verma]

So, I'm assuming my program wasn't able to solve snap mode properly, and hence did not move forward to dynamics mode, and thus no output was shown in plot graph.

[Roger Dugan]

I'm not sure what is going on, but execute

Show mon voltage_1

and see if there are any numbers in the Monitor object.