Recent changes to Home

Discussion for Home page

Edward Sternin — Tue, 12 Jul 2022 18:03:43 -0000

Oh, I see! Vectors get created even without create! This might be good enough.

I'm not 100% clear as to why syntactical compatibility between 2.x and
3.x is needed. Nor why the vectors need to created in a single command.

Is this because the TCL code making the call can't be changed?

The reason for my initiating this compatibility discussion is this: if I want to write a code that I can distribute (to students, for example) I need to anticipate the environment in which they will be using it. The vast majority of Linux distributions out there use a fork of BLT which calls itself "v 2.5.3" - just because there is a convenient Debian/Ubuntu package of it that is installed by default by apt install blt. ActiveTCL which dominates the Windows world has dropped support for BLT altogether, although one can still find a v.2.4.7z that will install and run there. We tend to recommend to Windows users undroidwish/vanillawish which has BLT 2.4.7z built in, and this also works under Android and MacOS (androwish.org).

And I keep hoping to return all the "strays" back to this mother project. Maybe when the official version 3.0 is released , it will be picked up by the Debian/Ubuntu maintainers. Not everyone will be willing to install from source.

That is why I found myself needing to focus on robust code that runs under all flavours of BLT. As to the preference for making multiple vectors in a single command: that's just a desire for compactness and similarity with variable declarations in any other language, and a mild irritation at having to modify perfectly good code that's been running for years.

Discussion for Home page

Edward Sternin — Tue, 12 Jul 2022 00:20:43 -0000

Sorry, @ghowlett, I may have been unclear. It's the loss of ability to declare multiple vectors on one line that represents a discontinuity in syntax:

$ bltsh30 
% blt::vector create x(5) t w
unknown switch "t"
The following switches are available:
   -variable varName
   -command command
   -watchunset bool
   -flush bool
   -length length

although I just noticed that there is in v.2.5.3 from blt-dev an option:
vector configure -oldcreate bool which may be doing what I had in mind:

The configure operation sets the default options used in creating vectors: ... The -oldcreate enable the creation shortcut: vector vec1 vec2 ...

However, this seems to not have been included in 3.0, so it's probably one of the non-canonical changes made in a fork of the BLT. It does seem like a reasonable approach, though I still think that simply preserving the old flexible syntax would be my first choice.
Even in the new syntax, I think the multiple-vector option could be maintained: all switches begin with a -, so in

vector create x -length 5 t w

it's pretty clear that vectors t and w would have a zero length. Or one could use

vector create x -length 5 -- t w

Discussion for Home page

Edward Sternin — Wed, 06 Jul 2022 23:44:44 -0000

Very simple but useful things that are missing in v.2.x : [x min] and [x max]. This is difficult to overcome (my shortest version is x dup xx; xx sort; puts "$xx(0)" for min), and the best workaround I found is to use critcl:

package require BLT
namespace import ::blt::*
package require critcl
critcl::clibraries -lBLT
critcl::ccode {
  #include <tcl.h>
  #include <blt.h>
  }
critcl::cproc minValue { Tcl_Interp* ip Tcl_Obj* v } double {
  Blt_Vector *vp;
  Blt_GetVector(ip, Tcl_GetString(v), &vp);
  return vp->min;
  }
critcl::cproc maxValue { Tcl_Interp* ip Tcl_Obj* v } double {
  Blt_Vector *vp;
  Blt_GetVector(ip, Tcl_GetString(v), &vp);
  return vp->max;
  }

vector create x; x seq 5 0 -1
puts "$x(:) is from [minValue x] to [maxValue x]"

the Blt_Vector structure in C simply has the min/max within it, but in v.2.x access to them is not provided. The above will work under all versions, fast and with no memory overhead.

Unless I missed something and @gah can correct me.

Discussion for Home page

Edward Sternin — Wed, 06 Jul 2022 23:26:59 -0000

