[Meta-diff-devel] InstallerScripts metadiff.iss,NONE,1.1

[Sebastian S. <ey...@us...>]

Update of /cvsroot/meta-diff/InstallerScripts
In directory sc8-pr-cvs1.sourceforge.net:/tmp/cvs-serv30951/InstallerScripts

Added Files:
	metadiff.iss 
Log Message:
Added an Inno Setup script to install meta-diff, LVDiff and CompareShellEx (incl. sources).

--- NEW FILE: metadiff.iss ---
[Code]
var
    ProgramPage:TInputFileWizardPage;

procedure InitializeWizard;
begin
    // Use a monospaced font in the license dialog.
    //WizardForm.LicenseMemo.Font.Name:='Courier New';
    //WizardForm.LicenseMemo.Font.Size:=8;

    // Create a custom page to specify comparison programs.
    ProgramPage:=CreateInputFilePage(
        wpInstalling,
        'Specify comparison programs',
        'One this page you can browse for comparison programs you want meta-diff to launch.',
        'You can skip this step by leaving the boxes blank and editing the ".metadiff" configuration file manually afterwards, which gives you access to more options and examples.'
    );

    ProgramPage.Add(
        'Program to use for directory comparisions:',
        'Executable files (*.exe)|*.exe|All files (*.*)|*.*',
        '*.exe'
    );

    ProgramPage.Add(
        'Program to use for file comparisions:',
        'Executable files (*.exe)|*.exe|All files (*.*)|*.*',
        '*.exe'
    );
end;

procedure CurStepChanged(CurStep:TSetupStep);
var
    ConfigFile,DirProgram,FileProgram,lvdiff:string;
begin
    if CurStep<>ssDone then Exit;

    ConfigFile:=ExpandConstant('{app}\.metadiff');

    // Add the programs to the config file.
    DirProgram:=RemoveQuotes(Trim(ProgramPage.Values[0]));
    if Length(DirProgram)>0 then begin
        SaveStringToFile(ConfigFile,#13#10+'/ '+DirProgram+#13#10,True);
    end;

    lvdiff:=ExpandConstant('{app}\lvdiff.exe');
    if FileExists(lvdiff) then begin
        SaveStringToFile(ConfigFile,#13#10+'*.vi '+lvdiff+#13#10,True);
    end;

    FileProgram:=RemoveQuotes(Trim(ProgramPage.Values[1]));
    if Length(FileProgram)>0 then begin
        SaveStringToFile(ConfigFile,#13#10+'*.* '+FileProgram+#13#10,True);
    end;
end;

[Setup]
; Compiler-related
InternalCompressLevel=max
OutputBaseFilename=meta-diff-suite-v2.1
SolidCompression=yes

; Installer-related
AllowNoIcons=yes
AppName=meta-diff suite
AppVerName=meta-diff suite 2.1
DefaultDirName={pf}\meta-diff
DefaultGroupName=meta-diff suite
DisableStartupPrompt=yes
LicenseFile=..\CompareShellEx\CSE-License.txt

[Types]
Name: full; Description: Full installation
Name: min; Description: Minimal installation
Name: custom; Description: Custom installation; Flags: iscustom

[Components]
Name: main; Description: meta-diff (main application); Types: full min custom; Flags: fixed
Name: lvdiff; Description: LVDiff (LabVIEW virtual instrument comparison); Types: full custom
Name: cse; Description: CompareShellEx (Windows Explorer shell extension); Types: full custom
Name: src; Description: Full C++ / Delphi source code; Types: full

[Files]
; meta-diff
Source: ..\meta-diff\.metadiff; DestDir: {app}; Components: main
Source: ..\meta-diff\license.txt; DestDir: {app}; DestName: metadiff-license.txt; Components: main
Source: ..\meta-diff\metadiff.exe; DestDir: {app}; Components: main
Source: ..\meta-diff\readme.txt; DestDir: {app}; DestName: metadiff-readme.txt; Components: main; Flags: isreadme

Source: ..\meta-diff\GNUmakefile; DestDir: {app}\source\meta-diff; Components: src
Source: ..\meta-diff\metadiff.bpr; DestDir: {app}\source\meta-diff; Components: src
Source: ..\meta-diff\metadiff.cpp; DestDir: {app}\source\meta-diff; Components: src
Source: ..\meta-diff\metadiff.sln; DestDir: {app}\source\meta-diff; Components: src
Source: ..\meta-diff\metadiff.vcproj; DestDir: {app}\source\meta-diff; Components: src

; LVDiff
Source: ..\lv-diff\.lvdiff; DestDir: {app}; Components: lvdiff
Source: ..\lv-diff\license.txt; DestDir: {app}; DestName: lvdiff-license.txt; Components: lvdiff
Source: ..\lv-diff\lvdiff.exe; DestDir: {app}; Components: lvdiff
Source: ..\lv-diff\lvdiff.vi; DestDir: {app}; Components: lvdiff
Source: ..\lv-diff\readme.txt; DestDir: {app}; DestName: lvdiff-readme.txt; Components: lvdiff

Source: ..\lv-diff\GNUmakefile; DestDir: {app}\source\lv-diff; Components: src
Source: ..\lv-diff\lvdiff.bpr; DestDir: {app}\source\lv-diff; Components: src
Source: ..\lv-diff\lvdiff.cpp; DestDir: {app}\source\lv-diff; Components: src
Source: ..\lv-diff\lvdiff.sln; DestDir: {app}\source\lv-diff; Components: src
Source: ..\lv-diff\lvdiff.vcproj; DestDir: {app}\source\lv-diff; Components: src

; CompareShellEx
Source: ..\CompareShellEx\CompareShellEx.dll; DestDir: {app}; Components: cse; Flags: uninsrestartdelete
Source: ..\CompareShellEx\CSE-License.txt; DestDir: {app}; DestName: CompareShellEx-License.txt; Components: cse
Source: ..\CompareShellEx\CSE-ReadMe.txt; DestDir: {app}; DestName: CompareShellEx-ReadMe.txt; Components: cse

Source: ..\CompareShellEx\CompareShellEx.dpr; DestDir: {app}\source\CompareShellEx; Components: src
Source: ..\CompareShellEx\CompareShellEx.lc; DestDir: {app}\source\CompareShellEx; Components: src
Source: ..\CompareShellEx\CompareShellEx.res; DestDir: {app}\source\CompareShellEx; Components: src

[Icons]
Name: {group}\Uninstall meta-diff; Filename: {uninstallexe}

[Run]
Filename: {sys}\RunDLL32.exe; Parameters: {app}\CompareShellEx.dll,Install; Components: cse; Flags: runhidden

[UninstallRun]
Filename: {sys}\RunDLL32.exe; Parameters: {app}\CompareShellEx.dll,Uninstall; Components: cse;  Flags: runhidden

[Messages]
BeveledLabel=http://meta-diff.sourceforge.net/