[Gtkada-wrapper-devel] SF.net SVN: gtkada-wrapper: [2] trunk

[<bec...@us...>]

Revision: 2
          http://svn.sourceforge.net/gtkada-wrapper/?rev=2&view=rev
Author:   bechir_zalila
Date:     2006-11-24 14:53:48 -0800 (Fri, 24 Nov 2006)

Log Message:
-----------
	* Directory hierarchy an build mechanism

Added Paths:
-----------
    trunk/AUTHORS
    trunk/COPYING
    trunk/ChangeLog
    trunk/INSTALL
    trunk/Makefile.am
    trunk/NEWS
    trunk/README
    trunk/TODO
    trunk/configure.ac
    trunk/doc/
    trunk/doc/Makefile.am
    trunk/src/
    trunk/src/Makefile.am
    trunk/support/
    trunk/support/ada.m4
    trunk/support/reconfig

Added: trunk/AUTHORS
===================================================================

Added: trunk/COPYING
===================================================================

Added: trunk/ChangeLog
===================================================================

Added: trunk/INSTALL
===================================================================

Added: trunk/Makefile.am
===================================================================
--- trunk/Makefile.am	                        (rev 0)
+++ trunk/Makefile.am	2006-11-24 22:53:48 UTC (rev 2)
@@ -0,0 +1 @@
+SUBDIRS=doc src

Added: trunk/NEWS
===================================================================

Added: trunk/README
===================================================================

Added: trunk/TODO
===================================================================

Added: trunk/configure.ac
===================================================================
--- trunk/configure.ac	                        (rev 0)
+++ trunk/configure.ac	2006-11-24 22:53:48 UTC (rev 2)
@@ -0,0 +1,91 @@
+AC_PREREQ(2.57)
+AC_INIT(GTKAda-Wrapper, 0.1, gtk...@li...)
+AC_CONFIG_SRCDIR(src)
+AC_CONFIG_AUX_DIR(support)
+
+##########################################
+# Initialization.
+##########################################
+
+AC_CANONICAL_SYSTEM
+AM_INIT_AUTOMAKE
+LIBVERSIONINFO=0:1:0
+AC_SUBST(LIBVERSIONINFO)
+
+##########################################
+# Check fo various programs.
+##########################################
+
+AC_CHECK_PROG(MV, mv, mv)
+AC_CHECK_PROG(RM, rm, rm)
+AC_CHECK_PROG(CP, cp, cp)
+AC_CHECK_PROG(GREP, grep, grep)
+AC_PROG_RANLIB
+AM_PROG_WORKING_ADA
+AC_CHECK_PROG(GNATCLEAN, gnatclean, gnatclean)
+AC_EXEEXT
+
+##########################################
+# GTKAda
+##########################################
+
+GTKADA_INCS=""
+GTKADA_LIBS=""
+GTKADA_FLAGS=""
+has_gtkada=no
+
+AC_MSG_CHECKING([GTKAda])
+if gtkada-config --help 2>&1 | ${GREP} '^Usage.*gtkada-config' > /dev/null 2>&1; then
+   GTKADA_INCS="`gtkada-config --cflags`"
+   GTKADA_LIBS="`gtkada-config --libs`"
+   GTKADA_FLAGS=`gtkada-config`
+   has_gtkada=yes
+else
+   has_gtkada=no
+fi
+AC_MSG_RESULT($has_gtkada)
+AM_CONDITIONAL(HAS_GTKADA, test x"$has_gtkada" = xyes)
+
+AC_SUBST(GTKADA_INCS)
+AC_SUBST(GTKADA_LIBS)
+AC_SUBST(GTKADA_FLAGS)
+
+##########################################
+# Check for maintainer (debug) mode.
+##########################################
+
+GNATFLAGS=""
+
+define(DEBUG_OPTIONS, [dnl
+  GNATFLAGS="-XBUILD=debug"
+  debug=true])
+define(NODEBUG_OPTIONS, [dnl
+  GNATFLAGS="-XBUILD=release"
+  debug=false])
+
+AC_ARG_ENABLE(debug,
+[  --enable-debug          Turn on debugging options],
+[if [[ "$enableval" = "yes" ]]; then
+  DEBUG_OPTIONS
+else
+  NODEBUG_OPTIONS
+fi],
+[NODEBUG_OPTIONS])
+
+AC_SUBST(GNATFLAGS)
+AM_CONDITIONAL(DEBUG, test x$debug = xtrue)
+
+##########################################
+# Output generated files
+##########################################
+
+dnl Important! One file per line, nothing before
+dnl or after except whitespace! This section
+dnl is edited automatically by make_distrib.
+
+AC_OUTPUT([
+	Makefile
+	doc/Makefile
+	src/Makefile
+])
+

