[libexif-cvs] exif/m4 .cvsignore,NONE,1.1 Makefile.am,NONE,1.1 gp-config-msg.m4,NONE,1.1 gp-gettext-hack.m4,NONE,1.1

[Hans U. N. <hu...@us...>]

Update of /cvsroot/libexif/exif/m4
In directory sc8-pr-cvs1.sourceforge.net:/tmp/cvs-serv29102/m4

Added Files:
	.cvsignore Makefile.am gp-config-msg.m4 gp-gettext-hack.m4 
Log Message:
new build system for exif

--- NEW FILE: .cvsignore ---
Makefile
Makefile.in
autom4te.cache
codeset.m4
gettext.m4
glibc21.m4
iconv.m4
intdiv0.m4
intmax.m4
inttypes-pri.m4
inttypes.m4
inttypes_h.m4
isc-posix.m4
lcmessage.m4
lib-ld.m4
lib-link.m4
lib-prefix.m4
longdouble.m4
longlong.m4
nls.m4
po.m4
printf-posix.m4
progtest.m4
signed.m4
size_max.m4
stdint_h.m4
uintmax_t.m4
ulonglong.m4
wchar_t.m4
wint_t.m4
xsize.m4

--- NEW FILE: gp-config-msg.m4 ---
dnl
dnl GP_CONFIG_MSG
dnl
dnl Simple way to print a configuration summary at the end of ./configure.
dnl
dnl Example usage:
dnl
dnl    GP_CONFIG_INIT
dnl    GP_CONFIG_MSG([Source code location],[${srcdir}])
dnl    GP_CONFIG_MSG([Compiler],[${CC}])
dnl    GP_CONFIG_MSG
dnl    GP_CONFIG_MSG([Feature foo],[${foo}])
dnl    GP_CONFIG_MSG([Location of bar],[${bar}])
dnl    GP_CONFIG_OUTPUT
dnl

AC_DEFUN([GP_CONFIG_INIT],
[
ndim_config_msg="
Configuration (${PACKAGE_TARNAME} ${PACKAGE_VERSION}):

"
])

AC_DEFUN([GP_CONFIG_MSG],
[
AC_REQUIRE([GP_CONFIG_INIT])
# the empty string must contain at least as many spaces as the substr length
ndim_config_empty="                        "
if test -n "$1"; then
   ndim_config_msg="${ndim_config_msg}	$(expr "$1:${ndim_config_empty}" : "\(.\{0,22\}\)") $2
"
else
   ndim_config_msg="${ndim_config_msg}
"
fi
])

AC_DEFUN([GP_CONFIG_OUTPUT],
[
AC_REQUIRE([GP_CONFIG_INIT])
AC_REQUIRE([GP_CONFIG_MSG])
echo "${ndim_config_msg}
You may run \"make\" and \"make install\" now."
])

dnl Please do not remove this:
dnl filetype: de774af3-dc3b-4b1d-b6f2-4aca35d3da16
dnl I use this to find all the different instances of this file which 
dnl are supposed to be synchronized.

dnl Local Variables:
dnl mode: autoconf
dnl End:

--- NEW FILE: gp-gettext-hack.m4 ---
dnl
dnl GP_GETTEXT_HACK
dnl
dnl gettext hack, originally designed for libexif, libgphoto2, and Co.
dnl This creates a po/Makevars file with adequate values if the
dnl po/Makevars.template is present.
dnl
dnl Example usage:
dnl    GP_GETTEXT_HACK([${PACKAGE_TARNAME}-${LIBFOO_CURRENT}],
dnl                    [Copyright Holder],
dnl                    [foo...@ex...])
dnl    ALL_LINGUAS="de es fr"
dnl    AM_GNU_GETTEXT([external])
dnl    GP_GETTEXT_FLAGS
dnl
dnl You can leave out the GP_GETTEXT_HACK parameters if you want to,
dnl GP_GETTEXT_HACK will try fall back to sensible values in that case:
dnl

AC_DEFUN([GP_GETTEXT_HACK],
[
if test -n "$1"; then
   GETTEXT_PACKAGE="$1"
else
   GETTEXT_PACKAGE=${PACKAGE_TARNAME}
fi
AC_DEFINE_UNQUOTED([GETTEXT_PACKAGE], ["$GETTEXT_PACKAGE"],
                   [The gettext domain we're using])
AC_SUBST([GETTEXT_PACKAGE])
sed_cmds="s|^DOMAIN.*|DOMAIN = ${GETTEXT_PACKAGE}|"
if test -n "$2"; then
   sed_cmds="${sed_cmds};s|^COPYRIGHT_HOLDER.*|COPYRIGHT_HOLDER = $2|"
fi
if test -n "$3"; then
   sed_mb="$3"
elif test -n "$PACKAGE_BUGREPORT"; then
   sed_mb="${PACKAGE_BUGREPORT}"
else
   AC_MSG_ERROR([
*** Your configure.{ac,in} is wrong.
*** Either define PACKAGE_BUGREPORT (by using the 4-parameter AC INIT syntax)
*** or give [GP_GETTEXT_HACK] the second parameter.
***
])
fi
sed_cmds="${sed_cmds};s|^MSGID_BUGS_ADDRESS.*|MSGID_BUGS_ADDRESS = ${sed_mb}|"
# Not so sure whether this hack is all *that* evil...
AC_MSG_CHECKING([for po/Makevars requiring hack])
if test -f po/Makevars.template; then
   sed "$sed_cmds" < po/Makevars.template > po/Makevars
   AC_MSG_RESULT([yes, done.])
else
   AC_MSG_RESULT([no])
fi
])

AC_DEFUN([GP_GETTEXT_FLAGS],
[
AC_REQUIRE([AM_GNU_GETTEXT])
AC_REQUIRE([GP_CONFIG_MSG])
if test "x${BUILD_INCLUDED_LIBINTL}" = "xyes"; then
   AM_CFLAGS="${AM_CFLAGS} -I\$(top_srcdir)/intl"
fi
GP_CONFIG_MSG
GP_CONFIG_MSG([Use translations],[${USE_NLS}])
if test "x$USE_NLS" = "xyes" && test "${BUILD_INCLUDED_LIBINTL}"; then
   GP_CONFIG_MSG([Use included libintl],[${BUILD_INCLUDED_LIBINTL}])
fi
])

dnl Please do not remove this:
dnl filetype: 71ff3941-a5ae-4677-a369-d7cb01f92c81
dnl I use this to find all the different instances of this file which 
dnl are supposed to be synchronized.

dnl Local Variables:
dnl mode: autoconf
dnl End:

--- NEW FILE: Makefile.am ---
EXTRA_DIST = gp-gettext-hack.m4 gp-config-msg.m4