--- a
+++ b/trunk/configure.in
@@ -0,0 +1,113 @@
+dnl Process this file with autoconf to produce a configure script.
+AC_INIT(qjackctlMainForm.ui.h)
+
+dnl Set default installation prefix.
+AC_PREFIX_DEFAULT(/usr/local)
+ac_prefix=$prefix
+if test "x$ac_prefix" = "xNONE"; then
+    ac_prefix=$ac_default_prefix
+fi
+AC_SUBST(ac_prefix)
+
+dnl Checks for programs.
+AC_PROG_CC
+AC_PROG_CPP
+AC_PROG_CXX
+AC_PROG_CXXCPP
+AC_PROG_GCC_TRADITIONAL
+
+dnl Checks for languages.
+AC_LANG_C
+AC_LANG_CPLUSPLUS
+
+dnl Check for QTDIR environment variable.
+AC_MSG_CHECKING([whether QTDIR environment variable is set])
+if test "x$QTDIR" = "x"; then
+  AC_MSG_RESULT([no])
+  AC_MSG_ERROR([QTDIR must be properly set.])
+else
+  AC_MSG_RESULT([$QTDIR])
+fi
+
+dnl Checks for Qt library.
+AC_CACHE_CHECK([for Qt library],
+  ac_qtlib, [
+  for X in qt-mt qt; do
+    if test "x$ac_qtlib" = "x"; then
+      if test -f $QTDIR/lib/lib$X.so -o -f $QTDIR/lib/lib$X.a; then
+        ac_qtlib=$X
+      fi
+    fi
+  done
+])
+if test "x$ac_qtlib" = "x"; then
+  AC_MSG_ERROR([Qt library not found. Maybe QTDIR isn't properly set.])
+fi
+AC_SUBST(ac_qtlib)
+
+CFLAGS="$CFLAGS -I$QTDIR/include"
+CPPFLAGS="$CPPFLAGS -I$QTDIR/include"
+LIBS="-L$QTDIR/lib -L/usr/X11R6/lib"
+
+AC_CACHE_CHECK([for Qt library version >= 3.0.1],
+  ac_qtlib_version, [
+  AC_TRY_LINK([#include "qglobal.h"], [
+#if QT_VERSION < 301
+#error Qt library 3.0.1 or greater required.
+#endif
+    ],
+    ac_qtlib_version="yes", [
+      echo "no; Qt 3.0.1 or greater is required"
+      exit
+    ])
+])
+
+dnl A common error message:
+ac_qtdir_errmsg="not found in current PATH. Maybe QTDIR isn't properly set."
+
+dnl Check for Qt qmake utility.
+AC_PATH_PROG(ac_qmake, qmake, [no], $ac_qtdir/bin:${PATH})
+if test "x$ac_qmake" = "xno"; then
+   AC_MSG_ERROR([qmake $ac_qtdir_errmsg])
+fi
+AC_SUBST(ac_qmake)
+
+dnl Check for Qt moc utility.
+AC_PATH_PROG(ac_moc, moc, [no])
+if test "x$ac_moc" = "xno"; then
+   AC_MSG_ERROR([moc $ac_qtdir_errmsg])
+fi
+AC_SUBST(ac_moc)
+
+dnl Check for Qt uic utility.
+AC_PATH_PROG(ac_uic, uic, [no])
+if test "x$ac_uic" = "xno"; then
+   AC_MSG_ERROR([uic $ac_qtdir_errmsg])
+fi
+AC_SUBST(ac_uic)
+
+dnl Checks for libraries.
+AC_CHECK_LIB(m, main)
+AC_CHECK_LIB(X11, main)
+AC_CHECK_LIB(Xext, main)
+AC_CHECK_LIB($ac_qtlib, main)
+
+dnl Checks for header files.
+AC_HEADER_STDC
+AC_HEADER_SYS_WAIT
+AC_CHECK_HEADERS(fcntl.h sys/ioctl.h unistd.h)
+
+dnl Checks for typedefs, structures, and compiler characteristics.
+AC_C_CONST
+
+dnl Checks for library functions.
+AC_CHECK_FUNCS(system)
+
+
+AC_OUTPUT(Makefile)
+
+make clean > /dev/null 2>&1
+
+echo ""
+echo "Now type 'make', followed by 'make install' as root."
+echo ""