Thread: services: services/perl/lib/AppSwitch/Base Client.pm

SourceForge Headquarters 225 Broadway Suite 1600 San Diego, CA 92101 +1 (858) 422-6466

jgsmith     01/07/20 13:54:09

  Added:       perl/lib/AppSwitch/Base Client.pm
  Log:
  Initial checkin

  Revision  Changes    Path
  1.1                  services/perl/lib/AppSwitch/Base/Client.pm

  Index: Client.pm
  ===================================================================
  package AppSwitch::Base::Client;

  our $VERSION = 0.01;

  use Carp;
  use SOAP::Transport::UNIX;

  # $ Id: $

  =head1 NAME

  AppSwitch::Base::Client

  =head1 SYNOPSIS

  package AppSwitch::MyService;

  use base q(AppSwitch::Base::Client);

  our $RPC_SERVICE = q(x-myservice);

  =head1 DESCRIPTION

  This base class contains most of the code common across service 
  clients.

  =head1 METHODS

  The following methods are provided.

  =over 4

  =item new

  This is a basic constructor for the client object.  If overriding 
  this method, use it to construct the object and then modify the 
  resulting object.

    sub new {
        my $self = shift -> SUPER::new(@_);

        # process @_ here if needed

        return $self;
    }

  =cut

  sub new {
      my $class = shift;
      $class = ref $class || $class;

      my $self = bless { }, $class;

      return $self;
  }

  =item service

  This will return the service name of the client.

  If an argument is provided, it sets the service name of the 
  client and returns the previous service name.  Be careful with 
  this as it changes how requests are sent to the service 
  providers.

  The default value is defined by the C<RPC_SERVICE> package 
  global.  The <@ISA> array is searched if needed.

  =cut

  sub service {
      my $self = shift;

      if(@_) {
          my $o = $self -> service();
          $self -> {_service} = $_[0];
          return $o;
      }

      return $self -> {_service} if defined $self -> {_service};

      my $class = ref $self || $self;

      return($self -> {_service} = ${$class . "::RPC_SERVICE"}) if(defined ${$class . "::RPC_SERVICE"});

      croak "Service class undefined by $class" unless defined @{$class . "::ISA"};

      my @classes = @{$class . "::ISA"};

      while(@classes) {
          $class = shift @classes;

          return($self -> {_service} = ${$class . "::RPC_SERVICE"}) if(defined ${$class . "::RPC_SERVICE"});

          push @classes, @{$class . "::ISA"} if defined @{$class . "::ISA"};
      }

      $class = ref $self || $self;

      croak "Service class undefined by $class";
  }

  =item request

  This actually does the request.  The first argument is the method 
  name without the service name.  All subsequent arguments are 
  considered part of a hash that is sent to the daemon as a C<struct>.

  The return value is the result of the request (if synchronous) or 
  an object from which to fetch the result at a later time (if 
  asynchronous).  Note that asynchronous requests are not supported yet.

  =cut

  sub request {
      my($self) = shift;

      my $method = shift;
      my(%args) = @_;

      $method = $self -> service() . ".$method";

      # now we need to dispatch via the SOAP/XML-RPC client object...  which is global...
      our $_transport;

      if(!defined $_client) {
          $_client = SOAP::Lite -> proxy("unix:$ENV{APPSWITCH_SOCKET}")
              or croak "Unable to connect to AppSwitch daemon: $!";
      }

      if(@_) {
          return $_client -> $method({ %args }) -> result;
      } else {
          return $_client -> $method() -> result;
      }
  }

  =item version

  This will return the version of the service provider.  If 
  multiple service providers are configured for a service, it 
  will return the lowest version.

  =cut

  sub version {
      my($self) = shift;

      return $self -> request("version");
  }

  =back

  =head1 AUTHOR

  James Smith <jg...@ja...>

  =head1 SEE ALSO

  L<AppSwitch::Daemon>,
  L<AppSwitch::Server>

  =head1 COPYRIGHT

  =cut

  1;

Thread: services: services/perl/lib/AppSwitch/Base Client.pm

appswitch-commits