Request: TAd2DBitmapTexture - LoadFromMemory

This is my request, in TAd2DBitmapTexture can you add a procedure to load directly from memory?
We could skip one step to copy a block of memory (usually using TAd2dBitmap as Raw proxy). This is usefull & more fast to load a texture directly from our defined raw buffer, without need copy it to TAd2dBitmap first. Especially to load video buffer as dynamic texture.
I have modify the code (currently in OpenGL driver), each time I update from CVS I must edit the new code to make it fit of my need. Can you add this to CVS version?

abstract class:

TAd2DBitmapTexture = class(...)
public
  ...
procedure LoadFromMemory(const Src: Pointer; const AWidth, AHeight: Integer; const ABitDepth: TAdBitDepth); virtual; abstract;
...
end;

OpenGL:

// this procedure copied from LoadFromBitmap and modify some variable to fit the requirements.

procedure TOGLBitmapTexture.LoadFromMemory(const Src: Pointer; const AWidth,
  AHeight: Integer; const ABitDepth: TAdBitDepth);
var
  mem:PByte;
  w,h,x,y:integer;
  pnt32:PRGBARec;
  cur16:PWord;
  cur32:PLongWord;
  newtex: boolean;
begin
  //Calculate power of two size of the texture
  w := 1 shl ceil(log2(AWidth));
  h := 1 shl ceil(log2(AHeight));

  //Decide whether a new texture object has to be created
  if (w <> FWidth) or (h <> FHeight) or
     (ABitDepth <> FBitDepth) or (not Loaded) then
  begin
    FlushTexture;
    new(PCardinal(FTexture));
    glGenTextures(1,FTexture);
    newtex := true;
  end else
    newtex := false;

  //Bind the current texture
  glBindTexture(GL_TEXTURE_2D, PCardinal(FTexture)^);

  //Set some properties
  FWidth := w;
  FHeight := h;
  FBitDepth := ABitDepth;
  FBaseWidth := AWidth;
  FBaseHeight := AHeight;
  FHasMipMap := false;

  //Reserve memory for storing the texture data 
  GetMem(mem,w *h * Ord(ABitDepth) div 8);
 
  try
    if ABitDepth = ad32Bit then
    begin
      if newtex or FParent.FMipmaps then
      begin
        cur32 := PLongWord(mem);
        pnt32 := Src;
        for y := 0 to AHeight - 1 do
        begin
          Move(pnt32^, cur32^, AWidth * 4);
          inc(pnt32, AWidth);
          inc(cur32, w);
        end;
      end;

      if FParent.FMipmaps then
      begin
        FHasMipMap := true;
        gluBuild2DMipmaps(GL_TEXTURE_2D, 4, w, h, GL_BGRA, GL_UNSIGNED_BYTE, mem)
      end
      else
      begin
        if newtex then
        begin
          glTexImage2D(
            GL_TEXTURE_2D, 0, GL_RGBA,
            w, h,
            0, GL_BGRA, GL_UNSIGNED_BYTE, mem);
        end else
        begin
          glTexSubImage2D(
            GL_TEXTURE_2D, 0,
            0, 0, BaseWidth, BaseHeight,
            GL_BGRA, GL_UNSIGNED_BYTE, Src)
        end;
      end;
    end
    else
    begin
      cur16 := PWord(mem);
      pnt32 := Src;
      for y := 0 to AHeight - 1 do
      begin
        for x := 0 to w - 1 do
        begin
          if (x < AWidth) then
          begin
            cur16^ := ABGRTo16Bit(pnt32^.a,pnt32^.b,pnt32^.g,pnt32^.r);
            inc(pnt32);
          end;
          inc(cur16);
        end;
      end;

      glTexImage2D(    GL_TEXTURE_2D, 0, GL_RGBA16, w, h, 0, GL_RGBA, GL_UNSIGNED_SHORT_4_4_4_4, mem);
    end;

  finally
    FreeMem(mem,w*h* Ord(ABitDepth) div 8);
  end;
end;

// we still can use LoadFromMemory to load from TAd2dBitmap

procedure TOGLBitmapTexture.LoadFromBitmap(ABmp: TAd2dBitmap; ABitDepth: TAdBitDepth);
begin
  LoadFromMemory(ABmp.ScanLine, ABmp.Width, ABmp.Height, ABitDepth);
end;

Thanks!