[Meshdb-cvs] src/cf gd.m4,NONE,1.1.2.1 libpng.m4,NONE,1.1.2.1

[<le...@pr...>]

Update of /cvsroot/meshdb/src/cf
In directory sc8-pr-cvs1.sourceforge.net:/tmp/cvs-serv1924/cf

Added Files:
      Tag: leonard-dev
	gd.m4 libpng.m4 
Log Message:
more autoconf

--- NEW FILE: gd.m4 ---
dnl $Id: gd.m4,v 1.1.2.1 2004/11/07 12:16:31 leonard Exp $
dnl David Leonard, 2004. Public domain.

dnl
dnl Check for the GD library (http://www.boutell.com/gd/)
dnl
AC_DEFUN([CHECK_GDLIB],
[AC_ARG_WITH(gdlib,
	    AC_HELP_STRING([--with-gdlib=PREFIX],
			   [specify GD installation (default auto)]),
	    ac_cv_use_gdlib=$withval,
	    ac_cv_use_gdlib=auto)
AC_CACHE_CHECK([gdlib-config],
	       [ac_cv_gdlib_config],
	       [if test "auto" = "$ac_cv_use_gdlib"; then
		    prog=gdlib-config
		else
		    prog="$ac_cv_use_gdlib/bin/gdlib-config"
		fi
		if $prog --version >/dev/null 2>/dev/null; then
		    ac_cv_gdlib_config=$prog
		else
		    ac_cv_gdlib_config=no
		fi])
if test "no" != "$ac_cv_gdlib_config"; then
     GD_CFLAGS="$CFLAGS `$ac_cv_gdlib_config --cflags`"
     GD_LDFLAGS="$LDFLAGS `$ac_cv_gdlib_config --ldflags`"
     GD_LIBS="$LIBS `$ac_cv_gdlib_config --libs`"
fi

CFLAGS="$CFLAGS $GD_CFLAGS"
LDFLAGS="$LDFLAGS $GD_LDFLAGS"
LIBS="$LIBS $GD_LIBS"

AC_CHECK_HEADER(gd.h,,
	[AC_MSG_ERROR([unable to find or use required GD headers])])
AC_SEARCH_LIBS(gdImageCreate,gd,,
	[AC_MSG_ERROR([unable to find or use required GD library])])

])

--- NEW FILE: libpng.m4 ---
dnl $Id: libpng.m4,v 1.1.2.1 2004/11/07 12:16:31 leonard Exp $
dnl David Leonard, 2004. Public domain.
AC_DEFUN([CHECK_LIBPNG],
[AC_ARG_WITH(libpng,
	    AC_HELP_STRING([--with-libpng=PREFIX],
			   [specify libpng installation (default auto)]),
	    ac_cv_use_libpng=$withval,
	    ac_cv_use_libpng=auto)
AC_CACHE_CHECK([libpng-config],
	       [ac_cv_libpng_config],
	       [if test "auto" = "$ac_cv_use_libpng"; then
		    prog=libpng-config
		else
		    prog="$ac_cv_use_libpng/bin/libpng-config"
		fi
		if $prog --version >/dev/null 2>/dev/null; then
		    ac_cv_libpng_config=$prog
		else
		    ac_cv_libpng_config=no
		fi])

if test "no" != "$ac_cv_libpng_config"; then
     LIBPNG_CPPFLAGS="`$ac_cv_libpng_config --cppflags`"
     LIBPNG_CFLAGS="`$ac_cv_libpng_config --cflags`"
     LIBPNG_LDFLAGS="`$ac_cv_libpng_config --L_opts`"
     LIBPNG_LDFLAGS="$LIBPNG_LDFLAGS `$ac_cv_libpng_config --R_opts`"
     LIBPNG_LIBS="`$ac_cv_libpng_config --libs`"
fi

CPPFLAGS="$CPPFLAGS $LIBPNG_CPPFLAGS"
CFLAGS="$CFLAGS $LIBPNG_CFLAGS"
LDFLAGS="$LDFLAGS $LIBPNG_LDFLAGS"
LIBS="$LIBS $LIBPNG_LIBS"

AC_CHECK_HEADER(png.h,,
	[AC_MSG_ERROR([unable to find required PNG headers])])
AC_SEARCH_LIBS(png_init_io,png,,
	[AC_MSG_ERROR([unable to find required PNG library])])

])