genex-cvs-commit Mailing List for GeneX Gene Expression Database (Page 46)

SourceForge Headquarters 1320 Columbia Street Suite 310 San Diego, CA 92101 +1 (858) 422-6466

Update of /cvsroot/genex/genex-server/DB/scripts
In directory usw-pr-cvs1:/tmp/cvs-serv23975/DB/scripts

Added Files:
	fix-array.pl tab2AD.pl 
Log Message:
new


--- NEW FILE: fix-array.pl ---
#!/usr/bin/perl
use warnings;
use strict;
use Getopt::Long;

my %OPTIONS;
my $rc = GetOptions(\%OPTIONS,
		    'mangle',
		    'infile=s',
		    'outfile=s',
		    'design=s',
		    'help',
		   );

my $USAGE = <<"EOU";
usage: $0 [required flags] file1 ...
  required flags:
    --infile=file     : the file to read

  optional flags:
    --outfile=file    : the (adjusted) file to write
    --design=file     : the array design file to create
    --help            : print this message
EOU

die "Bad option\n$USAGE" unless $rc;

die $USAGE if exists $OPTIONS{help};

die "Must specify --infile\n$USAGE"
  unless exists $OPTIONS{infile};

open(IN,"$OPTIONS{infile}")
  or die "Couldn't open $OPTIONS{infile} for reading";

if (exists $OPTIONS{design}) {
  open(DESIGN,">$OPTIONS{design}")
    or die "Couldn't open $OPTIONS{design} for writing";
  print DESIGN "# id\ta_row\ta_col\trow\tcol\tname\n";
}

if (exists $OPTIONS{outfile}) {
  open(OUT,">$OPTIONS{outfile}")
    or die "Couldn't open $OPTIONS{outfile} for writing";
  print OUT "# id\ta_row\ta_col\trow\tcol\tname\n";
}


  # 0) Number
  # 1) Array Row
  # 2) Array Column
  # 3) Row
  # 4) Column
  # 5) Name
  # 6) X Location
  # 7) Y Location
  # 8) ch1 Intensity
  # 9) ch1 Background
  # 10) ch1 Intensity Std Dev
  # 11) ch1 Background Std Dev
  # 12) ch1 Diameter
  # 13) ch1 Area
  # 14) ch1 Footprint
  # 15) ch1 Circularity
  # 16) ch1 Spot Uniformity
  # 17) ch1 Bkg. Uniformity
  # 18) ch1 Signal Noise Ratio
  # 19) ch1 Confidence
  # 20) ch2 Intensity
  # 21) ch2 Background
  # 22) ch2 Intensity Std Dev
  # 23) ch2 Background Std Dev
  # 24) ch2 Diameter
  # 25) ch2 Area
  # 26) ch2 Footprint
  # 27) ch2 Circularity
  # 28) ch2 Spot Uniformity
  # 29) ch2 Bkg. Uniformity
  # 30) ch2 Signal Noise Ratio
  # 31) ch2 Confidence
  # 32) Ignore Filter

# all we need are:

  # 0) Number
  # 1) Array Row
  # 2) Array Column
  # 3) Row
  # 4) Column
  # 5) Name
  # 8) ch1 Intensity
  # 9) ch1 Background
  # 10) ch1 Intensity Std Dev
  # 11) ch1 Background Std Dev
  # 18) ch1 Signal Noise Ratio
  # 20) ch2 Intensity
  # 21) ch2 Background
  # 22) ch2 Intensity Std Dev
  # 23) ch2 Background Std Dev
  # 30) ch2 Signal Noise Ratio

my @INDICES = qw(0 1 2 3 4 5 8 9 10 11 18 20 21 22 23 30);

