[Exist-commits] eXist-1.0/webapp/mods/styles mods-overview.xsl,NONE,1.1 mods-detailed.xsl,NONE,1.1 mods-common.xsl,NONE,1.1 overview.xsl,NONE,1.1 mods.css,NONE,1.1 mods-form.css,NONE,1.1

[Wolfgang M. M. <wol...@us...>]

Update of /cvsroot/exist/eXist-1.0/webapp/mods/styles
In directory sc8-pr-cvs1.sourceforge.net:/tmp/cvs-serv24889/webapp/mods/styles

Added Files:
	mods-overview.xsl mods-detailed.xsl mods-common.xsl 
	overview.xsl mods.css mods-form.css 
Log Message:
First steps to integrate new library demo.

--- NEW FILE: mods-form.css ---
a {font-size:7pt;}
a:link {text-decoration:none; color:#000000;}
a:visited {text-decoration:none; color:#000000;}
a:hover {text-decoration:underline; color:#000000;}
a:active {text-decoration:underline; color:#000000;}
a:focus {text-decoration:underline; color:#000000;}
body {
    color:#000000; 
    background-color:#ccc; 
    font-family:Verdana,Arial,Helvetica; 
    font-size:10pt; 
    margin-top:5%;
}

input {
    color:#000000; 
    background-color:#FFFFFF; 
    font-family:Verdana,Arial,Helvetica; 
    font-size:10pt;
    border:none;
}

input.invalid {
    background-color: #AA0000;
}

input:hover{
    background-color:#aabbff;
}

input:focus{
    background-color:#aabbff;
    color:white;
}

textarea {
    color:#000000; 
    background-color:#FFFFFF; 
    font-family:Verdana,Arial,Helvetica; 
    font-size:10pt;
    border:none;
}

textarea:hover{
    background-color:#aabbff;
}

textarea:focus{
    background-color:#aabbff;
    color:white;
}

select {
    color:#000000; 
    background-color:#FFFFFF; 
    font-family:Verdana,Arial,Helvetica; 
    font-size:10pt;
    border:none;
}

select:hover{
    background-color:#aabbff;
}

select:focus{
    background-color:#aabbff;
    color:white;
}

option {color:#000000; background-color:#FFFFFF; font-family:Verdana,Arial,Helvetica; font-size:10pt; border-color:#000000; border-width:0pt; border-style:hidden;}
table {
    border-width:1pt; 
    border-color:#000000; 
    border-style:solid; 
    border-collapse:collapse; 
    border-spacing:0pt; 
    margin-top:5pt; 
    width:100%;
}

table.tabsheet {
    width: 690px;
}

td { 
    color:#000000; 
    background-color:#EEEEEE; 
    font-family:Verdana,Arial,Helvetica; 
    font-size:10pt; 
    padding:5pt;
}
.hidden-table {
    border-width:1pt; 
    border-color:#EEEEEE; 
    border-style:solid; 
    border-collapse:collapse; 
    border-spacing:0pt;
    width:100%;
}
.active-tab {border-width:1pt; border-color:#000000; border-style:solid; border-bottom-style:hidden; padding-top:0pt; padding-bottom:0pt; padding-left:5pt; padding-right:5pt;}
.inactive-tab {
    border-width:1pt; 
    border-color:#000000; 
    border-style:solid; 
    background-color:#b8ceb4;
    padding:0pt;
}
.inactive-tab-button {background-color:#DDDDDD;}
.filler-tab {border-width:1pt; border-color:#000000; border-style:solid; border-top-style:hidden; border-right-style:hidden; width:99%; background-color:#FFFFFF; text-align:right; padding-left:5pt; padding-right:5pt;}
.group-label {
    color: white;
    font-weight: bold;
    border-width:1pt; 
    border-color:#000000; 
    border-style:solid; 
    background-color:#b8ceb4; 
    padding-left:5pt; 
    padding-right:5pt; 
    padding-top:2pt; 
    padding-bottom:2pt; 
    width:100%;
}

.control-label {
    vertical-align:middle; 
    padding-left:5pt; 
    padding-right:5pt;
    padding-bottom:5pt;
    width:30%;
}

.control {
    text-align:left; 
    vertical-align:middle; 
    padding-left:5pt; 
    padding-right:5pt;
    padding-bottom: 5pt;
    width:70%;
}

.label { font-weight: bold; padding-bottom: 5px; }

.full-group {
    padding: 5px;
    border: none;
}

.repeat-group {
    border: none;
}

.repeat-selected {
    border: none;
    white-space:nowrap;
    background-color:#FAFAFA;
    padding: 5px;
}

.repeat-deselected {
    border: none;
    white-space:nowrap;
    background-color:#dddddd;
    padding: 5px;
}
.selector-cell{
    background-color:#cccccc;
    vertical-align:top;
    align:center;
}
.hint {font-size: 9pt;}
.textarea { padding-top: 5px; }
.action-panel {margin:5pt; text-align:center; vertical-align:middle;}
.action-button {color:#000000; background-color:#DDDDDD; font-family:Verdana,Arial,Helvetica; font-size:10pt; border-color:#000000; border-width:1pt; border-style:solid; margin:5pt;}
.alert {
    font-size: small; 
    color:#FF0000; 
    text-align:left; 
    vertical-align:top; 
    padding-top:2pt; 
    padding-bottom:2pt;
}
.blog_shadow { 
	background: url(../images/shadow-2.png); 
	width: 680px;
	height: 20px;
	margin-left: 5px;
}

--- NEW FILE: mods-detailed.xsl ---
<?xml version="1.0" encoding="UTF-8"?>

<!-- Format query results for display -->

<xsl:stylesheet 
    xmlns:xsl="http://www.w3.org/1999/XSL/Transform"
    xmlns:m="http://www.loc.gov/mods/v3"
    xmlns:exist="http://exist.sourceforge.net/NS/exist"
    xmlns:java="http://xml.apache.org/xslt/java"
    version="1.0">
    
    <xsl:template match="items">
        <xsl:variable name="summary" select="floor((@start - 1) div @max) * @max + 1"/>
        <div>
            <table class="overview" cellspacing="0">
                <xsl:call-template name="navigation">
                    <xsl:with-param name="position" select="'top'"/>
                    <xsl:with-param name="summary" select="$summary"/>
                </xsl:call-template>
                <xsl:apply-templates/>
                <xsl:call-template name="navigation">
                    <xsl:with-param name="position" select="'bottom'"/>
                    <xsl:with-param name="summary" select="$summary"/>
                </xsl:call-template>
            </table>
        
            <div class="blog_shadow"/>
        </div>
    </xsl:template>
    
    <xsl:template name="navigation">
        <xsl:param name="position"/>
        <xsl:param name="summary"/>
        <tr class="result-head">
            <th class="nav{$position}" width="20%">
                <xsl:if test="@start &gt; 1">
                    <a class="mods" href="?start={@start - 1}&amp;display=details&amp;max={@max}">
                        &lt;&lt; Previous
                    </a>
                </xsl:if>
            </th>
            <th class="nav{$position}" width="60%">
                <a class="mods" href="?start={$summary}&amp;display=summary&amp;max={@max}">
                    <span class="icondesc">[Back to Overview]</span>
                </a>
            </th>
            <th class="nav{$position}" width="20%">
                <xsl:if test="number(@next) &lt; @hits">
                    <a class="mods" href="?start={@next}&amp;display=details&amp;max={@max}">
                        Next &gt;&gt;
                    </a>
                </xsl:if>
            </th>
        </tr>
    </xsl:template>
    
    <xsl:template match="m:mods">
        <tr>
            <td colspan="3">
                <xsl:apply-templates select="m:titleInfo"/>
                <div class="mods_names">
                    <xsl:text>by </xsl:text><xsl:apply-templates select="m:name"/>
                </div>
                <xsl:apply-templates select="m:abstract"/>
                <table class="details" cellpadding="3">
                    <xsl:if test="m:subject">
                        <tr>
                            <td class="details_heading">Subjects:</td>
                            <td>
                                <xsl:apply-templates 
                                    select="m:subject/m:topic|m:geographic"/>
                            </td>
                        </tr>
                    </xsl:if>
                    <xsl:apply-templates select="m:typeOfResource"/>
                    <xsl:apply-templates select="m:identifier"/>
                    <xsl:apply-templates select="m:originInfo"/>
                </table>
            </td>
        </tr>
    </xsl:template>
    
    <xsl:template match="m:abstract">
        <div class="mods_abstract">
            <xsl:apply-templates/>
        </div>
    </xsl:template>
    
    <xsl:template match="m:titleInfo[not(@type)]">
        <div class="dc_title">
            <xsl:for-each select="m:nonSort|m:title">
                <xsl:apply-templates select="."/><xsl:text> </xsl:text>
            </xsl:for-each>
        </div>
        <xsl:if test="m:subTitle">
            <div class="mods_subTitle">
                <xsl:apply-templates select="m:subTitle"/>
            </div>
        </xsl:if>
    </xsl:template>
    
    <xsl:template match="m:titleInfo[@type]"/>
    
    <xsl:template match="m:name">
        <xsl:if test="position() &gt; 1">
            <xsl:text>; </xsl:text>
        </xsl:if>
        <xsl:choose>
            <xsl:when test="m:namePart[not(@type)]">
                <a class="mods"
                    href="?field=au&amp;query={java:java.net.URLEncoder.encode(m:namePart[not(@type)], 'UTF-8')}&amp;mode1=near&amp;max={ancestor::query-results/@max}">
                    <xsl:apply-templates select="m:namePart[not(@type)]"/>
                </a>
            </xsl:when>
            <xsl:when test="m:namePart[@type='family']">
                <xsl:variable name="name">
                    <xsl:value-of select="m:namePart[@type='family']"/>, <xsl:value-of select="m:namePart[@type='given']"/>
                </xsl:variable>
                <a class="mods"
                    href="?field=au&amp;query={java:java.net.URLEncoder.encode($name, 'UTF-8')}&amp;mode1=near&amp;max={ancestor::query-results/@max}">
                    <xsl:apply-templates select="m:namePart[@type='family']"/>
                    <xsl:text>, </xsl:text>
                    <xsl:apply-templates select="m:namePart[@type='given']"/>
                </a>
            </xsl:when>
        </xsl:choose>
        <xsl:if test="m:namePart[@type='date']">
            <xsl:text> [</xsl:text>
            <xsl:value-of select="m:namePart[@type='date']"/>
            <xsl:text>]</xsl:text>
        </xsl:if>
        <xsl:if test="m:role">
            <xsl:text> (</xsl:text>
            <xsl:value-of select="m:role/m:roleTerm|m:role/m:text"/>
            <xsl:text>)</xsl:text>
        </xsl:if>
    </xsl:template>
    
    <xsl:template match="m:typeOfResource">
        <tr>
            <td class="details_heading">Type of Resource:</td>
            <td><xsl:apply-templates/></td>
        </tr>
    </xsl:template>
    
    <xsl:template match="m:subject">
        <xsl:apply-templates select="m:topic"/>
    </xsl:template>
    
    <xsl:template match="m:topic">
        <xsl:if test="position() != 1">
            <xsl:text>; </xsl:text>
        </xsl:if>
        <xsl:apply-templates/>
    </xsl:template>
    
    <xsl:template match="m:originInfo">
        <xsl:apply-templates select="m:edition"/>
        <xsl:apply-templates select="m:publisher"/>
        <xsl:apply-templates select="m:place"/>
        <xsl:apply-templates select="m:copyrightDate"/>
        <xsl:apply-templates select="m:dateIssued[1]"/>
    </xsl:template>
    
    <xsl:template match="m:dateIssued">
        <tr>
            <td class="details_heading">Date Issued:</td>
            <td><xsl:apply-templates/></td>
        </tr>
    </xsl:template>
    
    <xsl:template match="m:copyrightDate">
        <tr>
            <td class="details_heading">Copyright Date:</td>
            <td><xsl:apply-templates/></td>
        </tr>
    </xsl:template>
    
    <xsl:template match="m:edition">
        <tr>
            <td class="details_heading">Edition:</td>
            <td><xsl:apply-templates/></td>
        </tr>
    </xsl:template>
    
    <xsl:template match="m:place">
        <xsl:apply-templates select="m:placeTerm[@type='text']"/>
    </xsl:template>
    
    <xsl:template match="m:placeTerm">
        <tr>
            <td class="details_heading">Place:</td>
            <td><xsl:apply-templates/></td>
        </tr>
    </xsl:template>
    
    <xsl:template match="m:publisher">
        <tr>
            <td class="details_heading">Publisher:</td>
            <td><xsl:apply-templates/></td>
        </tr>
    </xsl:template>
    
    <xsl:template match="m:identifier">
        <tr>
            <td class="details_heading">
                Identifier (<xsl:value-of select="@type"/>)
            </td>
            <td>
                <xsl:choose>
                    <xsl:when test="@type='uri'">
                        <a href="{text()}">
                            <xsl:apply-templates/>
                        </a>
                    </xsl:when>
                    <xsl:otherwise>
                        <xsl:apply-templates/>
                    </xsl:otherwise>
                </xsl:choose>
            </td>
        </tr>
    </xsl:template>
    
    <xsl:template match="exist:match">
	    <span class="hit"><xsl:apply-templates/></span>
    </xsl:template>
    
</xsl:stylesheet>

--- NEW FILE: mods.css ---
body {
	background-color: #ccc;
	font-family: Arial, Verdana, sans-serif;
	font-size: 11px;
	line-height: 1.4;
}

div#header {
    text-align: left;
    font-size: 18pt;
    padding: 10px;
    background: #686868; 
    border: solid 1px gray;
    color: white;
    font-size: 14px;
    width: 860px;
    font-family: Arial;
}

.authors {
    margin-top: 35px;
    margin-bottom: 5px;
    padding-left: 10px;
    padding-right: 10px;
    text-align: right;
    border-top: 1px solid black;
}

.xmlsrc {
    margin-top: 20px;
    margin-bottom: 20px;
    padding-right: 10px;
    text-align: right;
}

div#content {
	margin-left: 160px;
	background: white;
	width: 690px;
	padding: 15px;
	border-left: 1px solid gray;
	border-bottom: 1px solid gray;
	border-right: 1px solid gray;
}

.blog_shadow { 
	background: url(../images/shadow-2.png); 
	width: 680px;
	height: 20px;
	margin-left: 5px;
}

div#sidebar {
    padding-left: 10px;
    padding-right: 10px;
    padding-bottom: 10px; 
    width: 140px; 
    margin-top: 0px;
    background: #f0f0f0;
    float: left   
}

div.banner {
    padding-top: 30px;
    padding-bottom: 10px;
}

.variablelist {
    margin-left: 15px;
}

div.group {
    color: black;
    margin-top: 2px;
    text-align: left;
    font-size: 100%;
    font-weight: bold;
    padding-top: 10px;
    }

a, a:visited: {
    color: #203cd8;
    text-decoration: none;
}

a:hover, a:active {
    color: black;
    background-color: #94FF9C;
    text-decoration: none;
}

a.group { 
    color: black;
    text-decoration: none;  
}

a.page { color: white; }

div.item {
    font-size: 80%;
    padding-right: 10px;
    text-align: right;
    padding-left: 5px;
    padding-bottom: 2px;
    margin-left: 15px;
}
.item { font-size: 80%; }

th, td { /* ns 4 */
}

td.tab {
    border-right: 2px solid black;
}

td.tabpage {
    border-right: 2px solid black;
    border-bottom: 2px solid black;
}

tr.result-head {
    background-color: black;
}

tr.row-1 {
    background-color: rgb(235, 235, 235);
}

tr.row-2 {
    background-color: white;
}
          
.error {
    background-color: #ff5555;
    font-weight: bold;
    border: 1px solid black;
    padding-left: 5px;
    padding-right: 5px;
    padding-top: 5px;
    padding-bottom: 5px;
    margin-top: 5px;
    margin-bottom: 5px;
    text-align: center;
}
          
h1 { 
    font-size: 14pt;
    font-weight: normal;
    border: 1px solid black;
    background-color:  #F7F8E4;
    margin-left: 0px;
    margin-top: 5px;
    margin-bottom: 15px;
    padding: 10px;
}
          
h2.section { 
    font-size: 14pt;
    font-weight: bold;
    margin-left: 10px;
    margin-top: 5px;
    margin-bottom: 5px;
    padding-left: 10px;
    text-align: left;
}
          
h3 { 
    font-weight: bold;
}
          
div.expansion {
    font-weight: bold;
}
          
td.entry {
    border: 1pt solid black;
}
          
table.overview {
    border: 1pt solid black;
    background: white;
    cellspacing: 0;
    padding: 10px;
    width: 680px;

}

table.details {
    color: #666;
    margin-top: 10px;
    margin-left: 15px;
}

table.query {
    font-size: small;
    border: 1pt solid black;
}

a.mods {
    color: #666;
    text-decoration: underline;
}

td.overview {
    font-size: 11px;
    padding-left: 10px;
    padding-right: 10px;
    padding-top: 4px;
    padding-bottom: 4px;
}

th.navtop {
    font-size: 10px;
    background-color: #ceccb6; 
    padding-left: 10px;
    padding-right: 10px;
    padding-top: 3px;
    padding-bottom: 4px;
    border-bottom: 1px black solid;
}

th.table-head {
    font-size: 10px;
    background-color: #b8ceb4; 
    padding-left: 10px;
    padding-right: 10px;
    padding-top: 3px;
    padding-bottom: 4px;
    border-bottom: 1px black solid;
}


th.navbottom {
    font-size: 10px;
    border-top: 1px solid black;
    background-color: #ceccb6; 
    padding-left: 10px;
    padding-right: 10px;
}

th.summary {
    color: white;
}

td.details_heading {
    font-weight: bold;
}

th.summary_heading {
    border-top: 1pt solid black;
    border-bottom: 1pt solid black;
}

div.hits {
    margin-top: 25px;
    margin-bottom: 25px;
    font-family: Courier, monospace;
    font-size: smaller;
}

div.dc_title {
    font-size: 16pt;
    margin-bottom: 8px;
}

div.mods_subTitle {
    font-size: 10pt;
    font-weight: bold;
}

div.mods_names {
    padding-top: 5px;
    padding-bottom: 5px;
}

div.mods_abstract {
    text-indent: 15px;
    text-align: justify;
    margin-top: 10px;
    margin-left: 25px;
    margin-right: 25px;
}

div.dcq_alternative {
    font-size: 10pt;
    font-weight: bold;
}

div.dcq_IMT {
    font-size: small;
    text-align: center;
}

blockquote {
    text-align: justify;
}

span.icondesc {
    font-size: small;
    padding-right: 5px;
}

img.icon {
    vertical-align: middle;
    padding-right: 15px;
}

a {
    text-decoration: none;
    color: gray;
}

span.hit {
	background-color: #F5FF82;
}

input {
    vertical-align: top;
}

input:hover{
    background-color:#aabbff;
}

input:focus{
    background-color:#aabbff;
    color:white;
}

--- NEW FILE: mods-common.xsl ---
<xsl:stylesheet 
    xmlns:xsl="http://www.w3.org/1999/XSL/Transform"
    xmlns:m="http://www.loc.gov/mods/v3"
    xmlns:exist="http://exist.sourceforge.net/NS/exist"
    xmlns:java="http://xml.apache.org/xslt/java"
    version="1.0">
    
    <xsl:template match="m:titleInfo[not(@type)]">
        <span class="title">
            <xsl:for-each select="m:nonSort|m:title">
                <xsl:value-of select="."/><xsl:text> </xsl:text>
            </xsl:for-each>
        </span>
    </xsl:template>
    
    <xsl:template match="m:abstract">
        <xsl:if test="string-length(text()) &gt; 0">
            <p class="keywords">
                <span class="heading">Abstract: </span>
                <xsl:apply-templates/>
            </p>
        </xsl:if>
    </xsl:template>
    
    <xsl:template match="m:name">
        <xsl:if test="position() != 1">
            <xsl:text>; </xsl:text>
        </xsl:if>
        <xsl:choose>
            <xsl:when test="m:namePart[not(@type)]">
                <a href="?field=au&amp;query={java:java.net.URLEncoder.encode(m:namePart[not(@type)], 'UTF-8')}&amp;mode1=near&amp;max={ancestor::items/@max}">
                    <xsl:apply-templates select="m:namePart[not(@type)]"/>
                </a>
            </xsl:when>
            <xsl:when test="m:namePart[@type='family']">
                <xsl:variable name="name">
                    <xsl:value-of select="m:namePart[@type='family']"/>, <xsl:value-of select="m:namePart[@type='given']"/>
                </xsl:variable>
                <a href="?field=au&amp;query={java:java.net.URLEncoder.encode($name, 'UTF-8')}&amp;mode1=near&amp;max={ancestor::items/@max}">
                    <xsl:apply-templates select="m:namePart[@type='family']"/>
                    <xsl:text>, </xsl:text>
                    <xsl:apply-templates select="m:namePart[@type='given']"/>
                </a>
            </xsl:when>
        </xsl:choose>
    </xsl:template>
    
    <xsl:template match="m:topic|m:geographic">
        <xsl:if test="position() != 1">
            <xsl:text>; </xsl:text>
        </xsl:if>
        <a href="?field=su&amp;query={java:java.net.URLEncoder.encode(text(), 'UTF-8')}&amp;max={ancestor::items/@max}">
            <xsl:value-of select="."/>
        </a>
    </xsl:template>
</xsl:stylesheet>

--- NEW FILE: overview.xsl ---
<?xml version="1.0" encoding="UTF-8"?>

<!-- Format query results for display -->

<xsl:stylesheet 
    xmlns:xsl="http://www.w3.org/1999/XSL/Transform"
    xmlns:m="http://www.loc.gov/mods/v3"
    xmlns:exist="http://exist.sourceforge.net/NS/exist"
    xmlns:java="http://xml.apache.org/xslt/java"
    version="1.0">
    
    <xsl:include href="mods-common.xsl"/>
    
    <xsl:template match="items">
        <div id="biblio">
            <xsl:apply-templates select="item"/>
        </div>
    </xsl:template>
    
    <xsl:template match="item">
        <div class="record">
            <a href="{@chiba}&amp;instance=/chiba/exist{../@collection}/{@doc}&amp;submitsave=store.xq?document={@doc}">
                <img src="images/edit.gif"/>
            </a>
            <a href="?action=remove&amp;doc={java:java.net.URLEncoder.encode(@doc)}&amp;collection={java:java.net.URLEncoder.encode(../@collection)}"><img src="images/delete.gif"/></a>
            <p class="citation">
                <input type="checkbox" class="mark" value="N1"/>
                <xsl:apply-templates select="m:titleInfo"/>
            </p>
            <p class="keywords">
                <span class="heading">By: </span>
                <xsl:apply-templates select="m:name"/>
            </p>
            <p class="keywords">
                <span class="heading">Topics: </span>
                <xsl:apply-templates select="m:subject/m:topic|m:subject/m:geographic"/>
            </p>
            <xsl:apply-templates select="m:abstract"/>
        </div>
    </xsl:template>
    
    <xsl:template match="p">
        <p><xsl:apply-templates/></p>
    </xsl:template>
    
    <xsl:template match="exist:match">
	    <span class="hit"><xsl:apply-templates/></span>
    </xsl:template>
</xsl:stylesheet>

--- NEW FILE: mods-overview.xsl ---
<?xml version="1.0" encoding="UTF-8"?>

<!-- Format query results for display -->

<xsl:stylesheet 
    xmlns:xsl="http://www.w3.org/1999/XSL/Transform"
    xmlns:m="http://www.loc.gov/mods/v3"
    xmlns:exist="http://exist.sourceforge.net/NS/exist"
    xmlns:java="http://xml.apache.org/xslt/java"
    version="1.0">
    
    <xsl:template match="items">
        <div>
            <table class="overview" cellspacing="0">
                <xsl:call-template name="navigation">
                    <xsl:with-param name="position" select="'top'"/>
                </xsl:call-template>
                <xsl:apply-templates/>
                <xsl:call-template name="navigation">
                    <xsl:with-param name="position" select="'bottom'"/>
                </xsl:call-template>
            </table>
            
            <div class="blog_shadow"/>
        </div>
    </xsl:template>
    
    <xsl:template name="navigation">
        <xsl:param name="position"/>
        <tr class="result-head">
            <th class="nav{$position}" width="15%"> 
                <xsl:if test="@start &gt; 1">
                    <a class="mods" href="?start={@start - @max}&amp;max={@max}">
                        &lt;&lt; Previous
                    </a>
                </xsl:if>
            </th>
            <th class="nav{$position}" width="70%" colspan="2">
                Displaying items <xsl:value-of select="@start"/> to <xsl:value-of select="@next - 1"/>
                (total: <xsl:value-of select="@hits"/>)<br/>
                <span class="icondesc">
                    [<a class="mods" href="{@chiba}&amp;submitsave={java:java.net.URLEncoder.encode('store.xq')}">
                        Create New
                    </a>]
                </span>
            </th>
            <th class="nav{$position}" width="15%">
                <xsl:if test="number(@next) &lt; @hits">
                    <a class="mods" href="?start={@next}&amp;max={@max}">
                        Next &gt;&gt;
                    </a>
                </xsl:if>
            </th>
        </tr>
        <xsl:if test="$position='top'">
            <tr class="result-head">
                <th class="table-head" width="15%"></th>
                <th class="table-head" width="20%">
                    <a class="mods"
                        href="?order=creator&amp;start={@start}&amp;max={@max}">Creator/Editor</a>
                </th>
                <th class="table-head" width="50%">
                    <a class="mods"
                        href="?order=title&amp;start={@start}&amp;max={@max}">Title</a>
                </th>
                <th class="table-head" width="15%">
                    <a class="mods"
                        href="?order=date&amp;start={@start}&amp;max={@max}">Date</a>
                </th>
            </tr>
        </xsl:if>
    </xsl:template>
    
    <xsl:template match="item">
        <tr>
            <xsl:choose>
                <xsl:when test="position() mod 2 = 0">
                    <xsl:attribute name="class">row-1</xsl:attribute>
                </xsl:when>
                <xsl:otherwise>
                    <xsl:attribute name="class">row-2</xsl:attribute>
                </xsl:otherwise>
            </xsl:choose>
            <td class="overview">
                <a href="{@chiba}&amp;instance=/chiba/exist/{@collection}/{@doc}&amp;submitsave=store.xq?document={@doc}">
                    <img src="images/edit.gif"/>
                </a>
                <a href="?action=remove&amp;doc={java:java.net.URLEncoder.encode(@doc)}&amp;collection={java:java.net.URLEncoder.encode(@collection)}"><img src="images/delete.gif"/></a>
            </td>
            <td class="overview">
                <xsl:apply-templates select="m:name"/>
            </td>
            <td class="overview">
                <a class="mods"
                    href="?start={../@start + position() - 1}&amp;display=details&amp;max={../@max}">
                    <xsl:apply-templates select="m:titleInfo"/>
                </a>
            </td>
            <td class="overview">
                <xsl:choose>
                    <xsl:when test="m:copyrightDate">
                        <xsl:value-of select="m:copyrightDate"/>
                    </xsl:when>
                    <xsl:when test="m:dateIssued[@type='marc']">
                        <xsl:value-of select="m:dateIssued[@type='marc']"/>
                    </xsl:when>
                    <xsl:when test="m:dateIssued">
                        <xsl:value-of select="m:dateIssued"/>
                    </xsl:when>
		    <xsl:when test="m:date">
		      <xsl:value-of select="m:date"/>
		    </xsl:when>
                </xsl:choose>
            </td>
        </tr>
    </xsl:template>
    
    <xsl:template match="m:titleInfo[not(@type)]">
        <xsl:for-each select="m:nonSort|m:title">
            <xsl:value-of select="."/><xsl:text> </xsl:text>
        </xsl:for-each>
    </xsl:template>
    
    <xsl:template match="m:name">
        <xsl:choose>
            <xsl:when test="m:namePart[not(@type)]">
                <xsl:apply-templates select="m:namePart[not(@type)]"/>
            </xsl:when>
            <xsl:when test="m:namePart[@type='family']">
                <xsl:apply-templates select="m:namePart[@type='family']"/>
                <xsl:text>, </xsl:text>
                <xsl:apply-templates select="m:namePart[@type='given']"/>
            </xsl:when>
        </xsl:choose>
    </xsl:template>
    
    <xsl:template match="p">
        <p><xsl:apply-templates/></p>
    </xsl:template>
    
    <xsl:template match="exist:match">
	    <span class="hit"><xsl:apply-templates/></span>
    </xsl:template>
</xsl:stylesheet>