Steel Bank Common Lisp

Hi, I would like to read and uncompress a .gz file on Linux on the
fly.

I tried something like

(let* ((instance (sb-ext:run-program "zcat" '("/tmp/test.gz")
				    :output :stream))
       (stream (sb-ext:process-output instance)))
  (display-stream stream))

where display-stream is simply

(defun display-stream (stream)
  "Display stream line by line until EOF."
  (tagbody
   top 
     (let ((line (read-line stream nil nil)))
       (when line
	 (format t "~a~%" line)
	 (go top)))))

but I get no output.  The file exists:

$ zcat /tmp/test.gz
Lorem ipsum dolor sit amet, consectetur adipisicing elit, sed do eiusmod
tempor incididunt ut labore et dolore magna aliqua. Ut enim ad minim 
veniam,
quis nostrud exercitation ullamco laboris nisi ut aliquip ex ea commodo
consequat. Duis aute irure dolor in reprehenderit in voluptate velit esse
cillum dolore eu fugiat nulla pariatur. Excepteur sint occaecat cupidatat
non proident, sunt in culpa qui officia deserunt mollit anim id est 
laborum.

and the uncompressed, non-piped version is read just fine with

(with-open-file (stream "/tmp/test")
  (display-stream stream))

I would appreciate any help on what I am doing wrong.

Tamas

Tamas K Papp wrote:

> (let* ((instance (sb-ext:run-program "zcat" '("/tmp/test.gz")
> 				    :output :stream))
>        (stream (sb-ext:process-output instance)))
>   (display-stream stream))
>
> [...]
>
> I would appreciate any help on what I am doing wrong.

  1. You're not checking the return value. This in itself is
     not the problem but it may have hinted at

  2. You need to specify the full path to the program or
     pass :SEARCH T to RUN-PROGRAM.

Hope that helps. :)

  Leslie

-- 
http://www.linkedin.com/in/polzer

On Sep 20, 2009, at 11:51, Leslie P. Polzer wrote:

> Tamas K Papp wrote:
>
>> (let* ((instance (sb-ext:run-program "zcat" '("/tmp/test.gz")
>> 				    :output :stream))
>>       (stream (sb-ext:process-output instance)))
>>  (display-stream stream))
>>
>> [...]
>>
>> I would appreciate any help on what I am doing wrong.
>
>  1. You're not checking the return value. This in itself is
>     not the problem but it may have hinted at
>
>  2. You need to specify the full path to the program or
>     pass :SEARCH T to RUN-PROGRAM.

Also, you need to specify :wait nil to not wait for zcat to exit  
before reaching DISPLAY-STREAM, else the programs will deadlock as  
soon as the uncompressed data exceeds the size of a pipe buffer.

-- 
Kevin Reid                                  <http://switchb.org/kpreid/>

Also, when using :wait nil, you must call sb-ext:process-wait to ensure 
exit code is ready to be read and to avoid defunct processes.

Additionally you should call sb-ext:process-close to ensure the output 
stream (and any other streams) of the processes is closed.

To sum up:

(let ((instance (sb-ext:run-program "zcat" '("/tmp/test.gz")
				    :output :stream
				    :search t
				    :wait nil)))
   (unwind-protect
        (display-stream (sb-ext:process-output instance))
     (sb-ext:process-wait instance)
     (sb-ext:process-close instance))
   (assert (zerop (sb-ext:process-exit-code instance)) ()
	  "zcat exited with code ~A"
	  (sb-ext:process-exit-code instance)))

Thomas Bakketun wrote:

> Additionally you should call sb-ext:process-close to ensure the output
> stream (and any other streams) of the processes is closed.

Hmm, I think streams are closed when they're being finalized.

  Leslie

-- 
http://www.linkedin.com/in/polzer