win32forth-cvs Mailing List for Win32Forth (Page 3)

SourceForge Headquarters 225 Broadway Suite 1600 San Diego, CA 92101 +1 (858) 422-6466

Update of /cvsroot/win32forth/win32forth/demos/OpenGLdemos
In directory sfp-cvs-1.v30.ch3.sourceforge.com:/tmp/cvs-serv5521

Added Files:
	Body.bmp CUBE.BMP Floor.bmp HelpForm.f OpenGl_Hello.f 
	UfoWithRobot.f 
Log Message:
Jos: Putting all OpenGL demos in one map and adding a new one. 
Just one demo still to go...

--- NEW FILE: CUBE.BMP ---
(This appears to be a binary file; contents omitted.)

--- NEW FILE: OpenGl_Hello.f ---
anew -OpenGl_Hello.f       \ To show how an OpenGL drawing can be made in Win32Forth

s" src\lib\OpenGl" "fpath+ \ For OpenGL support

needs opengl.f             \ The OpenGl wrapper and many tools

menubar Openglmenu         \ Define a menu for the OpenGL window
  popup "&File"     menuitem   "E&xit"  bye ;
endbar

needs oglwin.f              \ The OpenGL window

\  Next starts the OpenGL part. That might need some study.

Font vFont

0 value baselist

: init-3Dfont  ( -- )
    sizeof glyphmetricsfloat 256 * malloc to lpgmf_buffer
    255 glGenLists to baselist
    s" Comic Sans MS" SetFaceName: vFont
    Create: vFont
    Handle: vFont ghdc call SelectObject               \ Old font on the stack
    ghdc 1 255 baselist 0.2e 0.09e                      \ create display lists
    WGL_FONT_POLYGONS lpgmf_buffer wglUseFontOutlines  \ for the selected font
    ( OldFont) ghdc call SelectObject                   \ Restore the old font
    call DeleteObject ?winerror ; \ Delete the new font. It is now in the list

: eye-parameters ( f: -- eyex eyey eyez  centerx centery centerz upx upy upz  )
\  eyex    eyey      eyez
   .0000e   .2300e    4.130e
\ centerx  centery   centerz
   .0000e   .1724e    3.340e
\ upx       upy      upz
   00000e   .000e     -.02000e ;

: set-viewpoint
    GL_PROJECTION glMatrixMode             \ starting the projection matrix
    glLoadIdentity

    GL_COLOR_BUFFER_BIT GL_DEPTH_BUFFER_BIT OR glClear
    0.0e0  0e0  .0e0     glColor3f         \ The screen color

\ Setting up a perspective in the projection matrix.
\ This will affect the entire scene.
    47.00e 1.000e .0100e 15.00e  gluPerspective
    0.00e .00e -.200e .000e      glRotatef            \ deg x y z rotate eye
\ Setting up a viewing transformation
    eye-parameters gluLookAt
    .1290e .1583e .1700e    glscalef                        \ Scale it a bit
    0.00e .00e -.200e .000e glRotatef  \ deg x y z  Rotate around the center
    -.8700e 1.399e 21.40e   glTranslatef       \ x y z position of the scene
    4.000e -1.400e .0000e .0000e glRotatef   \ deg x y z  Rotate all objects
\ Continue with the model matrix for the object(s)
    GL_MODELVIEW glMatrixMode ;

: InitGL  ( -- )
    init-3Dfont
\ Enable a number of features
    GL_SMOOTH    glShadeModel
    GL_DEPTH_TEST glEnable
    GL_FRONT GL_AMBIENT glColorMaterial
    GL_COLOR_MATERIAL glEnable
    GL_LIGHTING   glEnable
    GL_LIGHT0     glEnable ;

: DrawIntro ( -- )
    0.00e 1.1624e .1766e 0.3000e objectcolor!  \ Prepair the color of the object
    GL_POLYGON               \           fill
      -10.00e 0e 0.5e 0e     \       Rotation f: deg xg yg zg
      .2333e .2531e  .7000e  \        Scaling f: xs ys zs
     -.4000e .2100e -.4000e  \ Transformation f: xt yt zt
      [rot-scaled-object  ( fill -- ) ( f: deg xg yg zg   xs ys zs   xt yt zt -- )
           s" Hello OpenGL" baselist glType
      object]

    0.00e -4.038e 1.977e .3000e  objectcolor!
    GL_POLYGON
      -10.00e 0e 0.5e 0e
      .2333e   .2531e  .7000e
      -.4000e -.1900e -.4000e
         [rot-scaled-object  ( fill -- ) ( f: deg xg yg zg   xs ys zs   xt yt zt -- )
              s" in Win32Forth." baselist glType
         object]
    show-frame ;

