vim-latex-devel

[Vim-latex-devel] splitting lines

[Carl M. <cm...@ma...>]

Here is another feature which I would very much like to see.
Automatic splitting of lines is a great feature for editing.
On the other hand, it is a pain when an editor splits up a 
math expression $...$.  As part of auctex.vim, I wrote the
following function(s) which keep $...$ expressions on the
same line, while allowing the user to keep typing without
hitting <CR>.

Best wishes,
Carl Mueller

----------------------

" The following is necessary for TexFormatLine() and TexFill()
set tw=0
" substitute text width
let b:tw = 79

"  With this map, <Space> will split up a long line, keeping the dollar
"  signs together (see the next function, TexFormatLine).
inoremap <buffer> <Space> <Space><Esc>:call <SID>TexFill(b:tw)<CR>a
function! s:TexFill(width)
    if col(".") > a:width
	exe "normal a##\<Esc>"
	call <SID>TexFormatLine(a:width)
	exe "normal ?##\<CR>2s\<Esc>"
    endif
endfunction

function! s:TexFormatLine(width)
    normal $
    let length = col(".")
    let go = 1
    while length > a:width+2 && go
    let between = 0
    let string = strpart(getline(line(".")),0,a:width)
    " Count the dollar signs
    let evendollars = 1
    let counter = 0
    while counter <= a:width-1
	if string[counter] == '$' && string[counter-1] != '\'  " Skip \$.
	   let evendollars = 1 - evendollars
	endif
	let counter = counter + 1
    endwhile
    " Get ready to split the line.
    exe "normal " . (a:width + 1) . "|"
    if evendollars
    " Then you are not between dollars.
       exe "normal ?\\$\\| \<CR>W"
    else
    " Then you are between dollars.
	normal F$
	if col(".") == 1
	   let go = 0
	endif
    endif
    exe "normal i\<CR>\<Esc>$"
    let length = col(".")
    endwhile
endfunction

Re: [Vim-latex-devel] splitting lines

[Srinath A. <sr...@ee...>]

Hello Carl,

Thanks for the contribution. I must say, this is the most convenient way
for us to incorporate someone's work. You have already done the work of
distilling out the portion which we need... Most excellent! Thanks!

I just tried it out and it looks pretty cool. However, a (small) bug
report. Try typing the following (pretty pointless drivel).

this is $ a new math environment which is really really really long ...

basically, keep typing in one line without typing in the second $. You
will notice that new lines keep getting inserted with every space after
a while.  Also, it would be nice if the &tw setting is checked before
setting it to zeo and hardcoding in b:tw=79.

Also, since we have contributions from so many people coming in, we need
to step back and figure out a good way to organize LaTeX-suite so that
incorporating contributions from people is seamless...

Here's a suggestion off the top of my head.

For such scripts which are kind of independent of the rest of
LaTeX-suite, we could just put them in the ftplugin/tex/ directory. We
could name such files with a leading "ls_" or something similar to
prevent conflicts... A few questions arise. How will such a "plugin"
know where to put itself in the menus?

So please be a little patient :) This function is definitely going into
LaTeX-suite. However, please give us some time to figure out the best
way to incorporate it. Also, mapping the space bar is pretty intense. We
definitely need to test this a lot before taking so much control away
from vim.

If you wish, you can keep in sync with our conversations and give
suggestions by signing up with the vim-latex-devel mailing list. See

https://lists.sourceforge.net/lists/listinfo/vim-latex-devel

for instructions.

Thanks,
Srinath

On Fri, 8 Nov 2002, Carl Mueller wrote:

> Here is another feature which I would very much like to see.
> Automatic splitting of lines is a great feature for editing.
> On the other hand, it is a pain when an editor splits up a
> math expression $...$.  As part of auctex.vim, I wrote the
> following function(s) which keep $...$ expressions on the
> same line, while allowing the user to keep typing without
> hitting <CR>.
>
> Best wishes,
> Carl Mueller
>
> ----------------------
>
> " The following is necessary for TexFormatLine() and TexFill()
> set tw=0
> [snip]

-- 
Srinath Avadhanula
Nov 9 1:01am
"The chain which can be yanked is not the eternal chain."
		-- G. Fitch