1. Summary
  2. Files
  3. Support
  4. Report Spam
  5. Create account
  6. Log in

root/trunk/smartmontools/configure.in @ 3192

Revision 3192, 18.6 KB (checked in by chrfranke, 3 years ago)

Remove unused controller support from dev_legacy adapter module.

  • Property svn:eol-style set to native
  • Property svn:keywords set to Id
Line 
1#
2# $Id$
3#
4dnl Process this file with autoconf to produce a configure script.
5AC_PREREQ(2.50)
6AC_INIT(smartmontools, 5.41, smartmontools-support@lists.sourceforge.net)
7AC_CONFIG_SRCDIR(smartctl.cpp)
8
9smartmontools_configure_date=`date -u +'%Y-%m-%d %T %Z'`
10smartmontools_cvs_tag=`echo '$Id$'`
11smartmontools_release_date=2010-10-16
12smartmontools_release_time="16:34:38 UTC"
13
14AC_DEFINE_UNQUOTED(SMARTMONTOOLS_CONFIGURE_ARGS, "$ac_configure_args",            [smartmontools Configure Arguments])
15AC_DEFINE_UNQUOTED(SMARTMONTOOLS_CONFIGURE_DATE, "$smartmontools_configure_date", [smartmontools Configure Date])
16AC_DEFINE_UNQUOTED(SMARTMONTOOLS_RELEASE_DATE,   "$smartmontools_release_date",   [smartmontools Release Date])
17AC_DEFINE_UNQUOTED(SMARTMONTOOLS_RELEASE_TIME,   "$smartmontools_release_time",   [smartmontools Release Time])
18AC_DEFINE_UNQUOTED(CONFIG_H_CVSID,               "$smartmontools_cvs_tag",        [smartmontools CVS Tag])
19AC_DEFINE_UNQUOTED(PACKAGE_HOMEPAGE,             "http://smartmontools.sourceforge.net/", [smartmontools Home Page])
20
21AM_CONFIG_HEADER(config.h)
22
23AM_INIT_AUTOMAKE
24
25AM_MAINTAINER_MODE
26
27AC_LANG_CPLUSPLUS
28dnl Checks for programs.
29AC_PROG_CXX
30AM_PROG_AS
31AC_PROG_INSTALL
32
33AC_ARG_VAR(WINDMC, [Windows message compiler command])
34AC_ARG_VAR(WINDRES, [Windows resource compiler command])
35
36AC_CANONICAL_HOST
37dnl Set flags which may affect AC_CHECK_*.
38case "${host}" in
39        *-*-mingw*)
40                # Cygwin gcc 4.x does no longer support '-mno-cygwin' to select MinGW gcc.
41                if test "${build}" = "${host}" && test -x /usr/bin/uname && \
42                   /usr/bin/uname | grep -i '^CYGWIN' >/dev/null; then
43                  AC_MSG_ERROR([Build with MinGW on Cygwin requires cross-compilation, see INSTALL file.])
44                fi
45                AC_CHECK_PROGS(WINDMC, [${host}-windmc windmc])
46                AC_CHECK_PROGS(WINDRES, [${host}-windres windres])
47                CPPFLAGS="$CPPFLAGS -I$srcdir/os_win32"
48                ;;
49        *-*-freebsd*)
50                CPPFLAGS="$CPPFLAGS -I/usr/src/sys"
51                ;;
52esac
53
54# Check for SVN.
55AC_MSG_CHECKING([whether this is a build from SVN])
56is_svn_build=no
57if test -f "$srcdir/.svn/entries"; then
58  is_svn_build=unknown
59  if (cd "$srcdir" && svn --version && svnversion && svn info) >/dev/null 2>&1; then
60    is_svn_build=yes
61  fi
62fi
63AM_CONDITIONAL(IS_SVN_BUILD, [test "$is_svn_build" = "yes"])
64AC_MSG_RESULT([$is_svn_build])
65
66dnl Checks for libraries needed for name services (Solaris needs
67dnl libnsl, might in the future also need libsocket)
68#  AC_SEARCH_LIBS (FUNCTION, SEARCH-LIBS, [ACTION-IF-FOUND], [ACTION-IF-NOT-FOUND], [OTHER-LIBRARIES])
69AC_SEARCH_LIBS(socket, socket)
70AC_SEARCH_LIBS(gethostbyname, nsl)
71AC_SEARCH_LIBS(getaddrinfo, nsl)
72AC_SEARCH_LIBS(getdomainname, nsl)
73
74dnl Checks for header files.
75AC_CHECK_HEADERS([locale.h])
76AC_CHECK_HEADERS([dev/ata/atavar.h])
77AC_CHECK_HEADERS([netdb.h])
78dnl we need [u]int64_t and friends.
79AC_CHECK_HEADERS([inttypes.h])          dnl C99, UNIX98, solaris 2.6+
80AC_CHECK_HEADERS([stdint.h])            dnl C99
81AC_CHECK_HEADERS([sys/inttypes.h])      dnl pre-UNIX98
82AC_CHECK_HEADERS([sys/int_types.h])     dnl pre-UNIX98, solaris 2.6+
83dnl Check for FreeBSD twe include files...currently missing on 5.2, but should be there
84AC_CHECK_HEADERS([sys/tweio.h])
85AC_CHECK_HEADERS([sys/twereg.h])
86dnl Check for FreeBSD twa include files...
87AC_CHECK_HEADERS([sys/tw_osl_ioctl.h])
88dnl Check for FreeBSD ciss include files...
89AC_CHECK_HEADERS([dev/ciss/cissio.h])
90dnl This header file is needed for cciss_ioctl.h at least on SuSE LINUX
91AC_CHECK_HEADERS([linux/compiler.h])
92dnl Check for Linux CCISS include file
93AC_CHECK_HEADERS([linux/cciss_ioctl.h], [], [], [AC_INCLUDES_DEFAULT
94#ifdef HAVE_LINUX_COMPILER_H
95# include <linux/compiler.h>
96#endif
97])
98dnl Check for Windows DDK header files
99AC_CHECK_HEADERS([ntdddisk.h ddk/ntdddisk.h], [], [], [AC_INCLUDES_DEFAULT
100#include <windows.h>
101])
102
103dnl Checks for typedefs, structures, and compiler characteristics.
104AC_CHECK_TYPES([int64_t, uint64_t])
105
106dnl Checks for library functions.
107AC_CHECK_FUNCS([getopt_long], [need_getopt_long=no], [need_getopt_long=yes])
108AM_CONDITIONAL(NEED_GETOPT_LONG, [test "$need_getopt_long" = "yes"])
109AC_CHECK_FUNCS([regcomp], [need_regex=no], [need_regex=yes])
110AM_CONDITIONAL(NEED_REGEX, [test "$need_regex" = "yes"])
111
112AC_CHECK_FUNCS([getdomainname])
113AC_CHECK_FUNCS([gethostname])
114AC_CHECK_FUNCS([getaddrinfo])
115AC_CHECK_FUNCS([gethostbyname])
116AC_CHECK_FUNCS([sigset])
117AC_CHECK_FUNCS([strtoull])
118AC_CHECK_FUNCS([uname])
119
120# Check byte ordering (defines WORDS_BIGENDIAN)
121AC_C_BIGENDIAN
122
123# Check whether snprintf appends null char and returns expected length on overflow
124AC_MSG_CHECKING([for working snprintf])
125AC_RUN_IFELSE([AC_LANG_PROGRAM([[#include <stdio.h>]], [[ char buf[]="ABCDEFGHI";
126               int i=snprintf(buf,8,"12345678"); return !(!buf[7] && i==8); ]])],
127              [libc_have_working_snprintf=yes],
128              [libc_have_working_snprintf=no],
129              [libc_have_working_snprintf=unknown])
130AC_SUBST(libc_have_working_snprintf)
131if test "$libc_have_working_snprintf" = "yes"; then
132  AC_DEFINE(HAVE_WORKING_SNPRINTF, 1, [Define to 1 if the `snprintf' function is sane])
133fi
134AC_MSG_RESULT([$libc_have_working_snprintf])
135
136# check for __attribute__((packed))
137AC_MSG_CHECKING([whether $CXX supports __attribute__((packed))])
138AC_COMPILE_IFELSE([AC_LANG_PROGRAM(, [[struct a { int b; } __attribute__((packed));]])],
139                  [gcc_have_attr_packed=yes], [gcc_have_attr_packed=no])
140AC_COMPILE_IFELSE([AC_LANG_PROGRAM(, [[#if defined(__SUNPRO_C) || defined(__SUNPRO_CC)
141#error "Sun's compiler cannot handle __attribute__((packed))!"
142#endif]])],
143                  [true], [gcc_have_attr_packed=no])
144AC_SUBST(gcc_have_attr_packed)
145if test "$gcc_have_attr_packed" = "yes"; then
146  AC_DEFINE(HAVE_ATTR_PACKED, 1, [Define to 1 if C++ compiler supports __attribute__((packed))])
147fi
148AC_MSG_RESULT([$gcc_have_attr_packed])
149
150AC_SUBST(CPPFLAGS)
151AC_SUBST(LDFLAGS)
152AC_SUBST(ASFLAGS)
153
154AC_SUBST([exampledir], ['${docdir}/examplescripts'])
155
156AC_ARG_WITH(initscriptdir,
157  [AC_HELP_STRING([--with-initscriptdir=DIR],[Location of init scripts [SYSCONFDIR/rc.d/init.d]])],
158  [initddir="$withval"],[initddir='${sysconfdir}/rc.d/init.d'])
159AC_SUBST(initddir)
160AM_CONDITIONAL(INSTALL_INITSCRIPT, [test "$with_initscriptdir" != "no"])
161
162docdir_is_default=no
163AC_ARG_WITH(docdir,
164  [AC_HELP_STRING([--with-docdir=DIR],[Location of documentation [DATADIR/doc/smartmontools]])],
165  [docdir="$withval"],
166  [ if test -z "$docdir"; then
167      # autoconf 2.5x without '--docdir' support
168      docdir='${datadir}/doc/${PACKAGE}'
169      docdir_is_default=yes
170    elif test "$docdir" = '${datarootdir}/doc/${PACKAGE_TARNAME}'; then
171      # autoconf 2.6x '--docdir' default
172      docdir_is_default=yes
173    fi
174  ])
175AC_SUBST(docdir)
176
177AC_ARG_ENABLE(drivedb,
178  [AC_HELP_STRING([--disable-drivedb],[Disables drive database file])],
179  [drivedbdir_is_default=no],
180  [enable_drivedb=yes; drivedbdir_is_default=yes])
181
182AC_ARG_WITH(drivedbdir,
183  [AC_HELP_STRING([--with-drivedbdir=DIR],[Location of drive database file (implies --enable-drivedb) [DATADIR/smartmontools]])],
184  [drivedbdir="$withval"; enable_drivedb=yes; drivedbdir_is_default=no],
185  [drivedbdir=; test "$enable_drivedb" = "yes" && drivedbdir='${datadir}/${PACKAGE}'])
186AC_SUBST(drivedbdir)
187AM_CONDITIONAL(ENABLE_DRIVEDB, [test "$enable_drivedb" = "yes"])
188
189AC_ARG_ENABLE(savestates, [AC_HELP_STRING([--enable-savestates],[Enables default smartd state files])])
190
191AC_ARG_WITH(savestates,
192  [AC_HELP_STRING([--with-savestates=PREFIX],[Prefix for default smartd state files (implies --enable-savestates) [LOCALSTATEDIR/lib/smartmontools/smartd.]])],
193  [savestates="$withval"; enable_savestates="yes"],
194  [savestates=; test "$enable_savestates" = "yes" && savestates='${localstatedir}/lib/${PACKAGE}/smartd.'])
195savestatesdir="${savestates%/*}"
196AC_SUBST(savestates)
197AC_SUBST(savestatesdir)
198AM_CONDITIONAL(ENABLE_SAVESTATES, [test "$enable_savestates" = "yes"])
199
200AC_ARG_ENABLE(attributelog, [AC_HELP_STRING([--enable-attributelog],[Enables default smartd attribute log files])])
201
202AC_ARG_WITH(attributelog,
203  [AC_HELP_STRING([--with-attributelog=PREFIX],[Prefix for default smartd attribute log files (implies --enable-attributelog) [LOCALSTATEDIR/lib/smartmontools/attrlog.]])],
204  [attributelog="$withval"; enable_attributelog="yes"],
205  [attributelog=; test "$enable_attributelog" = "yes" && attributelog='${localstatedir}/lib/${PACKAGE}/attrlog.'])
206attributelogdir="${attributelog%/*}"
207AC_SUBST(attributelog)
208AC_SUBST(attributelogdir)
209AM_CONDITIONAL(ENABLE_ATTRIBUTELOG, [test "$enable_attributelog" = "yes"])
210
211AC_ARG_ENABLE(sample,
212  [AC_HELP_STRING([--enable-sample],[Enables appending .sample to the installed smartd rc script and configuration file])],
213  [smartd_suffix=; test "$enableval" = "yes" && smartd_suffix=".sample"],
214  [smartd_suffix=;])
215AC_SUBST(smartd_suffix)
216AM_CONDITIONAL(SMARTD_SUFFIX, [test -n "$smartd_suffix"])
217
218AC_ARG_WITH(os-deps,
219  [AC_HELP_STRING([--with-os-deps='os_module.o ...'],[Specify OS dependent module(s) [guessed]])],
220  [ for x in $with_os_deps; do
221      case $x in
222        *.o) ;;
223        *) AC_MSG_ERROR([non-object file specified by --with-os-deps]) ;;
224      esac
225    done
226  ],[])
227
228AC_ARG_WITH(selinux,
229  [AC_HELP_STRING([--with-selinux@<:@=yes|no@:>@],[Enables SELinux support [no]])],
230  [ if test "$withval" = "yes"; then
231      AC_CHECK_HEADERS([selinux/selinux.h], [], [AC_MSG_ERROR([Missing SELinux header files])])
232      AC_CHECK_LIB(selinux, matchpathcon, [], [AC_MSG_ERROR([Missing or incorrect SELinux library files])])
233    fi
234  ],[])
235AC_SUBST(with_selinux)
236if test "$with_selinux" = "yes"; then
237  AC_DEFINE(WITH_SELINUX, 1, [Define to 1 if SELinux support is enabled])
238fi
239
240AC_ARG_WITH(libcap-ng,
241  [AC_HELP_STRING([--with-libcap-ng@<:@=auto|yes|no@:>@],[Add Libcap-ng support to smartd [auto]])],
242  [with_libcap_ng="$withval"],
243  [with_libcap_ng=auto])
244
245use_libcap_ng=no
246if test "$with_libcap_ng" != "no"; then
247  AC_CHECK_LIB(cap-ng, capng_clear,
248    [AC_DEFINE(HAVE_LIBCAP_NG, 1, [Define to 1 if you have the `cap-ng' library (-lcap-ng).])
249     CAPNG_LDADD="-lcap-ng"; use_libcap_ng=yes])
250
251  if test "$use_libcap_ng" = "yes"; then
252    AC_CHECK_HEADER(cap-ng.h, [], [AC_MSG_ERROR([libcap-ng libraries found but headers are missing])])
253  elif test "$with_libcap_ng" = "yes"; then
254    AC_MSG_ERROR([libcap-ng support was requested but the library was not found])
255  fi
256fi
257
258AC_MSG_CHECKING([whether to use libcap-ng])
259AC_SUBST(CAPNG_LDADD)
260AM_CONDITIONAL(ENABLE_CAPABILITIES, [test "$use_libcap_ng" = "yes"])
261AC_MSG_RESULT([$use_libcap_ng])
262
263if test "$prefix" = "NONE"; then
264    dnl no prefix and no mandir, so use ${prefix}/share/man as default
265    if test "$mandir" = '${prefix}/man'; then
266        AC_SUBST([mandir], ['${prefix}/share/man'])
267    fi
268fi
269
270AC_SUBST(releaseversion,['${PACKAGE}-${VERSION}'])
271AC_SUBST(smartmontools_release_date)
272AC_SUBST(smartmontools_release_time)
273
274AC_MSG_CHECKING([for OS dependent modules and libraries])
275dnl if OS not recognized, then use the os_generic modules
276os_win64=no
277case "${host}" in
278        *-*-linux*)
279                AC_SUBST([os_deps], ['os_linux.o cciss.o'])
280                if test "$with_selinux" = "yes"; then
281                        AC_SUBST([os_libs], ['-lselinux'])
282                else
283                        AC_SUBST([os_libs], [''])
284                fi;;
285        *-*-freebsd*|*-*-dragonfly*|*-*-kfreebsd*-gnu*)
286                AC_SUBST([os_deps], ['os_freebsd.o cciss.o'])
287                AC_SUBST([os_libs], ['-lcam'])
288                AC_CHECK_LIB(usb, libusb20_dev_get_device_desc)
289                ;;
290        sparc-*-solaris*)
291                AC_DEFINE_UNQUOTED(DEFAULT_MAILER, "mailx", [use mailx as default mailer])
292                AC_DEFINE_UNQUOTED(NEED_SOLARIS_ATA_CODE, "os_solaris_ata.s", [need assembly code os_solaris_ata.s])
293                AC_SUBST([os_deps], ['os_solaris.o os_solaris_ata.o'])
294                AC_SUBST([os_libs], ['']) ;;
295        *-pc-solaris*)
296                AC_DEFINE_UNQUOTED(DEFAULT_MAILER, "mailx", [use mailx as default mailer])
297                AC_SUBST([os_deps], ['os_solaris.o'])
298                AC_SUBST([os_libs], ['']) ;;
299        *-*-netbsd*)
300                AC_SUBST([os_deps], ['os_netbsd.o'])
301                AC_SUBST([os_libs], ['-lutil']) ;;
302        *-*-openbsd*)
303                AC_SUBST([os_deps], ['os_openbsd.o'])
304                AC_SUBST([os_libs], ['-lutil']) ;;
305        *-*-cygwin*)
306                AC_SUBST([os_deps], ['os_win32.o'])
307                AC_SUBST([os_libs], ['']) ;;
308        *-*-mingw*)
309                AC_SUBST([os_deps], ['os_win32.o'])
310                AC_SUBST([os_libs], [''])
311                test "$host_cpu" = "x86_64" && os_win64=yes ;;
312        *-*-darwin*)
313                AC_SUBST([os_deps], ['os_darwin.o'])
314                AC_SUBST([os_libs], ['-framework CoreFoundation -framework IOKit']) ;;
315        *-*-nto-qnx*)
316                AC_SUBST([os_deps], ['os_qnxnto.o'])
317                AC_SUBST([os_libs], ['']) ;;
318               
319        *)
320                AC_SUBST([os_deps], ['os_generic.o'])
321                AC_SUBST([os_libs], ['']) ;;
322esac
323
324# Replace if '--with-os-deps' was specified
325test -z "$with_os_deps" || os_deps="$with_os_deps"
326AC_MSG_RESULT([$os_deps $os_libs])
327
328# Check if we need adapter to old interface (dev_legacy.cpp)
329os_src=`echo "${os_deps}"|sed -n 's,^\([[^ .]]*\)\.o.*$,\1.cpp,p'`
330AC_MSG_CHECKING([whether ${os_src} uses new interface])
331if grep "smart_interface" "${srcdir}/${os_src}" >/dev/null 2>&1; then
332  os_new_interface=yes
333else
334  os_new_interface=no
335  os_deps="${os_deps} dev_legacy.o"
336  AC_DEFINE(OLD_INTERFACE, 1, [Define to 1 if os_*.cpp still uses the old interface])
337fi
338AC_MSG_RESULT([$os_new_interface])
339
340dnl Define platform-specific symbol.
341AM_CONDITIONAL(OS_DARWIN, [echo $host_os | grep '^darwin' > /dev/null])
342AM_CONDITIONAL(OS_SOLARIS, [echo $host_os | grep '^solaris' > /dev/null])
343AM_CONDITIONAL(OS_WIN32_MINGW, [echo $host_os | grep '^mingw' > /dev/null])
344AM_CONDITIONAL(OS_WIN32_WINDMC, [test -n "$WINDMC" && test "$WINDMC" != "no" && test -n "$WINDRES"])
345AM_CONDITIONAL(OS_WIN64, [test "$os_win64" = "yes"])
346AM_CONDITIONAL(OS_FREEBSD, [echo $host_os | grep '^freebsd' > /dev/null])
347
348dnl Add -Wall and -W if using g++ and its not already specified.
349if test "$GXX" = "yes"; then
350  if test -z "`echo "$CXXFLAGS" | grep "\-Wall" 2> /dev/null`" ; then
351      CXXFLAGS="$CXXFLAGS -Wall"
352  fi
353# In the next line, do NOT delete the 2 spaces inside double quotes.
354  if test -z "`echo "$CXXFLAGS " | grep "\-W " 2> /dev/null`" ; then
355      CXXFLAGS="$CXXFLAGS -W"
356  fi
357  case "${host}" in
358    *-*-mingw*)
359      # MinGW uses MSVCRT.DLL which uses printf format "%I64d" and not "%lld" for int64_t
360      CXXFLAGS="$CXXFLAGS -Wno-format";;
361  esac
362
363  # Disable strict aliasing rules by default (see ticket #23).
364  if test -z "`echo "$CXXFLAGS" | grep "\-f[[no-]]*strict-aliasing" 2> /dev/null`" ; then
365    AC_MSG_CHECKING([whether $CXX supports -fno-strict-aliasing])
366    ac_save_CXXFLAGS="$CXXFLAGS"
367    CXXFLAGS="-fno-strict-aliasing"
368    AC_COMPILE_IFELSE([AC_LANG_PROGRAM()],
369      [gcc_have_fno_strict_aliasing=yes], [gcc_have_fno_strict_aliasing=no])
370    CXXFLAGS="$ac_save_CXXFLAGS"
371    if test "$gcc_have_fno_strict_aliasing" = "yes"; then
372      CXXFLAGS="$CXXFLAGS -fno-strict-aliasing"
373    fi
374    AC_MSG_RESULT([$gcc_have_fno_strict_aliasing])
375  fi
376
377else
378 dnl We are NOT using gcc, so enable host-specific compiler flags
379 case "${host}" in
380        sparc*-*-solaris*)
381          dnl set CXXFLAGS for Solaris/SPARC C++ compiler
382          if test -z "`echo "$CXXFLAGS" | grep "\-xmemalign" 2> /dev/null`" ; then
383            dnl we have to tell the compilers about packed ATA structures
384            CXXFLAGS="-xmemalign=1i $CXXFLAGS"
385          fi
386 esac
387 case "${host}" in
388        *-*-solaris*)
389          if test -z "`echo "$CXXFLAGS" | grep "\-xO" 2> /dev/null`" ; then
390            dnl turn on optimization if user has not explicitly set its value
391            CXXFLAGS="-xO2 $CXXFLAGS"
392          fi
393          if test -z "`echo "$CXXFLAGS" | grep "\-erroff" 2> /dev/null`" ; then
394            dnl suppress trivial warnings
395            CXXFLAGS="-erroff=%none,wbadinitl,wbadasgl,badargtypel2w,badargtype2w $CXXFLAGS"
396          fi
397 esac
398fi
399
400AC_DEFINE_UNQUOTED(SMARTMONTOOLS_BUILD_HOST,     "${host}",                       [smartmontools Build Host])
401
402AC_SUBST(CXXFLAGS)
403
404AC_OUTPUT(Makefile examplescripts/Makefile)
405AC_PROG_MAKE_SET
406
407echo "-----------------------------------------------------------------------------" >&AS_MESSAGE_FD
408echo "${PACKAGE}-${VERSION} configuration:" >&AS_MESSAGE_FD
409echo "host operating system:  $host" >&AS_MESSAGE_FD
410echo "C++ compiler:           $CXX" >&AS_MESSAGE_FD
411echo "C compiler:             $CC" >&AS_MESSAGE_FD
412echo "preprocessor flags:     $CPPFLAGS" >&AS_MESSAGE_FD
413echo "C++ compiler flags:     $CXXFLAGS" >&AS_MESSAGE_FD
414echo "C compiler flags:       $CFLAGS" >&AS_MESSAGE_FD
415echo "linker flags:           $LDFLAGS" >&AS_MESSAGE_FD
416
417case "$host_os" in
418  mingw*)
419    echo "resource compiler:      $WINDRES" >&AS_MESSAGE_FD
420    echo "message compiler:       $WINDMC" >&AS_MESSAGE_FD
421    if test -n "$drivedbdir"; then
422      echo "drive database file:    EXEDIR/drivedb.h" >&AS_MESSAGE_FD
423      if test "$drivedbdir_is_default" = "yes"; then
424        echo "(NOTE: old default was: [[disabled]])" >&AS_MESSAGE_FD
425      fi
426    else
427      echo "drive database file:    [[disabled]]" >&AS_MESSAGE_FD
428    fi
429    if test -n "$savestates"; then
430      echo "smartd save files:      `eval eval eval echo $savestates`MODEL-SERIAL.TYPE.state" >&AS_MESSAGE_FD
431    fi
432    if test -n "$attributelog"; then
433      echo "smartd attribute logs:  `eval eval eval echo $attributelog`MODEL-SERIAL.TYPE.csv" >&AS_MESSAGE_FD
434    fi
435    ;;
436
437  *)
438    echo "binary install path:    `eval eval eval echo $sbindir`" >&AS_MESSAGE_FD
439    echo "man page install path:  `eval eval eval echo $mandir`" >&AS_MESSAGE_FD
440    echo "doc file install path:  `eval eval eval echo $docdir`" >&AS_MESSAGE_FD
441    if test "$docdir_is_default" = "yes"; then
442      echo "(NOTE: old default was: `eval eval eval echo ${prefix}/share/doc/${PACKAGE}-${VERSION}`)" >&AS_MESSAGE_FD
443    fi
444    if test -n "$drivedbdir"; then
445      echo "drive database file:    `eval eval eval echo $drivedbdir`/drivedb.h" >&AS_MESSAGE_FD
446      if test "$drivedbdir_is_default" = "yes"; then
447        echo "(NOTE: old default was: [[disabled]])" >&AS_MESSAGE_FD
448      fi
449      echo "database update script: `eval eval eval echo $sbindir`/update-smart-drivedb" >&AS_MESSAGE_FD
450    else
451      echo "drive database file:    [[disabled]]" >&AS_MESSAGE_FD
452      echo "database update script: [[disabled]]" >&AS_MESSAGE_FD
453    fi
454    echo "local drive database:   `eval eval eval echo $sysconfdir`/smart_drivedb.h" >&AS_MESSAGE_FD
455    echo "smartd config file:     `eval eval eval echo $sysconfdir`/smartd.conf${smartd_suffix}" >&AS_MESSAGE_FD
456    echo "smartd initd script:    `eval eval eval echo $initddir`/smartd${smartd_suffix}" >&AS_MESSAGE_FD
457    if test -n "$savestates"; then
458      echo "smartd save files:      `eval eval eval echo $savestates`MODEL-SERIAL.TYPE.state" >&AS_MESSAGE_FD
459    else
460      echo "smartd save files:      [[disabled]]" >&AS_MESSAGE_FD
461    fi
462    if test -n "$attributelog"; then
463      echo "smartd attribute logs:  `eval eval eval echo $attributelog`MODEL-SERIAL.TYPE.csv" >&AS_MESSAGE_FD
464    else
465      echo "smartd attribute logs:  [[disabled]]" >&AS_MESSAGE_FD
466    fi
467    echo "libcap-ng support:      $use_libcap_ng" >&AS_MESSAGE_FD
468    case "$host_os" in
469      linux*) echo "SELinux support:        ${with_selinux-no}" >&AS_MESSAGE_FD ;;
470    esac
471    ;;
472esac
473echo "-----------------------------------------------------------------------------" >&AS_MESSAGE_FD
Note: See TracBrowser for help on using the browser.