Menu
▾
▴
[OMPT-svn-commit] SF.net SVN: modplug:[469] trunk/OpenMPT
|
From: <sag...@us...> - 2010-01-16 19:49:00
|
Revision: 469
http://modplug.svn.sourceforge.net/modplug/?rev=469&view=rev
Author: saga-games
Date: 2010-01-16 19:48:28 +0000 (Sat, 16 Jan 2010)
Log Message:
-----------
[New] Added InnoSetup script and resources for OpenMPT installer.
Added Paths:
-----------
trunk/OpenMPT/installer/
trunk/OpenMPT/installer/filetypes.iss
trunk/OpenMPT/installer/install-big.bmp
trunk/OpenMPT/installer/install-small.bmp
trunk/OpenMPT/installer/install.iss
trunk/OpenMPT/installer/mpt.ico
trunk/OpenMPT/installer/packageTemplate/
trunk/OpenMPT/installer/packageTemplate/readme.txt
Added: trunk/OpenMPT/installer/filetypes.iss
===================================================================
--- trunk/OpenMPT/installer/filetypes.iss (rev 0)
+++ trunk/OpenMPT/installer/filetypes.iss 2010-01-16 19:48:28 UTC (rev 469)
@@ -0,0 +1,96 @@
+; OpenMPT Install script - File associations
+; Written by Johannes Schultz
+; http://sagamusix.de/
+; http://sagagames.de/
+
+[Setup]
+ChangesAssociations=yes
+
+[Tasks]
+; common file extensions
+Name: "associate_common"; Description: "Associate OpenMPT with common module files"; GroupDescription: "File associations:";
+Name: "associate_common\mod"; Description: "ProTracker / Noise Tracker / etc. (MOD)";
+Name: "associate_common\s3m"; Description: "Scream Tracker 3 (S3M)";
+Name: "associate_common\xm"; Description: "Fasttracker 2 (XM)";
+Name: "associate_common\it"; Description: "Impulse Tracker (IT)";
+Name: "associate_common\itp"; Description: "Impulse Tracker Project (ITP)";
+Name: "associate_common\mptm"; Description: "OpenMPT (MPTM)";
+; same, but compressed
+Name: "associate_common\compressed"; Description: "Above when compressed (MDR, MDZ, S3Z, XMZ, ITZ, MPTMZ)";
+; less common
+Name: "associate_exotic"; Description: "Associate OpenMPT with less common module files"; GroupDescription: "File associations:";
+Name: "associate_exotic\669"; Description: "Composer 669 (669)";
+Name: "associate_exotic\amf"; Description: "ASYLUM Music Format / Advanced Music Format (AMF)";
+Name: "associate_exotic\ams"; Description: "Extreme Tracker (AMS)";
+Name: "associate_exotic\dbm"; Description: "DigiBooster (DBM)";
+Name: "associate_exotic\dmf"; Description: "X-Tracker (DMF)";
+Name: "associate_exotic\dsm"; Description: "DSIK (DSM)";
+Name: "associate_exotic\far"; Description: "Farandole Composer (FAR)";
+Name: "associate_exotic\gdm"; Description: "General Digital Music (GDM)";
+Name: "associate_exotic\imf"; Description: "Imago Orpheus (IMF)";
+Name: "associate_exotic\j2b"; Description: "Jazz Jackrabbit 2 Music (J2B)";
+Name: "associate_exotic\mdl"; Description: "DigiTracker (MDL)";
+Name: "associate_exotic\med"; Description: "OctaMED (MED)";
+Name: "associate_exotic\mo3"; Description: "MO3 compressed modules (MO3)";
+Name: "associate_exotic\mt2"; Description: "MadTracker 2 (MT2)";
+Name: "associate_exotic\mtm"; Description: "MultiTracker Modules (MTM)";
+Name: "associate_exotic\okt"; Description: "Oktalyzer (OKT)";
+Name: "associate_exotic\psm"; Description: "Epic Megagames MASI (PSM)";
+Name: "associate_exotic\ptm"; Description: "PolyTracker (PTM)";
+Name: "associate_exotic\stm"; Description: "Scream Tracker 2 (STM)";
+Name: "associate_exotic\ult"; Description: "UltraTracker (ULT)";
+Name: "associate_exotic\umx"; Description: "Unreal Music (UMX)";
+Name: "associate_exotic\wow"; Description: "Grave Composer (WOW)";
+
+[Registry]
+; common file extensions
+Root: HKCR; Subkey: ".mod"; ValueType: string; ValueName: ""; ValueData: "OpenMPTFile"; Flags: uninsdeletevalue; Tasks: associate_common\mod
+Root: HKCR; Subkey: ".s3m"; ValueType: string; ValueName: ""; ValueData: "OpenMPTFile"; Flags: uninsdeletevalue; Tasks: associate_common\s3m
+Root: HKCR; Subkey: ".xm"; ValueType: string; ValueName: ""; ValueData: "OpenMPTFile"; Flags: uninsdeletevalue; Tasks: associate_common\xm
+Root: HKCR; Subkey: ".it"; ValueType: string; ValueName: ""; ValueData: "OpenMPTFile"; Flags: uninsdeletevalue; Tasks: associate_common\it
+Root: HKCR; Subkey: ".itp"; ValueType: string; ValueName: ""; ValueData: "OpenMPTFile"; Flags: uninsdeletevalue; Tasks: associate_common\itp
+Root: HKCR; Subkey: ".mptm"; ValueType: string; ValueName: ""; ValueData: "OpenMPTFile"; Flags: uninsdeletevalue; Tasks: associate_common\mptm
+; same, but compressed
+Root: HKCR; Subkey: ".mdr"; ValueType: string; ValueName: ""; ValueData: "OpenMPTFile"; Flags: uninsdeletevalue; Tasks: associate_common\compressed
+Root: HKCR; Subkey: ".mdz"; ValueType: string; ValueName: ""; ValueData: "OpenMPTFile"; Flags: uninsdeletevalue; Tasks: associate_common\compressed
+Root: HKCR; Subkey: ".s3z"; ValueType: string; ValueName: ""; ValueData: "OpenMPTFile"; Flags: uninsdeletevalue; Tasks: associate_common\compressed
+Root: HKCR; Subkey: ".xmz"; ValueType: string; ValueName: ""; ValueData: "OpenMPTFile"; Flags: uninsdeletevalue; Tasks: associate_common\compressed
+Root: HKCR; Subkey: ".itz"; ValueType: string; ValueName: ""; ValueData: "OpenMPTFile"; Flags: uninsdeletevalue; Tasks: associate_common\compressed
+Root: HKCR; Subkey: ".mptmz"; ValueType: string; ValueName: ""; ValueData: "OpenMPTFile"; Flags: uninsdeletevalue; Tasks: associate_common\compressed
+; less common
+Root: HKCR; Subkey: ".669"; ValueType: string; ValueName: ""; ValueData: "OpenMPTFile"; Flags: uninsdeletevalue; Tasks: associate_exotic\669
+Root: HKCR; Subkey: ".amf"; ValueType: string; ValueName: ""; ValueData: "OpenMPTFile"; Flags: uninsdeletevalue; Tasks: associate_exotic\amf
+Root: HKCR; Subkey: ".ams"; ValueType: string; ValueName: ""; ValueData: "OpenMPTFile"; Flags: uninsdeletevalue; Tasks: associate_exotic\ams
+Root: HKCR; Subkey: ".dbm"; ValueType: string; ValueName: ""; ValueData: "OpenMPTFile"; Flags: uninsdeletevalue; Tasks: associate_exotic\dbm
+Root: HKCR; Subkey: ".dmf"; ValueType: string; ValueName: ""; ValueData: "OpenMPTFile"; Flags: uninsdeletevalue; Tasks: associate_exotic\dmf
+Root: HKCR; Subkey: ".dsm"; ValueType: string; ValueName: ""; ValueData: "OpenMPTFile"; Flags: uninsdeletevalue; Tasks: associate_exotic\dsm
+Root: HKCR; Subkey: ".far"; ValueType: string; ValueName: ""; ValueData: "OpenMPTFile"; Flags: uninsdeletevalue; Tasks: associate_exotic\far
+Root: HKCR; Subkey: ".gdm"; ValueType: string; ValueName: ""; ValueData: "OpenMPTFile"; Flags: uninsdeletevalue; Tasks: associate_exotic\gdm
+Root: HKCR; Subkey: ".imf"; ValueType: string; ValueName: ""; ValueData: "OpenMPTFile"; Flags: uninsdeletevalue; Tasks: associate_exotic\imf
+Root: HKCR; Subkey: ".j2b"; ValueType: string; ValueName: ""; ValueData: "OpenMPTFile"; Flags: uninsdeletevalue; Tasks: associate_exotic\j2b
+Root: HKCR; Subkey: ".mdl"; ValueType: string; ValueName: ""; ValueData: "OpenMPTFile"; Flags: uninsdeletevalue; Tasks: associate_exotic\mdl
+Root: HKCR; Subkey: ".med"; ValueType: string; ValueName: ""; ValueData: "OpenMPTFile"; Flags: uninsdeletevalue; Tasks: associate_exotic\med
+Root: HKCR; Subkey: ".mo3"; ValueType: string; ValueName: ""; ValueData: "OpenMPTFile"; Flags: uninsdeletevalue; Tasks: associate_exotic\mo3
+Root: HKCR; Subkey: ".mt2"; ValueType: string; ValueName: ""; ValueData: "OpenMPTFile"; Flags: uninsdeletevalue; Tasks: associate_exotic\mt2
+Root: HKCR; Subkey: ".mtm"; ValueType: string; ValueName: ""; ValueData: "OpenMPTFile"; Flags: uninsdeletevalue; Tasks: associate_exotic\mtm
+Root: HKCR; Subkey: ".okt"; ValueType: string; ValueName: ""; ValueData: "OpenMPTFile"; Flags: uninsdeletevalue; Tasks: associate_exotic\okt
+Root: HKCR; Subkey: ".psm"; ValueType: string; ValueName: ""; ValueData: "OpenMPTFile"; Flags: uninsdeletevalue; Tasks: associate_exotic\psm
+Root: HKCR; Subkey: ".ptm"; ValueType: string; ValueName: ""; ValueData: "OpenMPTFile"; Flags: uninsdeletevalue; Tasks: associate_exotic\ptm
+Root: HKCR; Subkey: ".stm"; ValueType: string; ValueName: ""; ValueData: "OpenMPTFile"; Flags: uninsdeletevalue; Tasks: associate_exotic\stm
+Root: HKCR; Subkey: ".ult"; ValueType: string; ValueName: ""; ValueData: "OpenMPTFile"; Flags: uninsdeletevalue; Tasks: associate_exotic\ult
+Root: HKCR; Subkey: ".umx"; ValueType: string; ValueName: ""; ValueData: "OpenMPTFile"; Flags: uninsdeletevalue; Tasks: associate_exotic\umx
+Root: HKCR; Subkey: ".wow"; ValueType: string; ValueName: ""; ValueData: "OpenMPTFile"; Flags: uninsdeletevalue; Tasks: associate_exotic\wow
+
+; important (setup)
+Root: HKCR; Subkey: "OpenMPTFile"; ValueType: string; ValueName: ""; ValueData: "OpenMPT Module"; Flags: uninsdeletekey; Tasks: associate_common or associate_exotic
+Root: HKCR; Subkey: "OpenMPTFile\DefaultIcon"; ValueType: string; ValueName: ""; ValueData: "{app}\mpt.ico,0"; Tasks: associate_common or associate_exotic
+Root: HKCR; Subkey: "OpenMPTFile\shell\open\command"; ValueType: string; ValueName: ""; ValueData: """{app}\mptrack.exe"" ""%1"""; Tasks: associate_common or associate_exotic
+
+[Files]
+; icon file (should be moved into EXE)
+Source: "mpt.ico"; DestDir: "{app}"; Flags: ignoreversion
+
+
+
+
+
Added: trunk/OpenMPT/installer/install-big.bmp
===================================================================
(Binary files differ)
Property changes on: trunk/OpenMPT/installer/install-big.bmp
___________________________________________________________________
Added: svn:mime-type
+ application/octet-stream
Added: trunk/OpenMPT/installer/install-small.bmp
===================================================================
(Binary files differ)
Property changes on: trunk/OpenMPT/installer/install-small.bmp
___________________________________________________________________
Added: svn:mime-type
+ application/octet-stream
Added: trunk/OpenMPT/installer/install.iss
===================================================================
--- trunk/OpenMPT/installer/install.iss (rev 0)
+++ trunk/OpenMPT/installer/install.iss 2010-01-16 19:48:28 UTC (rev 469)
@@ -0,0 +1,105 @@
+; OpenMPT Install script
+; Written by Johannes Schultz
+; http://sagamusix.de/
+; http://sagagames.de/
+
+[Setup]
+AppId=OpenMPT
+AppVerName=OpenMPT 1.18
+AppVersion=1.18.00.00
+AppName=OpenMPT
+AppPublisher=OpenMPT Devs / Olivier Lapicque
+AppPublisherURL=http://www.openmpt.com/
+AppSupportURL=http://www.openmpt.com/
+AppUpdatesURL=http://www.openmpt.com/
+DefaultDirName={pf}\OpenMPT
+DefaultGroupName=OpenMPT
+AllowNoIcons=yes
+OutputDir=.\
+OutputBaseFilename=OpenMPT Setup
+Compression=lzma
+SolidCompression=yes
+WizardImageFile=install-big.bmp
+WizardSmallImageFile=install-small.bmp
+;LicenseFile=license.txt
+;CreateUninstallRegKey=no
+
+[Tasks]
+; icons and install mode
+Name: "desktopicon"; Description: "{cm:CreateDesktopIcon}"; GroupDescription: "{cm:AdditionalIcons}";
+Name: "quicklaunchicon"; Description: "{cm:CreateQuickLaunchIcon}"; GroupDescription: "{cm:AdditionalIcons}"; Flags: unchecked
+Name: "portable"; Description: "Use program directory to store configuration in (portable mode)"; GroupDescription: "Options:"; Flags: unchecked
+; file associations - put this below all other [tasks]!
+#include "filetypes.iss"
+
+[Languages]
+Name: "en"; MessagesFile: "compiler:Default.isl"
+
+[Files]
+; you may want to change the base paths here
+
+; preserve file type order for best solid compression results (first binary, then text)
+; home folder
+Source: "..\mptrack\bin\mptrack.exe"; DestDir: "{app}"; Flags: ignoreversion
+Source: "..\mptrack\bin\OpenMPT_SoundTouch_i16.dll"; DestDir: "{app}"; Flags: ignoreversion
+Source: "..\mptrack\bin\unmo3.dll"; DestDir: "{app}"; Flags: ignoreversion
+Source: "packageTemplate\readme.txt"; DestDir: "{app}"; Flags: ignoreversion
+Source: "..\packageTemplate\history.txt"; DestDir: "{app}"; Flags: ignoreversion
+; soundtouch license stuff
+Source: "..\packageTemplate\SoundTouch\*.*"; DestDir: "{app}\SoundTouch"; Flags: ignoreversion
+; keymaps
+Source: "..\packageTemplate\extraKeymaps\*.*"; DestDir: "{app}\extraKeymaps"; Flags: ignoreversion
+
+[Dirs]
+; option dirs for non-portable mode
+Name: "{userappdata}\OpenMPT"; Tasks: not portable
+Name: "{userappdata}\OpenMPT\tunings"; Tasks: not portable
+; dirst for portable mode
+Name: "{app}\tunings"; Tasks: portable
+
+[Icons]
+; start menu
+Name: "{group}\{cm:LaunchProgram,OpenMPT}"; Filename: "{app}\mptrack.exe"
+Name: "{group}\{cm:UninstallProgram,OpenMPT}"; Filename: "{uninstallexe}"
+Name: "{group}\ModPlug Central"; Filename: "{app}\ModPlug Central.url"
+Name: "{group}\Configuration files"; Filename: "{userappdata}\OpenMPT\"; Tasks: not portable
+
+; app's directory (for ease of use)
+Name: "{app}\Configuration files"; Filename: "{userappdata}\OpenMPT\"; Tasks: not portable
+
+; desktop, quick launch
+Name: "{userdesktop}\OpenMPT"; Filename: "{app}\mptrack.exe"; Tasks: desktopicon
+Name: "{userappdata}\Microsoft\Internet Explorer\Quick Launch\OpenMPT"; Filename: "{app}\mptrack.exe"; Tasks: quicklaunchicon
+
+[INI]
+; enable portable mode
+Filename: "{app}\mptrack.ini"; Section: "Paths"; Key: "UseAppDataDirectory"; String: "0"; Flags: uninsdeleteentry createkeyifdoesntexist; Tasks: portable
+; internet shortcut
+Filename: "{app}\ModPlug Central.url"; Section: "InternetShortcut"; Key: "URL"; String: "http://www.lpchip.com/modplug/"; Flags: createkeyifdoesntexist;
+
+[Run]
+; duh
+Filename: "{app}\mptrack.exe"; Description: "{cm:LaunchProgram,OpenMPT}"; Flags: nowait postinstall skipifsilent
+
+[UninstallDelete]
+; internet shortcut has to be deleted manually
+Type: files; Name: "{app}\ModPlug Central.url";
+; normal installation
+Type: files; Name: "{userappdata}\OpenMPT\mptrack.ini"; Tasks: not portable
+Type: files; Name: "{userappdata}\OpenMPT\plugin.cache"; Tasks: not portable
+Type: files; Name: "{userappdata}\OpenMPT\tunings\local_tunings.tc"; Tasks: not portable
+Type: dirifempty; Name: "{userappdata}\OpenMPT\tunings"; Tasks: not portable
+Type: dirifempty; Name: "{userappdata}\OpenMPT"; Tasks: not portable
+; portable installation
+Type: files; Name: "{app}\mptrack.ini"; Tasks: portable
+Type: files; Name: "{app}\plugin.cache"; Tasks: portable
+Type: files; Name: "{app}\tunings\local_tunings.tc"; Tasks: portable
+Type: dirifempty; Name: "{app}\tunings"; Tasks: portable
+
+
+
+
+
+
+
+
Added: trunk/OpenMPT/installer/mpt.ico
===================================================================
(Binary files differ)
Property changes on: trunk/OpenMPT/installer/mpt.ico
___________________________________________________________________
Added: svn:mime-type
+ application/octet-stream
Added: trunk/OpenMPT/installer/packageTemplate/readme.txt
===================================================================
--- trunk/OpenMPT/installer/packageTemplate/readme.txt (rev 0)
+++ trunk/OpenMPT/installer/packageTemplate/readme.txt 2010-01-16 19:48:28 UTC (rev 469)
@@ -0,0 +1,95 @@
+******************
+* OpenMPT 1.18 *
+******************
+
+
+Migrating from OpenMPT 1.17
+---------------------------
+
+-If you have an existing installation of OpenMPT 1.17 and wish to
+ re-use its settings, copy your mptrack.ini and plugin.cache
+ to the directory into which you installed OpenMPT.
+
+
+Uninstallation
+--------------
+
+-An uninstaller is provided. It will also uninstall custom settings and tunings, so if you want to keep those, back them up first. Use "open_settings_folder.bat" to find them.
+
+
+Making OpenMPT portable
+-----------------------
+
+By default, OpenMPT stores its settings in %appdata%\OpenMPT. To avoid this, create a file called "mptrack.ini" in the same directory as mptrack.exe (if it does not exist yet) and add the following lines to this file:
+[Paths]
+UseAppDataDirectory=0
+
+
+Changes
+-------
+
+See history.txt.
+
+
+Questions, comments, bug reports...
+-----------------------------------
+
+See forums at http://modplug.sourceforge.net/.
+
+
+Release package contents:
+-------------------------
+extraKeymaps(folder): Additional key bindings for the keyboard manager, available in several flavours (including MPT classic, FastTracker and Impulse Tracker) and country-specific layouts.
+soundtouch(folder): SoundTouch readme and copying.txt
+history.txt: Version history.
+mptrack.exe: Main executable.
+open_settings_folder.bat: Opens settings folder.
+OpenMPT_SoundTouch_i16.dll: Slightly customized SoundTouch library used in time stretching feature.
+readme.txt:
+unmo3.dll: Used in MO3-file import.
+
+Misc:
+-----
+
+OpenMPT is partially under the following license:
+
+> Copyright (c) 2004-2010, OpenMPT contributors
+> Copyright (c) 1997-2003, Olivier Lapicque
+> All rights reserved.
+>
+> Redistribution and use in source and binary forms, with or without
+> modification, are permitted provided that the following conditions are met:
+> * Redistributions of source code must retain the above copyright
+> notice, this list of conditions and the following disclaimer.
+> * Redistributions in binary form must reproduce the above copyright
+> notice, this list of conditions and the following disclaimer in the
+> documentation and/or other materials provided with the distribution.
+> * Neither the name of the OpenMPT project nor the
+> names of its contributors may be used to endorse or promote products
+> derived from this software without specific prior written permission.
+>
+> THIS SOFTWARE IS PROVIDED BY THE CONTRIBUTORS ``AS IS'' AND ANY
+> EXPRESS OR IMPLIED WARRANTIES, INCLUDING, BUT NOT LIMITED TO, THE IMPLIED
+> WARRANTIES OF MERCHANTABILITY AND FITNESS FOR A PARTICULAR PURPOSE ARE
+> DISCLAIMED. IN NO EVENT SHALL THE CONTRIBUTORS BE LIABLE FOR ANY
+> DIRECT, INDIRECT, INCIDENTAL, SPECIAL, EXEMPLARY, OR CONSEQUENTIAL DAMAGES
+> (INCLUDING, BUT NOT LIMITED TO, PROCUREMENT OF SUBSTITUTE GOODS OR SERVICES;
+> LOSS OF USE, DATA, OR PROFITS; OR BUSINESS INTERRUPTION) HOWEVER CAUSED AND
+> ON ANY THEORY OF LIABILITY, WHETHER IN CONTRACT, STRICT LIABILITY, OR TORT
+> (INCLUDING NEGLIGENCE OR OTHERWISE) ARISING IN ANY WAY OUT OF THE USE OF THIS
+> SOFTWARE, EVEN IF ADVISED OF THE POSSIBILITY OF SUCH DAMAGE.
+
+
+ASIO is a trademark and software of Steinberg Media Technologies GmbH
+VST is a trademark of Steinberg Media Technologies GmbH
+
+For more information about SoundTouch, see folder SoundTouch.
+
+unmo3.dll
+---------
+Copyright (c) 2001-2009 Ian Luck. All rights reserved
+
+The MO3 software is free for non-commercial use; if anyone tries to
+charge you for it, kick 'em where it hurts!
+
+TO THE MAXIMUM EXTENT PERMITTED BY APPLICABLE LAW, THIS SOFTWARE IS PROVIDED "AS IS", WITHOUT WARRANTY OF ANY KIND, EITHER EXPRESSED OR IMPLIED, INCLUDING BUT NOT LIMITED TO THE IMPLIED WARRANTIES OF MERCHANTABILITY AND/OR FITNESS FOR A PARTICULAR PURPOSE. THE AUTHORS SHALL NOT BE HELD LIABLE FOR ANY DAMAGE THAT MAY RESULT FROM THE USE OF THIS SOFTWARE. YOU USE THIS SOFTWARE ENTIRELY AT YOUR OWN RISK.
This was sent by the SourceForge.net collaborative development platform, the world's largest Open Source development site.
|