my ($ARRAY_ROWS,$ARRAY_COLS,$ROWS,$COLS,$TOTAL_SPOTS);
my $in_data;
my $data_start_regexp = qr/^Begin\s+Data/o;
my $reading_data;
my $reading_data_regexp = qr/^Number/;
my @spots;
my $count = 0;
while (<IN>) {
  # see if we've found the Data section already
  unless ($in_data or /$data_start_regexp/) {
    # if not grab the info from the header
    # Look for the following:
    #    Array Rows	12
    #    Array Columns	4
    #    Rows	10
    #    Columns	12
    #    Total Spots	5760		
    if (/^Array\s+Rows\s+(\d+)/) {
      $ARRAY_ROWS = $1;
    } elsif (/^Array\s+Columns\s+(\d+)/) {
      $ARRAY_COLS = $1;
    } elsif (/^Rows\s+(\d+)/) {
      $ROWS = $1;
    } elsif (/^Columns\s+(\d+)/) {
      $COLS = $1;
    } elsif (/^Total\s+Spots\s+(\d+)/) {
      $TOTAL_SPOTS = $1;
    }
    next;
  }

  # check if this is the beginning of the Data section
  if (/$data_start_regexp/) {
    $in_data = 1;
    die "Didn't find Array Rows\n"
      unless defined $ARRAY_ROWS;
    die "Didn't find Array Columns\n"
      unless defined $ARRAY_COLS;
    die "Didn't find Rows\n"
      unless defined $ROWS;
    die "Didn't find Columns\n"
      unless defined $COLS;
    die "Didn't find Total Spots\n"
      unless defined $TOTAL_SPOTS;
    next;
  }

  # don't proceed unless we've past the Data section header line
  next unless $reading_data or /$reading_data_regexp/;

  # check if this is the header line of the Data section
  if (/$reading_data_regexp/) {
    $reading_data = 1;
    next;
  }

  # when we reach the end of the Data section, we're done
  last if /^End/;

  # 0) Number
  # 1) Array Row
  # 2) Array Column
  # 3) Row
  # 4) Column
  # 5) Name
  # 8) ch1 Intensity
  # 9) ch1 Background
  # 10) ch1 Intensity Std Dev
  # 11) ch1 Background Std Dev
  # 18) ch1 Signal Noise Ratio
  # 20) ch2 Intensity
  # 21) ch2 Background
  # 22) ch2 Intensity Std Dev
  # 23) ch2 Background Std Dev
  # 30) ch2 Signal Noise Ratio

  my @data = split /\t/;
  my ($num,$a_row,$a_col,$row,$col,$name,
      $ch1_int, $ch1_bkg, $ch1_int_std, $ch1_bkg_std, $ch1_snr,
      $ch2_int, $ch2_bkg, $ch2_int_std, $ch2_bkg_std, $ch2_snr,
     ) = @data[@INDICES];

  # commence error checking
  die "Found strange array row: $a_row, for line: $num"
    unless defined $a_row and $a_row > 0 and $a_row <= $ARRAY_ROWS;
  die "Found strange array col: $a_col, for line: $num"
    unless defined $a_col and $a_col > 0 and $a_col <= $ARRAY_COLS;
  die "Found strange row: $row, for line: $num"
    unless defined $row and $row > 0 and $row <= $ROWS;
  die "Found strange col: $col, for line: $num"
    unless defined $col and $col > 0 and $col <= $COLS;

  push(@spots, [$num,$a_row,$a_col,$row,$col,$name,
      $ch1_int, $ch1_bkg, $ch1_int_std, $ch1_bkg_std, $ch1_snr,
      $ch2_int, $ch2_bkg, $ch2_int_std, $ch2_bkg_std, $ch2_snr,]
     );

  if ($OPTIONS{mangle}) {
    unless (lc($name) eq 'blank'
	    or lc($name) =~ /^negative/
	    or lc($name) =~ /^lambda/
	   ) {
      # fix the name
      $name = sprintf('reporter%05d', $count++);
    }
  } else {
    # only use the first name in a group (R78541 | R78475)
    $name =~ s/\s*|.*//;
  }

  if (exists $OPTIONS{design}) {
    my $id = "$a_row.$a_col.$row.$col";
    print DESIGN "$id\t$a_row\t$a_col\t$row\t$col\t$name\n";
  }
  if (exists $OPTIONS{outfile}) {
    $_ = join("\t",
	      $num,$a_row,$a_col,$row,$col,$name,
	      $ch1_int, $ch1_bkg, $ch1_int_std, $ch1_bkg_std, $ch1_snr,
	      $ch2_int, $ch2_bkg, $ch2_int_std, $ch2_bkg_std, $ch2_snr
	     );
  }
} continue {
  if (exists $OPTIONS{outfile}) {
    print OUT;
  }
}
die "Found strange number of spots: ",
  scalar @spots, " expected: $TOTAL_SPOTS\n"
  unless scalar @spots == $TOTAL_SPOTS;

print STDERR "Finished\n";

--- NEW FILE: tab2AD.pl ---
#!/usr/bin/perl
use warnings;
use strict;
use Getopt::Long;
use Bio::MAGE qw(:ALL);
use Bio::MAGE::XMLUtils;
use Benchmark;

my %OPTIONS;
my $rc = GetOptions(\%OPTIONS,
		    'infile=s',
		    'outfile=s',
		    'ad_identifier=s',
		    'fg_identifier=s',
		    'rg_identifier=s',
		    'help',
		   );

my $USAGE = <<"EOU";
usage: $0 [required flags] file1 ...
  required flags:
    --infile=file       : the tab-delimited file to read
    --outfile=file      : the array design XML file to create
    --ad_identifier=id  : the identifier to use for the ArrayDesign

  optional flags:
    --fg_identifier=id  : the identifier to use for the FeatureGroup
    --rg_identifier=id  : the identifier to use for the ReporterGroup
    --help              : print this message
EOU

die "Bad option\n$USAGE" unless $rc;

die $USAGE if exists $OPTIONS{help};

die "Must specify --infile\n$USAGE"
  unless exists $OPTIONS{infile};

die "Must specify --outfile\n$USAGE"
  unless exists $OPTIONS{outfile};

die "Must specify --identifier\n$USAGE"
  unless exists $OPTIONS{ad_identifier};

