[24dce1]: help / stylesheets / plainhtml.xsl.in  Maximize  Restore  History

Download this file

178 lines (164 with data), 6.6 kB

<?xml version="1.0" encoding="utf-8"?>
<!-- This file is part of the gimp-help-2 project and is 
     (C) 2002, 2003 Daniel Egger.
     You may use this file in accordance to the GNU Free Documentation License
     Version 1.1 which is available from http://www.gnu.org. -->
<xsl:stylesheet xmlns:xsl="http://www.w3.org/1999/XSL/Transform" version="1.0">
  <xsl:import href="@STYLEBASE@/xhtml/profile-chunk.xsl" />
  <xsl:param name="html.stylesheet">gimp-help-plain.css
    gimp-help-screen.css</xsl:param>
  <xsl:param name="generate.index">1</xsl:param>
  <xsl:param name="admon.graphics" select="1" />
  <xsl:param name="admon.graphics.path">../images/</xsl:param>
  <xsl:param name="callout.graphics.path">../images/callouts/</xsl:param>
  <xsl:param name="section.autolabel" select="1" />
  <xsl:param name="make.valid.html" select="1" />
  <xsl:param name="collect.xref.targets" select="'yes'" />
  <xsl:param name="targets.filename" select="'gimp-xrefs.xml'" />
  <xsl:param name="toc.section.depth" select="3" />
  <xsl:param name="chunk.section.depth" select="3" />
  <xsl:param name="chunker.output.indent" select="'yes'" />

  <!-- Add NotInToc role to simplesect, which is using in fdl.xml to
       deal with FDL-In-TOC issue.-->
  <xsl:template match="simplesect[@role = 'NotInToc']" mode="toc"/>

  <xsl:template name="header.navigation">
    <xsl:param name="prev" select="/foo"/>
    <xsl:param name="next" select="/foo"/>
    <xsl:param name="nav.context"/>

    <xsl:variable name="home" select="/*[1]"/>
    <xsl:variable name="up" select="parent::*"/>

    <xsl:variable name="row1" select="$navig.showtitles != 0"/>
    <xsl:variable name="row2" select="count($prev) &gt; 0 or (count($up) &gt; 0 and generate-id($up) != generate-id($home) and $navig.showtitles != 0) or count($next) &gt; 0"/>

    <xsl:if test="$suppress.navigation = '0' and $suppress.header.navigation = '0'">
    <div class="navheader">
      <xsl:if test="$row1 or $row2">
        <table width="100%" summary="Navigation header">
          <xsl:if test="$row1">
            <tr>
              <th colspan="3" align="center" id="chaptername">
                <xsl:apply-templates select="$up" mode="object.title.markup"/>
              </th>
            </tr>
          </xsl:if>

          <xsl:if test="$row2">
            <tr>
              <td width="20%" align="left">
                <xsl:if test="count($prev)&gt;0">
                  <a accesskey="p">
                    <xsl:attribute name="href">
                      <xsl:call-template name="href.target">
                        <xsl:with-param name="object" select="$prev"/>
                      </xsl:call-template>
                    </xsl:attribute>
                    <xsl:call-template name="navig.content">
                      <xsl:with-param name="direction" select="'prev'"/>
                    </xsl:call-template>
                  </a>
                </xsl:if>
                <xsl:text>&#160;</xsl:text>
              </td>
              <th width="60%" align="center" id="sectionname">
                <xsl:choose>
                  <xsl:when test="count($up) &gt; 0 and generate-id($up) != generate-id($home) and $navig.showtitles != 0">
                    <xsl:apply-templates select="." mode="object.title.markup"/>
                  </xsl:when>
                  <xsl:otherwise>&#160;</xsl:otherwise>
                </xsl:choose>
              </th>
              <td width="20%" align="right">
                <xsl:text>&#160;</xsl:text>
                <xsl:if test="count($next)&gt;0">
                  <a accesskey="n">
                    <xsl:attribute name="href">
                      <xsl:call-template name="href.target">
                        <xsl:with-param name="object" select="$next"/>
                      </xsl:call-template>
                    </xsl:attribute>
                    <xsl:call-template name="navig.content">
                      <xsl:with-param name="direction" select="'next'"/>
                    </xsl:call-template>
                  </a>
                </xsl:if>
              </td>
            </tr>
          </xsl:if>
        </table>
      </xsl:if>
      <xsl:if test="$header.rule != 0">
        <hr/>
      </xsl:if>
    </div>
    </xsl:if>
  </xsl:template>

  <!-- For unknown reasons the original version of the template starting
       from August 2004 would unwind the path of the sourcecode several 
       times into the processing of the fileref thus prepending the path
       a few times into the src attribute of the img tag -->
  <xsl:template name="mediaobject.filename">
    <xsl:param name="object"></xsl:param>

    <xsl:variable name="data" select="$object/videodata
				      |$object/imagedata
				      |$object/audiodata
				      |$object"/>

    <xsl:variable name="filename">
      <xsl:choose>
	<xsl:when test="$data[@fileref]">
	  <xsl:value-of select="$data/@fileref"/>
	</xsl:when>
	<xsl:when test="$data[@entityref]">
	  <xsl:value-of select="unparsed-entity-uri($data/@entityref)"/>
	</xsl:when>
	<xsl:otherwise></xsl:otherwise>
      </xsl:choose>
    </xsl:variable>

    <xsl:variable name="real.ext">
      <xsl:call-template name="filename-extension">
	<xsl:with-param name="filename" select="$filename"/>
      </xsl:call-template>
    </xsl:variable>

    <xsl:variable name="ext">
      <xsl:choose>
	<xsl:when test="$real.ext != ''">
	  <xsl:value-of select="$real.ext"/>
	</xsl:when>
	<xsl:otherwise>
	  <xsl:value-of select="$graphic.default.extension"/>
	</xsl:otherwise>
      </xsl:choose>
    </xsl:variable>

    <xsl:variable name="graphic.ext">
      <xsl:call-template name="is.graphic.extension">
	<xsl:with-param name="ext" select="$ext"/>
      </xsl:call-template>
    </xsl:variable>

    <xsl:choose>
      <xsl:when test="$real.ext = ''">
	<xsl:choose>
	  <xsl:when test="$ext != ''">
	    <xsl:value-of select="$filename"/>
	    <xsl:text>.</xsl:text>
	    <xsl:value-of select="$ext"/>
	  </xsl:when>
	  <xsl:otherwise>
	    <xsl:value-of select="$filename"/>
	  </xsl:otherwise>
	</xsl:choose>
      </xsl:when>
      <xsl:when test="not($graphic.ext)">
	<xsl:choose>
	  <xsl:when test="$graphic.default.extension != ''">
	    <xsl:value-of select="$filename"/>
	    <xsl:text>.</xsl:text>
	    <xsl:value-of select="$graphic.default.extension"/>
	  </xsl:when>
	  <xsl:otherwise>
	    <xsl:value-of select="$filename"/>
	  </xsl:otherwise>
	</xsl:choose>
      </xsl:when>
      <xsl:otherwise>
	<xsl:value-of select="$filename"/>
      </xsl:otherwise>
    </xsl:choose>
  </xsl:template>
</xsl:stylesheet>

Get latest updates about Open Source Projects, Conferences and News.

Sign up for the SourceForge newsletter:





No, thanks