BLT v.3 significantly changed the syntax of the vector command. Since a lot of places are still running v.2.47z, trying to write universal code requires accommodations like these:

proc newVector { name len } {
  # BLT 2.x allowed to re-create existing vectors,
  # this is necessary in BLT 3 but will also work in BLT 2.x
  global BLT3 $name
  if { [info exists ${name}] } { vector destroy ${name} }
  if {$len != "" && $len > 0} { 
    if {$BLT3} {
      vector create ${name} -length $len
      # BLT 3 initializes to NaN, restore BLT 2.x behaviour of initializing to 0.0
      set ${name}(:) 0.0
      }\
    else {
      vector create ${name}($len)
      }
    }\
  else {
    vector create ${name}
    }
  } 

# take care of the BLT v.2.x syntax: "vector create x y(5) z..."
proc vectorsCreate { lv } {
  foreach v $lv {
    set v_name [lindex [split $v ()] 0]
    set v_len  [lindex [split $v ()] 1]
    newVector $v_name $v_len
    }
  }

With the above, both newVector x 5 and vectorsCreate {y(3) z t(0)} (which is a slight modification of what in v.2.47z would have been vector create y(3) z t(0)) work fine under all versions of BLT.

Discussion for Home page

Edward Sternin — Tue, 11 Feb 2020 11:30:26 -0000

BLT 2.4z has been the mainstay of most Linux distributions for a while and, unfortunately, the recent changes to the code here have not yet made through to the distribution channels. I wanted to make my code run under either the 2.x series or under the current 3.0 (4.0? in Readme) versions if you downloaded/compiled/installed that. These are some of the tricks I had to use:

if { [catch {set BLTversion [package require BLT]}] } {
    puts stderr "BLT and RBC packages are missing, maybe `sudo apt-get install blt`\n"; exit 1
} else {
  if { ![package vsatisfies $BLTversion 3] } {set BLT3 0} else {set BLT3 1}

  if { [info exists BLTversion] } {
    if { [catch namespace import ::blt::*] } { ;# in BLT3 blt::scale conflicts with tcl/tk scale
      namespace import ::blt::graph
      namespace import ::blt::vector
      namespace import ::blt::marker
      namespace import ::blt::element
      }

Then, later on I can use the BLT3 flag to identify the incompatible bits of code:

if {$BLT3} {
    if { [info exists x ] } { vector destroy x }  ; vector create x  -length $size
    if { [info exists y] } { vector destroy y1 } ; vector create y -length $size
     } else {;# BLT 2.x allowed to re-create existing vectors
    vector create x($size) y($size)
    }

  if {$BLT3} {
    $g axis configure x -title $xlabel -grid yes
    $g axis configure y -title $ylabel -grid yes
  } else {
    $g axis configure x -title $xlabel
    $g axis configure y -title $ylabel
    $g grid configure -mapx x -mapy y
    }

proc AddZoomStack { } {
  global BLT3 g
  if {$BLT3} {variable ::blt::Graph::_private} else {global zoomInfo}
  set cmd {}
  foreach margin { xaxis yaxis x2axis y2axis } {
    foreach axis [$g $margin use] {
      set min [$g axis cget $axis -min]; set max [$g axis cget $axis -max]
      set c [list $g axis configure $axis -min $min -max $max]
      append cmd "$c\n"
      }
    }
  if {$BLT3} { set _private($g,stack) [linsert $_private($g,stack) 0 $cmd]
  } else {     set zoomInfo($g,stack) [linsert $zoomInfo($g,stack) 0 $cmd] }
  }

Home modified by George A. Howlett

George A. Howlett — Tue, 30 Apr 2013 14:49:17 -0000

Welcome to your wiki!

This is the default page, edit it as you see fit. To add a new page simply reference it within brackets, e.g.: [SamplePage].

The wiki uses Markdown syntax.

Project Members:

George A. Howlett (admin)
Michael McLennan