Added: trunk/doc/Makefile.am
===================================================================

Added: trunk/src/Makefile.am
===================================================================

Added: trunk/support/ada.m4
===================================================================
--- trunk/support/ada.m4	                        (rev 0)
+++ trunk/support/ada.m4	2006-11-24 22:53:48 UTC (rev 2)
@@ -0,0 +1,64 @@
+dnl Ada compiler handling
+dnl Adapted from a similar file creted by Samuel Tardieu
+
+dnl Usage: AM_TRY_ADA(gnatmake, filename, content, pragmas, success, failure)
+dnl Compile, bind and link an Ada program and report its success or failure
+
+AC_DEFUN([AM_TRY_ADA],
+[mkdir conftest
+cat > conftest/src.ada <<EOF
+[$3]
+EOF
+cat > conftest/gnat.adc <<EOF
+[$4]
+EOF
+ac_try="cd conftest && $GNATCHOP -q src.ada && $1 $2 > /dev/null 2>../conftest.out"
+if AC_TRY_EVAL(ac_try); then
+  ifelse([$5], , :, [rm -rf conftest*
+  $5])
+else
+  ifelse([$6], , :, [ rm -rf conftest*
+  $6])
+fi
+rm -f conftest*])
+
+dnl Usage: AM_PROG_GNATMAKE
+dnl Look for an Ada make
+
+AC_DEFUN([AM_PROG_GNATMAKE],
+[AC_CHECK_PROGS(GNATMAKE, gnatmake gnatgcc adagcc gcc)])
+
+dnl Usage: AM_PROG_GNATCHOP
+dnl Look for GNATCHOP program
+
+AC_DEFUN([AM_PROG_GNATCHOP],
+[AC_CHECK_PROG(GNATCHOP, gnatchop, gnatchop)])
+
+dnl Usage: AM_PROG_GNATCHOP
+dnl Look for GNATCHOP program
+
+AC_DEFUN([AM_PROG_GNATCLEAN],
+[AC_CHECK_PROG(GNATCLEAN, gnatclean, gnatclean)])
+
+dnl Usage: AM_TRY_ADA(gnatmake, filename, content, pragmas, success, failure)
+dnl Compile, bind and link an Ada program and report its success or failure
+
+dnl Usage: AM_PROG_WORKING_ADA
+dnl Try to compile a simple Ada program to test the compiler installation
+dnl (especially the standard libraries such as Ada.Text_IO)
+
+AC_DEFUN([AM_PROG_WORKING_ADA],
+[AC_REQUIRE([AM_PROG_GNATMAKE])
+AC_REQUIRE([AM_PROG_GNATCHOP])
+AC_REQUIRE([AM_PROG_GNATCLEAN])
+AC_MSG_CHECKING([if the Ada compiler works])
+AM_TRY_ADA([$GNATMAKE -c],[check.adb],
+[with Ada.Text_IO;
+procedure Check is
+begin
+   null;
+end Check;
+], [], [AC_MSG_RESULT(yes)],
+[AC_MSG_RESULT(no)
+AC_MSG_ERROR([Ada compiler is not working])])])
+

Added: trunk/support/reconfig
===================================================================
--- trunk/support/reconfig	                        (rev 0)
+++ trunk/support/reconfig	2006-11-24 22:53:48 UTC (rev 2)
@@ -0,0 +1,12 @@
+#! /bin/sh
+
+rm -f aclocal.m4 support/libtool.m4 configure
+
+echo "Running aclocal"
+aclocal -I support
+
+echo "Running autoconf"
+autoconf
+
+echo "Running automake"
+automake --add-missing --copy


Property changes on: trunk/support/reconfig
___________________________________________________________________
Name: svn:executable
   + *


This was sent by the SourceForge.net collaborative development platform, the world's largest Open Source development site.