unless (exists $OPTIONS{fg_identifier}) {
  $OPTIONS{fg_identifier} =  $OPTIONS{ad_identifier};
  $OPTIONS{fg_identifier} =~ s/ArrayDesign/FeatureGroup/;
}

unless (exists $OPTIONS{rg_identifier}) {
  $OPTIONS{rg_identifier} =  $OPTIONS{ad_identifier};
  $OPTIONS{rg_identifier} =~ s/ArrayDesign/ReporterGroup/;
}

open(IN,"$OPTIONS{infile}")
  or die "Couldn't open $OPTIONS{infile} for reading";

open(OUT,">$OPTIONS{outfile}")
  or die "Couldn't open $OPTIONS{outfile} for writing";

my %zones;
my %reporters;
my $num_features;
my $cur_row = 0;
my $cur_col = 0;

my $start = new Benchmark;

my $zg = Bio::MAGE::ArrayDesign::ZoneGroup->new();
my $fg = Bio::MAGE::ArrayDesign::FeatureGroup->new(identifier=>"$OPTIONS{fg_identifier}",
							 );
my $rg = Bio::MAGE::ArrayDesign::ReporterGroup->new(identifier=>"$OPTIONS{rg_identifier}",
							 );

my $zone;
while (<IN>) {
  next if /^\#/;		# skip comment lines

  my ($id, $a_row, $a_col, $row, $col, $name) = split /\t/;
  my $zname = "$a_row.$a_col";

  # check that the zone exists
  my $zone = $zones{$zname};
  unless (defined $zone) {
    $zone = Bio::MAGE::ArrayDesign::Zone->new(identifier=>"Zone:$zname",
					      row=>$a_row,
					      column=>$a_col,
					     );
    $zones{$zname} = $zone;
    $zg->addZoneLocations($zone);
  }

  # create the Feature
  my $f_loc = Bio::MAGE::DesignElement::FeatureLocation->new(row=>$row,
							     column=>$col,
							    );
  my $feature = Bio::MAGE::DesignElement::Feature->new(identifier=>"$a_row.$a_col.$row.$col",
						       zone=>$zones{$zname},
						       featureLocation=>$f_loc,
						       );
  $fg->addFeatures($feature);

  # create a Reporter if necessary
  my $reporter = $reporters{$name};
  unless (defined $reporter) {
    $reporter = Bio::MAGE::DesignElement::Reporter->new(identifier=>"Reporter:$name",
							name=>$name,
						       );
    $rg->addReporters($reporter);
    $reporters{$name} = $reporter;
  }

  # create a FeatureReporterMap if necessary
  unless (defined $reporter->getFeatureReporterMaps()) {
    my $map = Bio::MAGE::DesignElement::FeatureReporterMap->new(identifier=>"FeatureReporterMap:$name");
    $map->setReporter($reporter);
    $reporter->addFeatureReporterMaps($map);
  }

  # map the Feature to the Reporter
  my $map_ref = $reporter->getFeatureReporterMaps();
  my $info = Bio::MAGE::DesignElement::FeatureInformation->new(feature=>$feature,
						       );
  $map_ref->[0]->addFeatureInformationSources($info);

  $num_features++;
  print "Completed $num_features\n" if $num_features % 1000 == 0;
}
print STDERR "Found $num_features features\n";
my $stop = new Benchmark;
my $diff = timediff($stop,$start);
print STDERR "Parsing took:", timestr($diff),"\n";
print STDERR "Found $num_features features\n";

my $ad = Bio::MAGE::ArrayDesign::PhysicalArrayDesign->new(identifier=>$OPTIONS{ad_identifier},
							  numberOfFeatures=>$num_features,
							  featureGroups=>[$fg],
							  reporterGroups=>[$rg],
							  zoneGroups=>[$zg],
							 );
print STDERR "Creating the MAGE object\n";
$start = new Benchmark;
my $mage = Bio::MAGE->new(identifier=>"MAGE-$OPTIONS{ad_identifier}",
			  objects=>[$ad]
			 );

$stop = new Benchmark;
$diff = timediff($stop,$start);
print STDERR "MAGE creation took:", timestr($diff),"\n";

print STDERR "Writing MAGE-ML\n";
$start = new Benchmark;

my $writer = Bio::MAGE::XMLWriter->new(fh=>\*OUT);
$writer->write($mage);

$stop = new Benchmark;
$diff = timediff($stop,$start);
print STDERR "Writing XML took:", timestr($diff),"\n";

print STDERR "Finished\n";

2002	Jan	Feb	Mar	Apr	May	Jun	Jul	Aug	Sep	Oct (267)	Nov (344)	Dec (119)
2003	Jan (23)	Feb (15)	Mar (16)	Apr (388)	May	Jun (4)	Jul	Aug	Sep (4)	Oct	Nov	Dec

genex-cvs-commit Mailing List for GeneX Gene Expression Database (Page 46)

genex-cvs-commit — CVS commit messages