[Javaprofiler-commits] CVS: test/snapshot DebugFmt.sed,NONE,1.1

[Lukas P. <pe...@us...>]

Update of /cvsroot/javaprofiler/test/snapshot
In directory usw-pr-cvs1:/tmp/cvs-serv2928

Added Files:
	DebugFmt.sed 
Log Message:
is helper for DebugOutput.java


--- NEW FILE: DebugFmt.sed ---
#!/bin/sed -f

# Purpose of this script is machine comparison of output from
# DebugOutput.print() and output from profiler library.
#
# usage: sed -f DebugFmt.sed FILE
#
# Output should be then sorted with Unix sort command.

#specialni osetreni prvni radky
s/.*/\
&/
s/
//

:b
#pripoj radku
/\n/!N
#uprav \r\n
s/
$//

#konec pri instancich, arenach a GC
/\nINSTANCE:/q
/\nARENA =/q
/\nGC:$/q

#nova hlavicka
/\nGROUP = /{
#kompaktnejsi hlavicku
s/GROUP = /GROUP=/
s/.*\n//p
bb
}
/\nIS_ARRAY = /{
#dokonci OBJECT_TYPE zaznam
s/\nIS_ARRAY =//p
d
}
/^OBJECT_TYPE:/{
#pokracuj OBJECT_TYPE zaznam
s/\nCLASS = //
bb
}
/\nOBJECT TYPE:/{
#zacni OBJECT_TYPE zaznam
#smaz zacatek
s/.*\n//
#kompaktnejsi hlavicku
s/OBJECT TYPE:/OBJECT_TYPE:/
bb
}
/\nCLASS = /{
#kompaktnejsi hlavicku
s/CLASS = /CLASS=/
s/.*\n//p
bb
}

#odstranit \n, pokud neni zbytek prazdny, tak vytisknout
s/\n\(.\)/ \1/p
s/\n/ /
#ponechat jen hlavicku
s/\([^ ]*\).*/\1/
#skok na zacatek
bb