\ Startup and exit part:

: RefreshIntro ( - )           \ Should be used when the window is repainted
    InitGL                                            \ Initialize the scene
    set-viewpoint
    DrawIntro   ;                                           \ Draw the scene

true to static-scene                          \ This drawing does not change

: ShowIntro ( -- )
  Start: OpenGLWindow                           \ Starting the OpenGl window
  ['] drop is KeyboardAction           \ Disable all keys here except escape
  RefreshIntro ;

: ExitIntro ( - )                                         \ The cleanup part
  baselist 255 glDeleteLists                 \ Kill  the 3d Font in the list
  lpgmf_buffer free  ;                               \ Free the lpgmf_buffer

  ShowIntro                \ Start the OpenGL window with the OpenGL drawing.
' RefreshIntro is painting \ Action when the window is repainted ( resized etc )

\s

--- NEW FILE: UfoWithRobot.f ---
Anew UfoWithRobot          \ To demonstrate the new 3D turtle.

s" src\lib\OpenGl" "fpath+ \ For OpenGL support

needs opengl.f             \ The OpenGl wrapper and many tools

menubar Openglmenu         \ Define a menu for the OpenGL window
  popup "&File"     menuitem   "E&xit"  bye ;
endbar

needs oglwin.f              \ The OpenGL window
needs Helpform.f            \ For the help window

\ ---[ DrawGLScene ]-------------------------------------------------
\ Here goes our drawing code

\ Define the various display lists
/BoxList mkstruct: SmallBox
/BoxList mkstruct: floor
/BoxList mkstruct: Body
/BoxList mkstruct: NodeUnit

: BuildLists ( #lists -- )
  glGenLists to lists	\ Compile the lists and specify the width height and depth (xyz)
  .32e  .32e  .32e	SmallBox	CompileBox
   14e  .2e    4e	Floor		CompileBox
  .3e   .85e   .3e	Body		CompileBox
  .05e  .15e   .15e	NodeUnit	CompileBox
 ;

\ Define and load various textures

0 value Texture-Ufo
0 value Texture-Floor
0 value Texture-Body

: LoadGLTextures ( -- )
	3 Create-Textures				\ Create the all the needed textures
	s" cube.bmp"  LoadTexture to Texture-Ufo	\ Load the texture and save the name
	s" floor.bmp" LoadTexture to Texture-Floor	\ Load the texture and save the name
	s" Body.bmp"  LoadTexture to Texture-Body	\ Load the texture and save the name
 ;

: SetupLight
	GL_LIGHT0	glEnable			\ enable light0
	GL_LIGHTING	glEnable			\ enable lighting
\  gray  blue   green  red
	4.50000e 4.5e 4.5e 4.5e  fref4LambientN floatsf@+ model-ambient GLfloat!
	GL_LIGHT_MODEL_AMBIENT model-ambient  glLightModelfv

\  gray  blue   green  red
\	1e 1e 1e 1e fref4DiffuseV floatsf@+ lightcolor GLfloat!
\	GL_LIGHT0  GL_DIFFUSE   lightcolor    glLightfv

\   ???     y    z      x
	1e   .9900e 1.478e 0.021e  fref3LpositionL floatsf@+ lightPosition GLfloat!
	GL_LIGHT0  GL_POSITION  lightPosition  glLightfv
 ;

\ Initialization OpenGL

0 value 0quadratic
: InitGL ( -- boolean )
    	LoadGLTextures					\ Load in the texture
	GL_TEXTURE_2D		glEnable		\ Enable texture mapping
	GL_SMOOTH		glShadeModel 		\ Enable smooth shading
	.2e .2e .5e 0.5e 	glClearColor 		\ A blue background
	1e			glClearDepth		\ Depth buffer setup
	GL_DEPTH_TEST		glEnable 		\ Enable depth testing
	GL_LEQUAL		glDepthFunc 		\ Type of depth test to do
	GL_COLOR_MATERIAL 	glEnable		\ enable material coloring
        GL_PERSPECTIVE_CORRECTION_HINT GL_NICEST glHint \ Really nice perspective calculations
	4 BuildLists 					\ Build the display lists
	SetupLight
 ;

\ Set the viewpoint

: set-viewpoint ( -- )   				\ The call to glViewport is done in Opengl.f
	GL_PROJECTION 	glMatrixMode 			\ Switch to the projection view
  \ Set our perspective - the F/ calcs the aspect ratio of w/h
  100e widthViewport  S>F heightViewport  S>F F/   0.1e 100e  GluPerspective \ (  f: fovy aspect near far-- )
	GL_MODELVIEW 	glMatrixMode 			\ Switch to the model view
;

create 0colors 1e F, 0e F, 0e F,

: Save#elements		( n - n )	dup to #elements ;

: AddElement ( f: red green blue - )
   glColor3f  DrawReposition
 ;

\ Various parts for the round Ufo

: AddGreenElements ( n - )
  Save#elements 0
     do   0e    i  IncrColor  0e AddElement  loop ; \ Adding a colored element

: AddRedElements ( n - )
   Save#elements 0
     do   i  IncrColor  0e  0e   AddElement  loop ;

: AddBlueElements ( n - )
   Save#elements 0
     do   0e  0e i  IncrColor    AddElement  loop ;

: AddYelloElements ( n - )
   Save#elements 0
     do  i  IncrColor  fdup 0e   AddElement  loop ;

\ For the robot body
: AddBodyElements ( n - )
   Save#elements 0
     do  .175e  fdup 0e          AddElement  loop ;

: AddWhiteElements ( n - )
   Save#elements 0
     do i  IncrColor  fdup fdup  AddElement  loop ;

\ Various parts in the drawing

:Part .Floor ( f: deg xg yg zg    xt yt zt -- )
	Floor to element		\ Using the display list of the floor which contains the sizes
	Texture-Floor Bind2DTexture	\ Select it's texture
	0.08e  fdup fdup  glColor3f	\ Select a color
	DrawReposition			\ It consists of 1 element and contains no additional elements
 ;Part

:Part .Ufo ( f: deg xg yg zg    xt yt zt -- )
   SmallBox to element   \ Each element is a SmallBox
   Texture-Ufo Bind2DTexture		\ Select it's texture
   5 AddGreenElements			\ Add a number of green cubes
	 60 0 do			\ Repeat
		90e 0e 0e 1e glRotatef	\ Turn Z ( up)
		5 AddRedElements

		90e 0e 1e 1e glRotatef	\ Turn Y and Z ( down + left )
		5 AddBlueElements	\ Add blue cubes

		90e 0e 0e 1e glRotatef	\ Turn Z
		9 AddYelloElements	\ Add yello cubes

		90e 0e 1e 1e glRotatef	\ Turn Y and Z
		9 AddWhiteElements	\ Add white cubes
	loop
 ;Part

\ All parts are attached to .Body, so keep the body in the starting matrix
\ Do not use glPushMatrix or :Part here.
: .Body  ( -- )
   body to element		\ Use body as the element for expanding
   .175e fdup 0.09e  glColor3f	\ Select a color
   DrawReposition		\ The body has 1 element and contains no additional elements
 ;

:Part .RightArm ( f: deg xg yg zg    xt yt zt -- )	\ :Part also takes care for the joint
	7 AddWhiteElements 				\ Draw the upper right arm
	-29.00e .0000e .0000e 1.600e	0e 0e 0e joint	\ The joint for the lower right arm
	8 AddWhiteElements				\ Draw the lower right arm
 ;Part

:Part .LeftArm ( f: deg xg yg zg    xt yt zt -- )
	7 AddWhiteElements				\ The upper arm
	97.00e .0000e .0000e 1.600e	0e 0e 0e joint	\ The Lower left arm
	8 AddWhiteElements
 ;Part

:Part .head ( f: deg xg yg zg    xt yt zt -- )
	3 AddWhiteElements				\ The neck
	90.00e .0000e -.0593e 1.600e 	.0403e -.1139e .0000e  joint
	5 AddWhiteElements 				\ The head
 ;Part

:Part .LeftLeg ( f: deg xg yg zg    xt yt zt -- )
	11 AddWhiteElements 				\ The upper left leg
	-23.00e .4000e .0000e -1.200e	-.0173e -.0025e .0000e joint
	12 AddWhiteElements				\ The lower left leg
 ;Part

:Part .RightLeg ( f: deg xg yg zg    xt yt zt -- )
	11 AddWhiteElements 				\ The upper right leg
	25.00e .0000e .0000e -.6000e	-.0173e -.0025e .0000e  joint
	12 AddWhiteElements				\ The lower right leg
 ;Part

:xPart .Robot ( f: deg xg yg zg    xt yt zt -- )  \ :xPart activates also the m and r key functions
	Texture-Body Bind2DTexture	\ Select the texture for the body
	.Body				\ The next parts are attached to the body
	Texture-Ufo Bind2DTexture	\ Select the texture for the other parts
	NodeUnit to element		\ Use the NodeUnit for expanding the other parts
	180.0e  .1580e .1580e  .0000e 	-.3168e .4529e  .0185e	.head
	184.0e  .0000e .1709e  .0000e	-.47e   .3535e  .0185e	.LeftArm
	-4.000e .0000e -.8000e -1.400e	-.1717e .3535e  .0185e	.RightArm
	114.0e  .0000e .0000e  -.6000e	-.3705e -.4376e .0185e	.LeftLeg
	65.00e  .0000e .0000e  -.6000e	-.2134e -.4376e .0185e	.RightLeg
 ;Part

: .Scene ( -- )
	GL_COLOR_BUFFER_BIT GL_DEPTH_BUFFER_BIT OR  glClear	\ Clear the screen
	\ glLoadIdentity
	0e 0e 0e 0e		.0000e  -5.00e  -7.600e	.Floor
	-.000e .00e 0.100e 00e  fref4RotG   floatsf@+
	-1.200e .4000e  -7.000e	fref3TransI floatsf@+ .Ufo \ The keys g and i can be used
	-47.e .20e .800e .0e  	4.007e  -3.163e -6.430e	.Robot
 ;

: DrawGLScene ( -- )
  .Scene .changed-fps>title  show-frame
 ;

\ ---[ Help text available Keys ]----------------------------------------------

: .change-Turtle  ( adr-flookat - ) ( f: n - )  f! ( DrawGLScene) ;

: HandleKeyPress ( &event -- )
  case
     VK_RIGHT   of  zx .change-Turtle			endof  \ right
     VK_LEFT    of -zx .change-Turtle			endof  \ left
     VK_UP      of  zy .change-Turtle			endof  \ up
     VK_DOWN    of -zy .change-Turtle			endof  \ down
     VK_PGUP    of -zz .change-Turtle			endof  \ zoom-
     VK_PGDN    of  zz .change-Turtle endof \ zoom. Forwards is DOWN on the negative z-axis!  117
     VK_HOME    of reset-active-function painting	endof  \ use defaults
     VK_.       of -zr  if  .change-Turtle  then	endof  \ rotate-
     VK_,       of  zr  if  .change-Turtle  then	endof  \ rotate
     VK_DEL     of  clear-all-offsets painting		endof
     VK_-       of  decr_interval			endof  \ decr
     VK_=       of  incr_interval			endof  \ incr
   ascii w      of start/end-fullscreen                 endof

   ascii i      of ['] fref3TransI 	is-fref3D  endof  \ move ufo
   ascii g      of ['] fref4RotG    	is-fref3D  endof  \ rotate ufo
   ascii m      of ['] frefT3MoveM	is-fref3D  endof  \ move robot
   ascii r      of ['] frefT4RotR	is-fref3D  endof  \ rotate robot

\ Only active when the source is changed:
   ascii c      of ['] frefT3Color	is-fref3D  endof  \ color turtle
   ascii s      of ['] frefT3RotS	is-fref3D  endof  \ scale the elements
   ascii n      of ['] frefT3Elements	is-fref3D  endof  \ #elements turtle
   ascii x      of ['] frefT3MoveX	is-fref3D  endof  \ orbit araound a turnpoint
   ascii z      of start/stop-slow-action          endof

  h12$ ShowHelp \ Show help when an inactive key is pressed
  endcase
  DrawGLScene
 ;

: _exitdrawing  ( -- )               \ For a clean start of the next drawing
  DeleteTextures
  true to resizing?
 ;

: DrawUfoWithRobot  ( -- )           \ (R)edraw of the scene.
    ResetOpenGL                      \ Cleanup from a previous drawing
    InitGL                           \ Enable some features and load textures
    set-viewpoint                    \ Set the viewpoint
    DrawGLScene                      \ Draw the scene
 ;

: InitUfoWithRobot  ( -- )               \ The startup
    ['] HandleKeyPress is KeyboardAction \ Use the keystrokes for this drawing only
    ['] _Exitdrawing is ExitScene        \ Specify Exitdrawing to free allocated memory
    Start: OpenGLWindow
    DrawUfoWithRobot
 ;

true to static-scene                     \ No automatic scene change

InitUfoWithRobot
'  DrawUfoWithRobot is painting

\s

--- NEW FILE: Floor.bmp ---
(This appears to be a binary file; contents omitted.)

--- NEW FILE: HelpForm.f ---
\ Helpform.f

\- textbox needs excontrols.f

aNew -Helpform.f

defer FocusOpenGLWindow

: $|  ( -<line>- )
    0 temp$ !
    source 3 /string temp$ +place
    crlf$ count temp$  +place
    here temp$ c@ allot
    temp$ 1+ swap temp$ c@ cmove
    (source) @ >IN !
 ; immediate

: :long$ create  -1 ,
     does> lcount
 ; immediate

: ;long$  ( - )
  here last @ name> cell+ dup>r - r> ! \ Store the lcount
  0 ,                                  \ Add a zero
 ;

0 value zHelpText$

: zHelpText  ( adr cnt - )
   drop to zHelpText$
 ;

:Object HelpForm                <Super DialogWindow

Font WinFont           \ default font
' 2drop value WmCommand-Func   \ function pointer for WM_COMMAND
ColorObject FrmColor      \ the background color

\ Font setting definitions
Font MText1-font
: Set-MText1-font ( -- )
                -14          Height: MText1-font
                0             Width: MText1-font
                0        Escapement: MText1-font
                0       Orientation: MText1-font
                400          Weight: MText1-font
                0           CharSet: MText1-font
                3      OutPrecision: MText1-font
                2     ClipPrecision: MText1-font
                1           Quality: MText1-font
                49   PitchAndFamily: MText1-font
                s" Courier New" SetFacename: MText1-font ;

MultiLineTextBox MText1
PushButton btOK

:M ClassInit:   ( -- )
                ClassInit: super
                \ Insert your code here, e.g initialize variables, values etc.
                ;M

:M WindowStyle:  ( -- style )
                WS_POPUPWINDOW WS_DLGFRAME or
                ;M

\ N.B if this form is a modal form a non-zero parent must be set
:M ParentWindow:  ( -- hwndparent | 0 if no parent )
                hWndParent
                ;M

:M WindowTitle: ( -- ztitle )
                z" Help"
                ;M

:M StartSize:   ( -- width height )
                611 490

                ;M

:M StartPos:    ( -- x y )
                 CenterWindow: Self swap width 2/ + 60 + swap 14 +
                ;M

:M Close:        ( -- )
                \ Insert your code here, e.g any data entered in form that needs to be saved
                Close: super
                ;M

:M WM_COMMAND   ( h m w l -- res )
                dup 0=      \ id is from a menu if lparam is zero
                if        over LOWORD CurrentMenu if dup DoMenu: CurrentMenu then
                          CurrentPopup if dup DoMenu: CurrentPopup then drop
                else	  over LOWORD ( ID ) self   \ object address on stack
                          WMCommand-Func ?dup    \ must not be zero
                          if        execute
                          else    2drop   \ drop ID and object address
                          then
                then      0 ;M

: FormAction  { id obj -- }
   id IDOK = if  close: Self then
;

:M SetCommand:  ( cfa -- )  \ set WMCommand function
                to WMCommand-Func
                ;M

:M On_Init:     ( -- )
                On_Init: Super
                ['] FormAction SetCommand: self

                s" MS Sans Serif" SetFaceName: WinFont
                8 Width: WinFont
                Create: WinFont

                \ set form color to system color
                COLOR_BTNFACE Call GetSysColor NewColor: FrmColor

                1000 SetTextLimit: MText1
                self Start: MText1
                30 32 556 383 Move: MText1
                Set-MText1-font
                Create: MText1-font
                Handle: MText1-font SetFont: MText1
                zHelpText$  SetTextZ: MText1

                true ReadOnly: MText1
                10 5 SetMargins: MText1

                IDOK SetID: btOK
                self Start: btOK
                253 440 100 25 Move: btOK
                Handle: Winfont SetFont: btOK
                s" OK" SetText: btOK
                ;M

:M start:       ( -- )
                start: Super
               \ FocusOpenGLWindow
                ;M

:M On_Paint:    ( -- )
                0 0 GetSize: self Addr: FrmColor FillArea: dc
                ;M

:M On_Done:    ( -- )
                Delete: WinFont
                Delete: MText1-font
                \ Insert your code here, e.g delete fonts, any bitmaps etc.
                On_Done: super
                ;M

;Object

: ShowHelp ( zHelpText cnt - )
   zHelpText close: HelpForm start: HelpForm
 ;

\ Use:

:long$ InitialText$
$| zHelpText$ has not been set.
$| Use zHelpText first.
$| zHelpText expects a long counted 0 terminated string.
  ;long$

InitialText$ zHelpText

\ start: HelpForm abort \ Activate this line for a demo.
\s

--- NEW FILE: Body.bmp ---
(This appears to be a binary file; contents omitted.)

2004	Jan	Feb	Mar	Apr	May	Jun	Jul	Aug	Sep	Oct	Nov	Dec (70)
2005	Jan (38)	Feb (4)	Mar (11)	Apr (49)	May (81)	Jun (65)	Jul (36)	Aug (57)	Sep (63)	Oct (57)	Nov (49)	Dec (41)
2006	Jan (75)	Feb (80)	Mar (10)	Apr (13)	May (100)	Jun (100)	Jul (77)	Aug (87)	Sep (80)	Oct (124)	Nov (39)	Dec (41)
2007	Jan (20)	Feb (32)	Mar (32)	Apr (43)	May (146)	Jun (40)	Jul (49)	Aug (33)	Sep (25)	Oct (19)	Nov (11)	Dec (8)
2008	Jan (4)	Feb (11)	Mar (31)	Apr (40)	May (34)	Jun (24)	Jul (39)	Aug (104)	Sep (27)	Oct (35)	Nov (34)	Dec (97)
2009	Jan (75)	Feb (29)	Mar (45)	Apr (76)	May (121)	Jun (103)	Jul (67)	Aug (28)	Sep (22)	Oct (39)	Nov (9)	Dec (15)
2010	Jan (7)	Feb (39)	Mar (40)	Apr (57)	May (67)	Jun (69)	Jul (49)	Aug (68)	Sep (22)	Oct (7)	Nov (2)	Dec (10)
2011	Jan	Feb	Mar (10)	Apr (4)	May (6)	Jun (10)	Jul (16)	Aug (23)	Sep (9)	Oct	Nov (28)	Dec (3)
2012	Jan (11)	Feb (10)	Mar (1)	Apr	May (4)	Jun (3)	Jul (3)	Aug (4)	Sep (2)	Oct	Nov	Dec (1)
2013	Jan	Feb (7)	Mar (30)	Apr (4)	May (4)	Jun (8)	Jul (10)	Aug (4)	Sep	Oct (2)	Nov (24)	Dec (13)
2014	Jan (7)	Feb (2)	Mar	Apr (1)	May (9)	Jun	Jul (3)	Aug (9)	Sep	Oct (2)	Nov	Dec (3)
2015	Jan (4)	Feb (2)	Mar	Apr	May	Jun (1)	Jul	Aug (5)	Sep (1)	Oct (4)	Nov (7)	Dec (39)
2016	Jan (17)	Feb (2)	Mar (2)	Apr	May (1)	Jun (1)	Jul	Aug	Sep	Oct	Nov (1)	Dec (2)
2017	Jan	Feb (3)	Mar	Apr	May (1)	Jun (2)	Jul	Aug (3)	Sep	Oct	Nov	Dec (2)
2018	Jan	Feb	Mar (2)	Apr	May	Jun	Jul	Aug	Sep	Oct	Nov	Dec
2019	Jan	Feb	Mar (1)	Apr	May	Jun	Jul	Aug	Sep	Oct	Nov	Dec
2022	Jan	Feb	Mar	Apr	May (1)	Jun	Jul	Aug	Sep (1)	Oct (2)	Nov (1)	Dec (1)
2023	Jan	Feb	Mar	Apr	May	Jun	Jul	Aug (1)	Sep	Oct (1)	Nov	Dec
2025	Jan	Feb	Mar	Apr	May	Jun (1)	Jul	Aug	Sep	Oct	Nov	Dec

win32forth-cvs Mailing List for Win32Forth (Page 3)

win32forth-cvs — CVS Commit List