[LV-k25-commit] CVS: kernel-2.5/arch/vax vmlinux.lds.S,NONE,1.1 Makefile,1.14,1.15 vmlinux.lds,1.6,NONE

[Kenn H. <ke...@us...>]

Update of /cvsroot/linux-vax/kernel-2.5/arch/vax
In directory sc8-pr-cvs1:/tmp/cvs-serv10326

Modified Files:
	Makefile 
Added Files:
	vmlinux.lds.S 
Removed Files:
	vmlinux.lds 
Log Message:
2.5.36 introduces a standard rule for generating vmlinux.lds.s from 
vmlinux.lds.S and automatically includes this in the vmlinux link 
command


--- NEW FILE ---
/* ld script to make bootable VAX image
 * Written for i386 by Martin Mares <mj...@at...>
 * Modified by Kenn Humborg <ke...@li...>
 */

/* As of 2.5.16, the jiffy counter is 64-bit and is called jiffies_64.
   For backward-compatibility, a symbol 'jiffies' needs to be aliased
   to the least-significant 32-bits of jiffies_64 */

jiffies = jiffies_64;

SECTIONS
{

  /* kernel is based in S0 space at 0x80100000 */
  . = 0x80000000 + 0x100000;

  _text = .;			/* Text and read-only data */
  __kernel_start = .;
  .text : {
        /* boot code comes first.  The fact that it is linked
           at 0x80100000 doesn't matter because it's all 
           hand-crafted position-independent code */
        *(.vaxboot)
        *(.vaxbootlib)

        /* Kernel C code starts here */
	*(.text)
	*(.fixup)
	*(.gnu.warning)
	} = 0x9090
  .text.lock : { *(.text.lock) }	/* out-of-line lock text */

  _etext = .;			/* End of text section */

  .rodata : { *(.rodata) }
  .kstrtab : { *(.kstrtab) }

  . = ALIGN(16);		/* Exception table */
  __start___ex_table = .;
  __ex_table : { *(__ex_table) }
  __stop___ex_table = .;

  __start___ksymtab = .;	/* Kernel symbol table */
  __ksymtab : { *(__ksymtab) }
  __stop___ksymtab = .;

  .data : {			/* Data */
	*(.data)
	CONSTRUCTORS
	}

  _edata = .;			/* End of data section */

  . = ALIGN(8192);		/* init_task */
  .data.init_task : { *(.data.init_task) }

  . = ALIGN(4096);		/* Init code and data */
  __init_begin = .;
  .text.init : { *(.text.init) }
  .data.init : { *(.data.init) }
  . = ALIGN(16);
  __setup_start = .;
  .setup.init : { *(.setup.init) }
  __setup_end = .;
  __initcall_start = .;
  .initcall.init : {
	*(.initcall1.init)
	*(.initcall2.init)
	*(.initcall3.init)
	*(.initcall4.init)
	*(.initcall5.init)
	*(.initcall6.init)
	*(.initcall7.init)
  }
  __initcall_end = .;
  . = ALIGN(4096);
  __init_end = .;


  . = ALIGN(4096);
  __init_end = .;               /* This is end of loadable image */

  __bss_start = .;		/* BSS */
  .bss : {
	*(.bss)
	}
  _end = .;  /* Boot code uses this to determine how much
                code and data to relocate */

  /* Sections to be discarded */
  /DISCARD/ : {
        *(.text.exit)
        *(.data.exit)
        *(.exitcall.exit)
        }

  /* Stabs debugging sections.  */
  .stab 0 : { *(.stab) }
  .stabstr 0 : { *(.stabstr) }
  .stab.excl 0 : { *(.stab.excl) }
  .stab.exclstr 0 : { *(.stab.exclstr) }
  .stab.index 0 : { *(.stab.index) }
  .stab.indexstr 0 : { *(.stab.indexstr) }
  .comment 0 : { *(.comment) }
}

Index: Makefile
===================================================================
RCS file: /cvsroot/linux-vax/kernel-2.5/arch/vax/Makefile,v
retrieving revision 1.14
retrieving revision 1.15
diff -u -r1.14 -r1.15
--- Makefile	9 Feb 2003 01:30:34 -0000	1.14
+++ Makefile	16 Feb 2003 23:49:08 -0000	1.15
@@ -24,8 +24,7 @@
 		
 # These flags are used by the top-level makefile when linking
 # the kernel
-LDFLAGS_vmlinux=-T arch/vax/vmlinux.lds \
-          -N -nostartfiles -nostdlib \
+LDFLAGS_vmlinux=-N -nostartfiles -nostdlib \
           -noinhibit-exec -warn-once \
           -Map vmlinux.map -cref
 

--- vmlinux.lds DELETED ---