tcltk-perl

[tcltk-perl] Change the way that %-subs are handled.

[Jeff H. <je...@Ac...>]

I finally figured out the magic that makes the commands that
require %-substitutions to work, like so:

     my $sub = sub {
	my ($X, $Y) = (Tcl::Ev('X'), Tcl::Ev('Y'));
	print "X: $X Y: $Y\n";
     };
     $mw->bind('<Motion>', \\'XY', $sub);

This double-reference to the scalar seems a little weird to me.
It would of course be best if we could somehow manage to get the
substitutions as part of the command.

Now that we properly handle command callbacks with args, I would
like to recommend this alternative:

     $mw->bind('<Motion>', [$sub, Tcl::EV('X', 'Y', ...), "foo", ...]);

This would magic convert to the either the same special things
that requires the Tcl::Ev in the sub, or perhaps (if I can make
the magic work), have it pass the %-subs to the Tcl side of the
callback, while maintaining the "foo", ... for the perl side.

Any objections, or better ideas?

-- 
     Jeff Hobbs, The Tcl Guy
     http://www.ActiveState.com/, a division of Sophos

RE: [tcltk-perl] Change the way that %-subs are handled.

[Jeff H. <je...@Ac...>]

>      my $sub = sub {
> 	my ($X, $Y) = (Tcl::Ev('X'), Tcl::Ev('Y'));
> 	print "X: $X Y: $Y\n";
>      };
>      $mw->bind('<Motion>', \\'XY', $sub);

OK, I've manage to make this work, so the above would be
written as:

my $sub = sub {
    print STDERR "CALLBACK (@_)\n";
};
$mw->bind('<Motion>', [$sub, Tcl::EV('%X', '%Y'), '<Motion>']);

and that would end up printing out something like:

CALLBACK (440 532 <Motion>)

I think this is a much cleaner way to operate.  It allows you
to declare the %-subs you want, like you do in Tcl, and it
passes them to your sub.  The only limitation is that the
Tcl::EV(...) must come first in the args set, although that is
just a convenience for now.  The core pieces of the code to
make this work in Tcl.pm are:

in Tcl.pm:call():
	elsif ($ref eq 'ARRAY' && ref($arg->[0]) eq 'CODE') {
	    # We have been passed something like [\&subroutine, $arg1, ...]
	    # Create a proc in Tcl that invokes this subroutine with args
	    my $events;
	    if ($#$arg >= 1 && ref($arg->[1]) eq 'Tcl::EV') {
		$events = splice(@$arg, 1, 1);
	    }
	    $args[$argcnt] =
		$interp->create_tcl_sub(sub {
		    splice @_, 0, 3; # remove ClientData, Interp and CmdName
		    $arg->[0]->(@_, @$arg[1..$#$arg]);
		}, $events);
	}

in Tcl.pm:
sub create_tcl_sub {
    my ($interp,$sub,$events,$tclname) = @_;
    unless ($tclname) {
	# stringify sub, becomes "CODE(0x######)" in ::perl namespace
	$tclname = "::perl::$sub";
    }
    unless (exists $anon_refs{$tclname}) {
	$anon_refs{$tclname}++;
	$interp->CreateCommand($tclname, $sub);
    }
    if ($events) {
	$tclname = "$tclname " . join(' ', @{$events});
    }
    return $tclname;
}
sub EV {
    my @events = @_;
    return bless \@events, "Tcl::EV";
}

and then we can get rid of all the other Ev ref stuff.  While this
might not be "ideal", I find it much more logical and easier to work
with than the previous solution.  You could auto-prepend each %, but
I think it's good to keep the logical connection of %-sub there.

Note that this also changes/corrects the call to code refs that take
args to called subroutines to pass args from Tcl first, before the
args that were given in perl.

In somewhat related changes, code and variables created in Tcl from
Perl go into the ::perl namespace in Tcl.

Jeff

Re: [tcltk-perl] Change the way that %-subs are handled.

[Jan D. <ja...@Ac...>]

On Wed, 21 Apr 2004 11:53:37 -0700, "Jeff Hobbs" <je...@Ac...>
wrote:

>$mw->bind('<Motion>', [$sub, Tcl::EV('%X', '%Y'), '<Motion>']);

[...]

>                             You could auto-prepend each %, but
>I think it's good to keep the logical connection of %-sub there.

I would think the Tcl::EV name already provides the connection to event
variables, so I would shorten this to:

  $mw->bind('<Motion>', [$sub, Tcl::EV('XY'), '<Motion>']);

Or do you expect to ever require multi-character variable names here?

Cheers,
-Jan

RE: [tcltk-perl] Change the way that %-subs are handled.

[Jeff H. <je...@Ac...>]

> >$mw->bind('<Motion>', [$sub, Tcl::EV('%X', '%Y'), '<Motion>']);
> [...]
> >               You could auto-prepend each %, but I think 
> >it's good to keep the logical connection of %-sub there.
> 
> I would think the Tcl::EV name already provides the 
> connection to event variables, so I would shorten this to:
> 
>   $mw->bind('<Motion>', [$sub, Tcl::EV('XY'), '<Motion>']);
> 
> Or do you expect to ever require multi-character variable names here?

The documentation for Tcl always refers to %a, %b, etc,
but I see that Perl/Tk removes the percent and uses Ev('a').
Of course, their Ev does other things that are ... odd, and
more specifically, their docs aren't scrubbed of many other
references to %a, %b, etc in doc details.

I'm not stuck on Tcl::EV taking '%a', '%b' vs 'ab', but one
advantage is that, as you can see from the super-simple
implementation:

sub EV {
    my @events = @_;
    return bless \@events, "Tcl::EV";
}

I don't actually process the args ... which means I can use
this for other means, like:

$mw->bind('<3>', [\&mysub, Tcl::EV('[winfo class %W]', '%X', '%Y')]);

as the args are just passed right on to Tcl and are evaled
there before the callback into Perl.

So do you still think it's work "simplifying"?

Jeff